I don't think that's what he meant. You wouldn't use the rotate() function to move something about the screen - the fact that the object is being drawn at different positions already does that. I believe he meant that you can use the rotate() function to rotate the object(s) following you so it looks like they are always facing towards the cursor. I pulled the following object code into a class for you too, have a look:

1. float dudeSpeed = 5.;
2. Boolean started = false;
3. Dude aDude;
4. class Dude {
5.   float px, py, a;
6.   color c;
7.   Dude( float _px, float _py ){
8.     px = _px;
9.     py = _py;
10.     a = atan2(mouseY-py, mouseX-px);
11.     c = color(255,255,0);
12.   }
13.   void move(){
14.     if( dist( mouseX, mouseY, px, py ) > dudeSpeed ){
15.       c = color(255,0,0);
16.       a = atan2(mouseY-py, mouseX-px);
17.       px = cos(a) * dudeSpeed + px;
18.       py = sin(a) * dudeSpeed + py;
19.     } else {
20.       c = color(0,255,0);
21.     }
22.   }
23.   void draw(){
24.     pushStyle();
25.     pushMatrix();
26.     translate(px, py);
27.     rotate(a);
28.     fill(c);
29.     noStroke();
30.     rect(0,0, 10, 10);
31.     popMatrix();
32.     popStyle();
33.   }
34. }
35. void setup() {
36.   size(800,600);
37.   smooth();
38.   aDude = new Dude( random(width), random(height) );
39. }
40. void draw() {
41.   background(0);
42.   aDude.move();
43.   aDude.draw();
44. }

Thanks for the help!