Mandelbrot problem

Programming Questions

asimes

in Programming Questions • 1 year ago

I'm interested in fractals at the moment and I thought I had made sense of the Wikipedia article on the Mandelbrot set which defines it as z = sq(z)+c where "c" is a complex number and "z" is tested after some number of iterations to see if it tends towards infinity. I looked at Daniel Shiffman's code in the Learning section and tried to rewrite his code to be more like the above equation because that makes sense to me. Unfortunately it doesn't seem to work, it just makes a bunch of concentric circles instead and I can't seem to figure out why. The rewriting of Shiffman's code is below. Set shiffmanCode to true to use his code (which correctly makes a Mandelbrot image) or leave it false to see what I tried:

boolean shiffmanCode = false; // Set this to true to use Shiffman's code
float xmin = -2.5;
float ymin = -2;
float wh = 4;
void setup() {
size(400, 400, P2D);
noLoop();
loadPixels();
}
void draw() {
int maxiterations = 200;
float xmax = xmin+wh;
float ymax = ymin+wh;
float dx = (xmax-xmin)/width;
float dy = (ymax-ymin)/height;
float x = xmin;
for (int i = 0; i < width; i++) {
float y = ymin;
for (int j = 0; j < height; j++) {
// Shiffman variables
float a = x;
float b = y;
// My variables, I am assuming Mandelbrot is z = sq(z)+c
float z = 0;
float cReal = x;
float cImaginary = y;
int n = 0;
while (n < maxiterations) {
// Original code from Processing's Learning section by Daniel Shiffman
if (shiffmanCode) {
float aa = a*a;
float bb = b*b;
float twoab = 2.0*a*b;
a = aa-bb+x;
b = twoab+y;
if (aa+bb > 16.0) break;
}
// My code
else {
z = sq(z)+sqrt(sq(cReal)+sq(cImaginary));
if (z > 2) break;
}
n++;
}
if (n == maxiterations) pixels[i+j*width] = 0;
else pixels[i+j*width] = color(n*16 % 255);
y += dy;
}
x += dx;
}
updatePixels();
}

If anyone can either explain why his code works or why mine doesn't I'd appreciate it.

EDIT: http://processing.org/learning/topics/mandelbrot.html

Replies(5)

jbum

Re: Mandelbrot problem

1 year ago

I'll take a stab at it.

So that simple equation

z = sq(z) + c

Involves complex numbers, which are pairs, real and imaginary. So let's say z is really (a,bi) and

c is really (x,yi).

z =~ a+bi

c =~ x+yi

Then the equation becomes

(a,bi) = (a+bi)(a+bi)+(x+yi)

Using algebra on the right side, we get

sq(a) + 2ab i +sq(b i) + x + y i

sq(b i) is the same as bb ii. The two i's make negative 1 (because i is the square root of -1), so we get -sq(b) .

sq(a ) + 2ab i -sq(b ) + x + y i

Separating out the real and the imaginary, we get

(a,bi) = (sq(a ) - sq(b ) + x, 2ab i+y i)

And this is essentially what is going on in Shiffman's code:

float aa = a*a;

float bb = b*b;

float twoab = 2.0*a*b;

a = aa-bb+x;

b = twoab+y;

Your code isn't working because you are ignoring the fact that z is compound number with real and imaginary components.

EDIT: For what it's worth, I find complex & imaginary numbers to be completely crazy and counter-intuitive. I use them because you can make cool fractals (and audio filters) with them, and it's simple enough to algebraically manipulate them, once you get the basic idea, but the *concept* is crazy.

asimes

Re: Mandelbrot problem

1 year ago

Oh, that does make sense, I forgot "z" was supposed to be complex too, thanks. By the way, does Processing handle imaginary numbers or do you just have to conceptually keep track of it?

jbum

Re: Mandelbrot problem

1 year ago

Processing (and Java) does not have built-in support for a complex number class. There are probably numerous Java classes that do complex numbers. Personally I would avoid them (or at least test the hell out of them), because their use will likely make your code less efficient. When you break down these equations, you can often eliminate stuff and save lots of computation. The iterations in the Mandelbrot set computation likely lend themselves to further optimizations. These types of optimizations can't be done if you abstract out complex as a class.

asimes

Re: Mandelbrot problem

1 year ago

One last question, isn't "twoab" a complex number? I don't exactly understand how that is only imaginary since it includes "a".

EDIT: Maybe my confusion stems from this? I tried to write out your explanation to my variables. The code does what I want it to but I'm not clear on the question above.

float xmin = -2.25;
float ymin = -1.5;
float wh = 3;
int maxIterations = 255;
void setup() {
size(400, 400, P2D);
loadPixels();
noLoop();
}
void draw() {
float xmax = xmin+wh;
float ymax = ymin+wh;
float dx = (xmax-xmin)/width;
float dy = (ymax-ymin)/height;
float cx = xmin;
for (int i = 0; i < width; i++) {
float cy = ymin;
for (int j = 0; j < height; j++) {
float zx = 0;
float zy = 0;
int numIterations = 0;
/*
Mandelbrot z = sq(z)+c
zx is real and zy is imaginary
cx is real and cy is imagainry
(zx, zyi) = (zx+zyi)*(zx+zyi)+(cx+cyi)
Right side becomes
sq(zx) + 2*zx*zyi - sq(zy) + cx + cyi
Separating real and imaginary makes
(zx, zyi) = (sq(zx) - sq(zy) + x, 2*zx*zyi + yi)
*/
while (numIterations < maxIterations) {
float zzx = zx*zx; // Real
float zzy = zy*zy; // Was imaginary, however imaginary * imaginary = neagative real
float twoComplex = 2.0*zx*zy; // Imaginary, also bad pun
zx = zzx-zzy+cx; // Put real numbers into zx
zy = twoComplex+cy; // Put imaginary numbers into zy
if (sq(zx)+sq(zy) > 4.0) break;
numIterations++;
}
if (numIterations == maxIterations) pixels[i+j*width] = 0;
else pixels[i+j*width] = numIterations+(numIterations<<8)+(numIterations<<16);
cy += dy;
}
cx += dx;
}
updatePixels();
}

jbum

Re: Mandelbrot problem

1 year ago

Look closely at the equation above right above where I wrote "separating the real and imaginary". I put all the terms that included an i on the right, and the remaining terms on the left. This puts the numbers in a form that can be expressed as a + bi. The original positions of a and b are not relevant at this point. We have a new number which contains new values for a and b.

Top Reply