I like the graphic and text of yours very much!


I changed the approach....

now everything loops all the time, but the books height and color is only defined once randomly in setup() and stored

when you draw the books, we use the stored data

when you click the man, it gets shuffled once


later we use an object Book and store each book there (x,y,height, width, color title) and have an array of those books....

at the moment we have three times the same books on one shelf, we could (and should) also have all different books

1. //
2. // http://forum.processing.org/topic/make-one-function-not-loop-while-the-rest-do
3. String pageText;
4. PImage nightWatchman;
5. PImage tree1;
6. PImage background;
7. Boolean eyeLids = false;
8. float tLidPos; //top eyelid position
9. float bLidPos; //bottom eyelid position
10. float bookXPos; //book position along shelves
11. float bookYPos; //shelf position
12. float bookHeight = 0;
13. Boolean books = true;
14. float count=0;
15. //
16. float[] bookList; // height
17. color[] bookColor = new color [17];
18. String[] bookTitle = new String [17]; // title
19. //
20. void setup() {
21.   size(800, 800);
22.   background(150, 0, 0);
23.   nightWatchman = loadImage("nightWatchman2.png");
24.   background = loadImage("background.png");
25.   tree1 = loadImage("tree1.png");
26.   //
27.   bookList = new float[17];
28.   //
29.   for (int j=0; j<17; j++) {
30.     for (int n=0; n<3; n++) {
31.       fill(random(100, 255), 101, 100);
32.       bookXPos = j*44 +27;
33.       bookYPos = n*255 +258;
34.       bookHeight = random(190, 221);
35.       bookList[j] = bookHeight;
36.       bookTitle[j] = "";
37.       bookColor  [j] = color (random(100, 255), 101, 100);
38.     }
39.   }
40.   bookTitle[6] = "Homer";
41. }
42. void draw() {
43.   background(0);
44.   noStroke();
45.   // image(background, 0, 0);
46.   //books
47.   drawBooks();
48.   //eyes
49.   fill(255);
50.   ellipse(655, 287, 35, 35);
51.   ellipse(703, 287, 35, 35);
52.   fill(0);
53.   ellipse(655, 287, 15, 15);
54.   ellipse(703, 287, 15, 15);
55.   //eyeLids
56.   fill(230, 198, 177);
57.   if (eyeLids == true) {
58.     for (int i=0; i<20; i++) {
59.       //top eyelids
60.       tLidPos = 251+i;
61.       rect(638, tLidPos, 35, 20);
62.       rect(686, tLidPos, 35, 20);
63.     }
64.     for (int b=0; b<15; b++) {
65.       //bottom eyelids
66.       bLidPos = 304-b;
67.       stroke(200, 156, 132);
68.       rect(638, bLidPos, 35, 15);
69.       rect(686, bLidPos, 35, 15);
70.     }
71.   }
72.   //night watchman
73.   //  image(nightWatchman, 0, 0);
74.   //text box and text
75.   fill(255);
76.   rect(50, 600, 700, 150);
77.   fill(0);
78.   pageText = "     hen the library is closed and the night watchman has fallen asleep ";
79.   pageText += "in his big armchair, the shelves come to life. Doors and windows appear on ";
80.   pageText += "the backs of the books, lights come on, and the sound of voices drifts out ";
81.   pageText += "between the pages. Full grown trees spring up and chimneys begin to smoke. ";
82.   pageText += "Staircases and ladders join the shelves into great cities, and in the distance ";
83.   pageText += "small dogs bark.";
84.   textSize(27);
85.   text("W", 71, 635);
86.   textSize(15);
87.   text(pageText, 70, 620, 670, 140);
88.   noStroke();
89.   ellipse(mouseX, mouseY, 30, 30);
90.   //
91. }
92. void mouseClicked() {
93.   if (mouseX >= 544 && mouseX <=800 && mouseY >=200 && mouseY<800) {
94.     eyeLids = true;
95.     count++;
96.     // redraw();
97.     shuffleSomeBooks();
98.   }
99. }
100. //
101. void shuffleSomeBooks() {    //  new
102.   // shuffle first 6 books.
103.   for (int j=0; j<7; j++) {
104.     int partner = int(random(0, 7));
105.     if (j!=partner)
106.       swapBooks(j, partner);
107.   } // for
108. }
109. //
110. void swapBooks( int j, int partner) {
111.   // swap two books
112.   color tempCol = bookColor[j];
113.   float tempHeight = bookList[j];
114.   String tempTitle = bookTitle[j];
115.   //
116.   bookColor[j] = bookColor[partner];
117.   bookList [j] = bookList [partner];
118.   bookTitle[j] = bookTitle[partner];
119.   //
120.   bookColor[partner] = tempCol;
121.   bookList [partner] = tempHeight;
122.   bookTitle[partner] = tempTitle;
123.   //
124. }
125. //
126. void drawWindow(float x, float y) {
127.   fill(255, 232, 71);
128.   rect(x, y, 20, 30);
129.   stroke(111, 71, 23);
130.   line(x, y, x+20, y);
131.   line(x, y+30, x+20, y+30);
132.   line(x, y, x, y+30);
133.   line(x+20, y, x+20, y+30);
134.   line(x+10, y, x+10, y+30);
135.   line(x, y+15, x+20, y+15);
136. }
137. void drawBooks() {
138.   for (int j=0; j<17; j++) {
139.     for (int n=0; n<3; n++) {
140.       fill(   bookColor  [j]   ); // new
141.       bookXPos = j*44 +27;
142.       bookYPos = n*255 +258;
143.       //
144.  
145.       //tells the program not to draw books between these coordinates
146.       if (bookXPos >= 150 && bookXPos <=320 && bookYPos >= 283 && bookYPos <= 514) {
147.         books=false;
148.       }
149.       else {
150.         books=true;
151.       }
152.       //everywhere else, draw books
153.       if (books == true) {
154.         rect(bookXPos, bookYPos-bookList[j], 40, bookList[j]);
155.         if (bookTitle[j] != "") {
156.           pushMatrix();
157.           translate (bookXPos+24, bookYPos-10);
158.           rotate (-radians(90));
159.           fill(255);
160.           text (bookTitle[j], 0, 0);
161.           popMatrix();
162.         } // if
163.       }
164.     }//for
165.   }//for
166.   // noLoop();
167. }

