It has the capacity to span the whole spectrum of grays.

After working on this, I realized that I was treating a color variable like an int and therefore it did not work.

I was able to solve this by taking the average of all the components (since it's in gray, all the components are actually the same) and using that int value in the comparisons instead.

I finished this segment of my project when I realized that. The finished product doesn't have random colors because when the program runs it looks really psychedelic.

The finished code is below:

 

//An object that replicates Warhol's silkscreen prints.
public class Monochrome extends Painting{
  PImage grey;
  PImage sat;
  PImage rand;
 
  Monochrome(PImage p){
    work = p;
    clone = 0;
    grey = createImage(p.width, p.height, RGB);
    sat = createImage(p.width, p.height, RGB);
    rand = createImage(p.width, p.height, RGB);
  }
 
  //Make everything grayscale first
  /* According to Wikipedia the formula to convert is as follows:
     30% of red, 59% green, 11% blue
     needs to be gamma compressed???
     */
  void grayscale(){
    work.loadPixels();
    grey.loadPixels();
    for(int i = 0; i< work.pixels.length; i++){
      color cp = work.pixels[i];
      color cpp = (int)(.30*red(cp)+ .59 *green(cp)+ .11*blue(cp));
      grey.pixels[i] = color(cpp);
    }
    grey.updatePixels();
  }
 
  //then saturate things to either black, mid-gray, or white
  void saturate(){
    grayscale();
    grey.loadPixels();
    sat.loadPixels();
    for(int i = 0; i< grey.pixels.length; i++){
     color q = grey.pixels[i];
     int cpp;
     int cp = (int)((red(q)+green(q)+blue(q))/3);
     if(cp >= 0 && cp< 64){
       cpp= 0;
     }
     else if( cp>= 64 && cp<128){
       cpp= 86;
     }
     else if(cp>=128 && cp<192){
       cpp = 172;
     }
     else{
       cpp= 255;
     }
     sat.pixels[i] = color(cpp);
    }
    sat.updatePixels();
      
  }
 
  //then color it in with a random color
  void ink(){
    saturate();
    sat.loadPixels();
    rand.loadPixels();

     // color a = color(random(255), random(255), random(255));
     // color b = color(random(255), random(255), random(255));
     // color c = color(random(255), random(255), random(255));
  
    color a = color(38, 206, 234);
    color b = color(255, 5, 139);
    color c = color(50, 144, 45);
    for(int i =0; i<sat.pixels.length; i++){
      color q = sat.pixels[i];
      int cp = (int)((red(q)+green(q)+blue(q))/3);
      color cpp;
     
      if(cp == 0){
        cpp = c;
      }
      else if (cp == 86){
        cpp = a;
      }
      else if(cp == 172){
        cpp = b;
      }
      else{
        cpp=color(255);
      }
     
      rand.pixels[i]=cpp;
    }
    rand.updatePixels();
  }
 
  void display(){
   
    background(120);
    ink();
    image(work, 0, 0, width/2,height/2);
    image(grey, width/2, 0, width/2, height/2);
    image(sat, 0, height/2, width/2, height/2);
    image(rand, width/2, height/2, width/2, height/2);
   
  }  
}

 

Any suggestions on how to make this better is greatly appreciated.