now with the class Book

1. //
2. // http://forum.processing.org/topic/make-one-function-not-loop-while-the-rest-do
3. String pageText;
4. PImage nightWatchman;
5. PImage tree1;
6. PImage background;
7. Boolean eyeLids = false;
8. float tLidPos; //top eyelid position
9. float bLidPos; //bottom eyelid position
10. //
11. float count=0;
12. Book [] books = new Book[3*17];
13. //
14. //
15. void setup() {
16.   size(800, 800);
17.   background(150, 0, 0);
18.   nightWatchman = loadImage("nightWatchman2.png");
19.   background = loadImage("background.png");
20.   tree1 = loadImage("tree1.png");
21.   //
22.   int i=0;
23.   for (int n=0; n<3; n++) {
24.     for (int j=0; j<17; j++) {
25.       books[i] = new Book();
26.       books[i].bookXPos = j*44 +27;
27.       books[i].bookYPos = n*255 +258;
28.       books[i].bookHeight = random(190, 221);
29.       books[i].bookTitle = "";
30.       books[i].bookColor = color (random(100, 255), 101, 100);
31.       i++;
32.     }
33.   }
34.   books[6].bookTitle = "Homer";
35. }
36. void draw() {
37.   background(0);
38.   noStroke();
39.   // image(background, 0, 0);
40.   //books
41.   drawBooks();
42.   //eyes
43.   fill(255);
44.   ellipse(655, 287, 35, 35);
45.   ellipse(703, 287, 35, 35);
46.   fill(0);
47.   ellipse(655, 287, 15, 15);
48.   ellipse(703, 287, 15, 15);
49.   //eyeLids
50.   fill(230, 198, 177);
51.   if (eyeLids == true) {
52.     for (int i=0; i<20; i++) {
53.       //top eyelids
54.       tLidPos = 251+i;
55.       rect(638, tLidPos, 35, 20);
56.       rect(686, tLidPos, 35, 20);
57.     }
58.     for (int b=0; b<15; b++) {
59.       //bottom eyelids
60.       bLidPos = 304-b;
61.       stroke(200, 156, 132);
62.       rect(638, bLidPos, 35, 15);
63.       rect(686, bLidPos, 35, 15);
64.     }
65.   }
66.   //night watchman
67.   //  image(nightWatchman, 0, 0);
68.   //text box and text
69.   fill(255);
70.   rect(50, 600, 700, 150);
71.   fill(0);
72.   pageText = "     hen the library is closed and the night watchman has fallen asleep ";
73.   pageText += "in his big armchair, the shelves come to life. Doors and windows appear on ";
74.   pageText += "the backs of the books, lights come on, and the sound of voices drifts out ";
75.   pageText += "between the pages. Full grown trees spring up and chimneys begin to smoke. ";
76.   pageText += "Staircases and ladders join the shelves into great cities, and in the distance ";
77.   pageText += "small dogs bark.";
78.   textSize(27);
79.   text("W", 71, 635);
80.   textSize(15);
81.   text(pageText, 70, 620, 670, 140);
82.   noStroke();
83.   ellipse(mouseX, mouseY, 30, 30);
84.   //
85. }
86. void mouseClicked() {
87.   if (mouseX >= 544 && mouseX <=800 && mouseY >=200 && mouseY<800) {
88.     eyeLids = true;
89.     count++;
90.     // redraw();
91.     shuffleSomeBooks();
92.   }
93. }
94. //
95. void shuffleSomeBooks() {  
96.   // shuffle first 6 books.
97.   for (int j=0; j<7; j++) {
98.     int partner = int(random(0, 7));
99.     if (j!=partner)
100.       books[j].swapBooks(partner);
101.   } // for
102. }
103. //
104. void drawWindow(float x, float y) {
105.   fill(255, 232, 71);
106.   rect(x, y, 20, 30);
107.   stroke(111, 71, 23);
108.   line(x, y, x+20, y);
109.   line(x, y+30, x+20, y+30);
110.   line(x, y, x, y+30);
111.   line(x+20, y, x+20, y+30);
112.   line(x+10, y, x+10, y+30);
113.   line(x, y+15, x+20, y+15);
114. } // func
115. //
116. void drawBooks() {
117.   for (int j=0; j<books.length; j++) {
118.     books[j].updateIsInsideForbiddenArea ();
119.     books[j].display();
120.   }//for
121. } // func
122. 
     
123. // ===================================================
124. 
     
125. class Book {
126. 
     
127.   float bookXPos; //book position along shelves
128.   float bookYPos; //shelf position
129.   float bookHeight = 0;
130.   float bookWidth  = 40;
131.   color bookColor = color (255, 2, 2);
132.   String bookTitle = ""; // title
133.   boolean bookShow = true ;
134.   //
135.   void display() {
136.     // draw books
137.     fill( bookColor ); 
138.     if (bookShow) {
139.       rect( bookXPos, bookYPos - bookHeight, bookWidth, bookHeight);
140.       if (bookTitle != "") {
141.         pushMatrix();
142.         translate (bookXPos+24, bookYPos-10);
143.         rotate (-radians(90));
144.         fill(255);
145.         text (bookTitle, 0, 0);
146.         popMatrix();
147.       } // if
148.     }
149.   } // method
150. 
     
151.   //
152. 
     
153.   void updateIsInsideForbiddenArea () {
154.     //tells the program not to draw books between these coordinates
155.     // and update the bookShow accordingly
156.     if (isInsideForbiddenArea()) {
157.       bookShow=false;
158.     }
159.     else {
160.       bookShow=true;
161.     }
162.   } // method
163.   //
164.   boolean isInsideForbiddenArea () {
165.     //tells the program not to draw books between these coordinates
166.     return  ( bookXPos >= 150 && 
167.       bookXPos <=320 && 
168.       bookYPos >= 283 && 
169.       bookYPos <= 514);
170.   } // method / func
171.   //
172.   void swapBooks(  int partner) {
173.     // swap book with another book (with index partner)
174.     color tempCol    = bookColor;
175.     float tempHeight = bookHeight;
176.     String tempTitle = bookTitle;
177.     //
178.     bookColor =  books[partner].bookColor;
179.     bookHeight = books[partner].bookHeight;
180.     bookTitle =  books[partner].bookTitle;
181.     //
182.     books[partner].bookColor = tempCol;
183.     books[partner].bookHeight = tempHeight;
184.     books[partner].bookTitle = tempTitle;
185.     //
186.   } // method
187.   //
188. } // class
189. //