lovely MP3 Player

Share your Work

Chrisir

in Share your Work • 7 months ago

More by accident I made a player for mp3-files.
Minim is so brillant I really only had to copy the examples from the introduction. Thanks!

Installation:

set String pathGlobal to "" to start with the data path or to a folder of your choice: String pathGlobal= "D://Music//Adele//21";

Features

It has navigation (prev / next) for the files in the current folder and you can also change the folder (click button marked "v").
When song is done, it goes to the next song
When folder is done, the folder is started again at file 0
Progress bar you can click to set play position of current song
FFT frequence graphic

To do:

make screen buttons an array
make nice images for screen buttons
volume control
control repeat / loop types (folder / song / none etc.)
be able to play recursively all subfolders when current folder is done
play list of some sort

[Edited]

new version - better error handling

//
import java.io.File;
import ddf.minim.*;
import ddf.minim.analysis.*;
// see
// http://code.compartmental.net/tools/minim/quickstart/
// http://code.compartmental.net/minim/javadoc/
//
// song stuff
Minim minim;
AudioPlayer song;
AudioMetaData meta;
int songLength=0;
boolean paused = false;
boolean noSongFound = false;
//
// buttons
Button buttonPause;
Button buttonProgressFrame;
Button buttonProgressData;
Button buttonPrevious;
Button buttonNext;
Button buttonFolder;
//
// files and Co.
// pathGlobal: set path or use "" to use data path
String pathGlobal = "D://Musik//Adele//21"; // or "" to use data path
String[] namesFiles; // songs in folder
int indexFile = 0; // current song in namesFiles
//
// frequence display
FFT fft;
//
void setup()
{
size(500, 500);
//
minim = new Minim(this);
//
getFolder() ;
//
// define buttons
buttonPause = new Button ( width/2-10, 65,
20, 20,
false, color (0),
true, color (255),
"||",
"Pause / play",
0);
//
buttonProgressFrame = new Button ( 10, 40,
width-20, 20,
false, color (0),
true, color (255),
"",
"Click to set play position",
1);
//
buttonProgressData = new Button ( 12, 42,
0, 17,
true, color (222, 1, 1),
false, color (255),
"",
"",
-1);
//
buttonPrevious = new Button ( width/2-70, 65,
20, 20,
false, color (0),
true, color (255),
"|<",
"Previous song",
2);
buttonNext = new Button ( width/2+50, 65,
20, 20,
false, color (0),
true, color (255),
">|",
"Next song",
3);
buttonFolder = new Button ( width-30, 65,
20, 20,
false, color (0),
true, color (255),
"v",
"Open folder",
4);
//
getCurrentSong();
//
}
//
void draw()
{
background(0);
//
// error detected?
if (noSongFound) {
fill(255);
textTab ("No song found in \n"
+ pathGlobal
+ "\nPlease use open folder to change folder.", 20, 20 );
}
//
if (!noSongFound) {
//
// show progress
buttonProgressFrame.display();
if (!(meta==null))
buttonProgressData.w = map(song.position(), 0, meta.length(), 0, width-24 );
buttonProgressData.display();
//
// show pause button
buttonPause.display();
//
} // if
//
showOtherScreenElements() ;
//
if (!noSongFound) {
// show meta data
showMeta() ;
} // if
//
if (!noSongFound) {
// song over? go next song (but not if just paused)
try {
if (!song.isPlaying()&&!paused)
{
// go To Next Song(
command( buttonNext.commandNumber );
}
}
catch (Exception e) {
// do nothing
}
}
//
// yellow mouse over tool tip
checkMouseOver();
//
} // func
//
// Inputs ---------------------------
void mousePressed() {
// which button
if (buttonPause.over()) {
command( buttonPause.commandNumber );
}
else if (buttonProgressFrame.over()) {
command( buttonProgressFrame.commandNumber );
}
else if (buttonNext.over()) {
command( buttonNext.commandNumber );
}
else if (buttonPrevious.over()) {
command( buttonPrevious.commandNumber );
}
else if (buttonFolder.over()) {
command( buttonFolder.commandNumber );
}
else {
println("not found");
}
}
//
void keyPressed () {
// keyPressed uses the same command as the buttons
switch (key) {
case ' ':
command( buttonPause.commandNumber );
break;
case 'n':
command( buttonNext.commandNumber );
break;
case 'p':
command( buttonPrevious.commandNumber );
break;
case 'o':
command( buttonFolder.commandNumber );
break;
default:
// do nothing
break;
}
}
//
// minor tools --------------------------
//
void checkMouseOver() {
if (!noSongFound) {
// which button
if (buttonPause.over()) {
buttonPause.showMouseOver() ;
}
else if (buttonProgressFrame.over()) {
buttonProgressFrame.showMouseOver() ;
}
else if (buttonNext.over()) {
buttonNext.showMouseOver() ;
}
else if (buttonPrevious.over()) {
buttonPrevious.showMouseOver() ;
}
else if (buttonFolder.over()) {
buttonFolder.showMouseOver() ;
}
else {
// println("not found");
}
}
else {
if (buttonFolder.over()) {
buttonFolder.showMouseOver() ;
} // if
} // else
//
}
//
void showOtherScreenElements() {
//
// first perform a forward fft on one of song's buffers
// I'm using the mix buffer
// but you can use any one you like
if (!noSongFound) {
if (!(fft==null)) {
fft.forward(song.mix);
stroke(255, 0, 0, 128);
// draw the spectrum as a series of vertical lines
// I multiple the value of getBand by 4
// so that we can see the lines better
for (int i = 0; i < fft.specSize(); i++)
{
line(i, height, i, height - fft.getBand(i)*4);
}
}
//
fill(255);
try {
text (
"Played "
+ strFromMillis ( song.position() )
+ " of "
+ strFromMillis ( songLength )
+ ".",
30, 30 );
// show pause
if (!song.isPlaying()) {
fill(255);
text ("pause", width/2-17, 54);
} // if
} // try
catch (Exception e) {
// e.printStackTrace();
}
finally {
}
//
//
buttonPrevious.display();
buttonNext.display();
} // if
buttonFolder.display();
//
}
//
void command( int commandNumber ) {
// can execute the command number from the buttons
switch (commandNumber) {
case 0:
// toggle pause
if (song.isPlaying()) {
song.pause();
paused=true;
buttonPause.text=">";
}
else
{
song.play();
paused=false;
buttonPause.text="||";
}
break;
case 1:
// progress bar: set cue
int newSongPosition = int ( map(mouseX,
buttonProgressFrame.x, buttonProgressFrame.x+buttonProgressFrame.w,
0, songLength ) ) ;
song.cue( newSongPosition );
break;
case 2:
indexFile--;
if (indexFile<0)
indexFile=0;
getCurrentSong() ;
break;
case 3:
indexFile++;
// last song?
if (indexFile>=namesFiles.length)
// indexFile=namesFiles.length-1; // last song again and again
indexFile=0; // 1st song in folder
getCurrentSong() ;
break;
case 4:
chooseFolder();
break;
case -1:
// undefined
break;
default:
// error
println("Error 101" ) ;
break;
} // switch
} // func
//
void getCurrentSong() {
// this loads song from the data folder
// check if ok
if (namesFiles.length>0) {
if (fileIsOK (namesFiles[indexFile])) {
// stop old song if playing one
if (song != null) {
song.close();
minim.stop();
}
noSongFound = false;
println (namesFiles[indexFile]);
song = minim.loadFile( namesFiles[indexFile] ); // pathGlobal + "\\" +
songLength=song.length();
// load meta
meta = song.getMetaData();
// an FFT needs to know how
// long the audio buffers it will be analyzing are
// and also needs to know
// the sample rate of the audio it is analyzing
fft = new FFT(song.bufferSize(), song.sampleRate());
//
song.play();
} // if
else
{
println ("not ok "+ namesFiles[indexFile]);
}
} // if
else
{
println ("no song found at all - not ok. ");
noSongFound = true;
} // else
} // func
//
void chooseFolder() {
selectFolder("Select a Music folder to play", "folderSelected");
}
//
void folderSelected(File selection) {
if (selection == null) {
println("Window was closed or the user hit cancel.");
}
else {
println("User selected " + selection.getAbsolutePath());
noSongFound = false;
indexFile=0;
pathGlobal= selection.getAbsolutePath();
getFolder();
getCurrentSong();
}
}
//
void getFolder() {
// get file list
if ( pathGlobal.equals("") )
pathGlobal = dataPath("");
File dir = new File( pathGlobal );
println(dir);
//
File[] namesFiles2 = dir.listFiles(); // dir.list();
if (namesFiles2==null) {
println("no file found - set folder to data path ##################");
pathGlobal = dataPath("");
dir = new File( pathGlobal );
println(dir);
//
namesFiles2 = dir.listFiles(); // dir.list();
}
namesFiles = new String [0];
// check all found files if they are ok
for (int i = 0; i < namesFiles2.length; i++) {
// if ok
if (fileIsOK(namesFiles2[i].getAbsolutePath() )) {
// build new array
namesFiles = append (namesFiles, namesFiles2[i].getAbsolutePath() );
noSongFound = false;
} // if
else
{
// println ("skipped "+namesFiles2[i]);
} // else
} // for
//
println("Found "+ namesFiles.length + " songs.");
// println(namesFiles);
indexFile=0;
//
if (namesFiles.length==0) {
println ("no song ################");
noSongFound = true;
}
else
noSongFound = false;
//
} // func
//
boolean fileIsOK (String name) {
// AudioPlayer: Mono and Stereo playback of WAV, AIFF, AU, SND, and MP3 files.
if (name==null) return false;
name=trim(name);
if (name.equals("")) return false;
if (name.substring ( name.length()-4 ).equals (".MP3") ) return true;
if (name.substring ( name.length()-4 ).equals (".mp3") ) return true;
if (name.substring ( name.length()-4 ).equals (".WAV") ) return true;
if (name.substring ( name.length()-4 ).equals (".wav") ) return true;
if (name.substring ( name.length()-5 ).equals (".aiff") ) return true;
if (name.substring ( name.length()-3 ).equals (".au") ) return true;
if (name.substring ( name.length()-4 ).equals (".SND") ) return true;
if (name.substring ( name.length()-4 ).equals (".snd") ) return true;
// when no extension matched:
return false;
}
//
void showMeta() {
//
// data for meta information
int ys = 115; // y start-pos
int yi = 16; // y line difference
//
int y = ys;
fill(255);
if (!(meta==null)) {
textTab("File Name: \t" + showSongWithoutFolder(), 5, y);
textTab("Length: \t" + strFromMillis(meta.length()), 5, y+=yi);
textTab("Title: \t" + meta.title(), 5, y+=yi);
textTab("Author: \t" + meta.author(), 5, y+=yi);
textTab("Album: \t" + meta.album(), 5, y+=yi);
textTab("Date: \t" + meta.date(), 5, y+=yi);
textTab("Comment: \t" + meta.comment(), 5, y+=yi);
try {
// textTab("Track: \t " + meta.track(), 5, y+=yi);
}
catch (ArrayIndexOutOfBoundsException e) { // to do ???
System.err.println("Caught ArrayIndexOutOfBoundsException: "
+ e.getMessage());
}
finally {
// do nothing
};
textTab("Genre:\t" + meta.genre(), 5, y+=yi);
textTab("Copyright: \t" + meta.copyright(), 5, y+=yi);
textTab("Disc: \t" + meta.disc(), 5, y+=yi);
textTab("Composer: \t" + meta.composer(), 5, y+=yi);
textTab("Orchestra: \t" + meta.orchestra(), 5, y+=yi);
textTab("Publisher: \t" + meta.publisher(), 5, y+=yi);
textTab("Encoded: \t" + meta.encoded(), 5, y+=yi);
} // if
textTab("Folder:\t" + pathGlobal, 5, y+=yi);
textTab("In folder:\t"
+"song "
+ str(indexFile+1)
+ " of "
+ namesFiles.length
+ ".", 5, y+=yi);
}
//
String showSongWithoutFolder() {
// println(pathGlobal);
// println(meta.fileName());
if ( meta == null ) {
println("meta==null");
return "?";
} // if
else {
return meta.fileName().substring(pathGlobal.length() + 1);
} // else
} // func
//
void textTab (String s, float x, float y)
{
// makes \t as tab for a table for one line
// only for 2 columns yet
// indent:
int indent = 90;
//
s=trim ( s );
String [] texts = split (s, "\t");
s=null;
texts[0]=trim(texts[0]);
text (texts[0], x, y);
//
// do we have a second part?
if (texts.length>1&&texts[1]!=null) {
// is the indent too small
if (textWidth(texts[0]) > indent) {
indent = int (textWidth(texts[0]) + 10);
} // if
//
texts[1]=trim(texts[1]);
text (texts[1], x+indent, y);
}
} // func
//
String strFromMillis ( int m ) {
// returns a string that represents a given millis m as hrs:minute:seconds
float sec;
int min;
//
sec = m / 1000;
min = floor(sec / 60);
sec = floor(sec % 60);
// over one hour?
if (min>59) {
int hrs = floor(min / 60);
min = floor (min % 60);
return hrs+":"+nf(min, 2)+":"+nf(int(sec), 2);
}
else
{
return min+":"+nf(int(sec), 2);
}
}
//
void stop()
{
song.close();
minim.stop();
//
super.stop();
}
//
// =======================================================================
class Button {
// represents a rect / button
float x; // pos
float y;
float w=0; // size
float h=0;
// color
boolean hasColorFill=true; // if it has filling
color colorFill; // what is it
//
boolean hasColorStroke=true; // if it has an outline
color colorStroke; // what is it
// other
String text=""; // text to display
String textMouseOver=""; // text for mouse over
int commandNumber; // each button has a command number that gets executed when clicked
//
// constructor
Button ( float x_, float y_,
float w_, float h_,
boolean hasColorFill_, color cFill_,
boolean hasColorStroke_, color cStroke_,
String text_,
String textMouseOver_,
int commandNumber_) {
x=x_;
y=y_;
w=w_;
h=h_;
// color fill
hasColorFill=hasColorFill_;
colorFill=cFill_;
// color stroke
hasColorStroke = hasColorStroke_;
colorStroke = cStroke_;
//
text=text_;
textMouseOver=textMouseOver_;
commandNumber=commandNumber_;
} // constructor
//
void display () {
if (hasColorFill)
fill(colorFill);
else
noFill();
if (hasColorStroke)
stroke(colorStroke);
else
noStroke();
rect(x, y, w, h);
fill(255);
text(text, x+8, y+12);
} // method
//
boolean over() {
return (mouseX>x && mouseX<x+w&& mouseY>y&&mouseY<y+h);
} // func
//
void showMouseOver() {
// yellow mouse over help text
if (!textMouseOver.equals("")) {
float pos=x; // or mouseX;
// right screen border?
if (pos+textWidth(textMouseOver)+10>width) {
pos=width-textWidth(textMouseOver)-12;
}
fill(255, 255, 44);
rect(pos, y+h+14, textWidth(textMouseOver)+2, 20);
fill(0);
text ( textMouseOver, pos+2, y+48);
}
//
}
//
} // class
//

Replies(16)

calsign

Funny... just a while ago, I tried to make something similar. If you don't mind, here's my program... I have already implemented some of the features that you describe for the future. Perhaps we can learn from each other as well...

My program was designed to be more like iTunes, so an application that stores a list of loaded songs and information about them, then allows you to play them. In my case, a list of songs is created in a "CalsignPlay" folder in the user's home directory. It is also possible to add songs to the list, but not a whole folder because I don't like the look of Processing's default folder selector (the Swing Dialog). Also, a lot of my design choices were made due to aesthetics. Hopefully I said all that without too many run-on sentences...

Hopefully clearer: This was created primarily to get it working and may / most certainly does contain a lot of rough edges.

Here it is:

import java.lang.System;
import java.util.Properties;
import java.util.concurrent.TimeUnit;
import java.io.*;
import ddf.minim.*;
Properties defaultProps;
Properties props;
PFont font;
String storagePath;
Minim minim;
AudioPlayer[] players;
int playing;
PlayPauseButton play;
PlayBar progress;
DataList list;
Slider volume;
Button importMusic;
boolean flagForReload;
boolean flagForNextSong;
int nextSongFlagged = -1000;
void setup() {
size(1200, 800);
registerDispose(this);
storagePath = System.getProperty("user.home") + "/CalsignPlay/";
(new File(storagePath)).mkdirs();
try {
defaultProps = new Properties();
FileInputStream in = new FileInputStream(storagePath + "defaultProperties.properties");
defaultProps.load(in);
in.close();
props = new Properties(defaultProps);
in = new FileInputStream(storagePath + "properties.properties");
props.load(in);
in.close();
} catch(Exception e) {
System.err.println("Could not load the properties files. Attempting to create them now...");
e.printStackTrace();
defaultProps = new Properties();
defaultProps.setProperty("volume", str(50));
props = new Properties(defaultProps);
try {
FileOutputStream out = new FileOutputStream(storagePath + "defaultProperties.properties");
defaultProps.store(out, "---No Comment---");
out.close();
out = new FileOutputStream(storagePath + "properties.properties");
props.store(out, "---No Comment---");
out.close();
} catch(Exception f) {
System.err.println("Unable to create properties files!");
f.printStackTrace();
}
}
font = createFont("Arial", 12);
textFont(font);
minim = new Minim(this);
list = new DataList(20, 90, width - 40, height - 150) {
public void selected(int id) {
players[playing].pause();
players[playing].rewind();
playing = id;
players[playing].play();
}
};
reload();
play = new PlayPauseButton(20, 20, 60, 50) {
public void action() {
if (players[playing].isPlaying())
players[playing].pause();
else
players[playing].play();
}
public boolean isPlaying() {
if(players.length > 0)
return players[playing].isPlaying();
else
return false;
}
};
progress = new PlayBar(80, 43, width - 280, 18) {
public void updateProgress(float skip) {
if(players.length > 0)
players[playing].skip((int) map(skip, 0, 100, 0, players[playing].length()) - players[playing].position());
}
public float getComplete() {
if(players.length > 0)
return map(players[playing].position(), 0, players[playing].length(), 0, 100);
else
return 0;
}
};
volume = new Slider(width - 180, 43, 160, 18) {
public void updateValue(float value) {
for (AudioPlayer player : players)
player.setGain(map(value, 0, 100, -40, 5));
}
public float getValue() {
if(players.length > 0)
return map(players[playing].getGain(), -40, 5, 0, 100);
else
return map(int(props.getProperty("volume")), 0, 100, -40, 5);
}
};
importMusic = new Button(20, height - 40, 60, 20) {
public void display() {
stroke(0);
if (over())
fill(204);
else
fill(250);
rect(loc.x, loc.y, dim.x, dim.y);
textSize(12);
textAlign(CENTER, CENTER);
fill(0);
text("Import...", loc.x + dim.x / 2, loc.y + dim.y / 2);
}
public void action() {
selectInput("Select file or folder to import", "importMusic");
}
};
float gain = map(int(props.getProperty("volume")), 0, 100, -40, 5);
for(AudioPlayer player : players)
player.setGain(gain);
smooth();
}
void draw() {
background(255);
if(flagForReload) {
reload();
flagForReload = false;
}
if(!flagForNextSong && players.length > 0 && players[playing].position() >= players[playing].length() - 1000) {
flagForNextSong = true;
nextSongFlagged = millis() + (players[playing].position() - players[playing].length() - 1000);
}
if(flagForNextSong && millis() - nextSongFlagged >= 1000) {
players[playing].pause();
players[playing].rewind();
if(playing < players.length - 1) {
playing ++;
players[playing].play();
}
flagForNextSong = false;
nextSongFlagged = -1000;
}
progress.display();
play.display();
if(players.length > 0) {
AudioMetaData metadata = players[playing].getMetaData();
fill(0);
textSize(12);
textAlign(LEFT, BOTTOM);
text(metadata.title() + " - " + metadata.album() + " - " + metadata.author(), 90, 38);
textAlign(RIGHT, BOTTOM);
long pos = players[playing].position();
String position = String.format("%d:%02d",
TimeUnit.MILLISECONDS.toMinutes(pos),
TimeUnit.MILLISECONDS.toSeconds(pos) -
TimeUnit.MINUTES.toSeconds(TimeUnit.MILLISECONDS.toMinutes(pos))
);
long len = players[playing].length();
String length = String.format("%d:%02d",
TimeUnit.MILLISECONDS.toMinutes(len),
TimeUnit.MILLISECONDS.toSeconds(len) -
TimeUnit.MINUTES.toSeconds(TimeUnit.MILLISECONDS.toMinutes(len))
);
text(position + " / " + length, width - 200, 38);
}
list.display();
volume.display();
importMusic.display();
}
void mousePressed() {
play.update();
progress.update();
list.update();
volume.update();
importMusic.update();
}
void mouseDragged() {
volume.updateDrag();
}
void mouseReleased() {
volume.updateRelease();
}
void importMusic(File selection) {
String toImport = selection.getAbsolutePath();
//String[] temp = loadStrings("songs.txt");
//temp = append(temp, selection.getAbsolutePath());
//saveStrings("songs.txt", temp);
//PrintWriter output = createWriter("songs.txt");
//output.println(selection.getAbsolutePath());
//output.flush();
//output.close();
try {
FileWriter writer = new FileWriter(new File(storagePath + "songs.txt"), true);
writer.write(System.getProperty("line.separator") + toImport);
writer.flush();
writer.close();
}
catch(IOException e) {
e.printStackTrace();
}
flagForReload = true;
}
void reload() {
players = new AudioPlayer[0];
//String[] songs = loadStrings("songs.txt");
File songsDest = new File(storagePath + "songs.txt");
if(!songsDest.exists()) {
String[] lines = {};
saveStrings(songsDest.getAbsolutePath(), lines);
}
String[] songs = new String[0];
BufferedReader reader = createReader(storagePath + "songs.txt");
String line = "";
while (line != null) {
try {
line = reader.readLine();
if (line != null) songs = append(songs, line);
}
catch (IOException e) {
e.printStackTrace();
line = null;
}
}
try {
reader.close();
}
catch(IOException e) {
e.printStackTrace();
}
list.items.clear();
for (String path : songs) {
try {
AudioPlayer temp = minim.loadFile(path);
AudioMetaData metadata = temp.getMetaData();
String[] data = {
metadata.title(), metadata.album(), metadata.author(), metadata.genre()
};
list.addItem(data);
players = (AudioPlayer[]) append(players, temp);
} catch(Exception e) {
System.err.println("Unable to load song: " + path);
e.printStackTrace();
}
}
}
void dispose() {
props.setProperty("volume", str(map(players[playing].getGain(), -40, 5, 0, 100)));
try {
FileOutputStream out = new FileOutputStream(storagePath + "properties.properties");
props.store(out, "---No Comment---");
out.close();
} catch(Exception e) {
e.printStackTrace();
}
}
abstract class Button {
PVector loc;
PVector dim;
Button(float x, float y, float w, float h) {
loc = new PVector(x, y);
dim = new PVector(w, h);
}
boolean over() {
return (mouseX > loc.x && mouseX < loc.x + dim.x && mouseY > loc.y && mouseY < loc.y + dim.y);
}
void update() {
if(mousePressed && over())
action();
}
abstract void display();
abstract void action();
}
abstract class DataList {
ArrayList<ListItem> items;
PVector loc;
PVector dim;
DataList(float x, float y, float w, float h) {
items = new ArrayList<ListItem>();
loc = new PVector(x, y);
dim = new PVector(w, h);
}
void addItem(String[] data) {
items.add(new ListItem(data, items.size()));
}
void update() {
if(mousePressed && mouseX > loc.x && mouseX < loc.x + dim.x && mouseY > loc.y && mouseY < loc.y + dim.y) {
int over = (int) (mouseY - (loc.y + 5)) / 20;
if(over > -1 && over < items.size())
selected(over);
}
}
void display() {
strokeWeight(1);
stroke(0);
fill(250);
rect(loc.x, loc.y, dim.x, dim.y);
textSize(12);
textAlign(LEFT, TOP);
noStroke();
float down = 0;
boolean dark = false;
for(ListItem item : items) {
if(dark)
fill(204);
else
fill(250);
rect(loc.x + 1, loc.y + 1 + down, dim.x - 1, 20 - 1);
fill(0);
float over = 0;
for(String data : item.data) {
if(textWidth(data + "...") > ((dim.x - 10) / item.data.length) - 5) {
while(textWidth(data + "...") > ((dim.x - 10) / item.data.length) - 5) {
data = data.substring(0, data.length() - 1);
}
data += "...";
}
text(data, loc.x + 5 + over, loc.y + 3 + down);
over += (dim.x - 10) / item.data.length;
}
down += 20;
dark = !dark;
}
//stroke(0);
//line(loc.x, loc.y + down, loc.x + dim.x, loc.y + down);
if(dark)
fill(204);
else
fill(250);
rect(loc.x + 1, loc.y + 1 + down, dim.x - 1, dim.y - (down + 1));
}
abstract void selected(int id);
}
class ListItem {
int id;
String[] data;
ListItem(String[] data, int id) {
this.id = id;
this.data = data;
}
}
abstract class PlayBar {
PVector loc;
PVector dim;
PlayBar(float x, float y, float w, float h) {
loc = new PVector(x, y);
dim = new PVector(w, h);
}
void update() {
if(mousePressed && over())
updateProgress(map(mouseX - loc.x, 0, dim.x, 0, 100));
}
void display() {
strokeWeight(1);
stroke(0);
fill(250);
rect(loc.x, loc.y, dim.x, dim.y);
fill(0);
rect(loc.x, loc.y, map(getComplete(), 0, 100, 0, dim.x), dim.y);
}
boolean over() {
return (mouseX > loc.x && mouseX < loc.x + dim.x && mouseY > loc.y && mouseY < loc.y + dim.y);
}
abstract void updateProgress(float skip);
abstract float getComplete();
}
abstract class PlayPauseButton extends Button {
PlayPauseButton(float x, float y, float w, float h) {
super(x, y, w, h);
}
void display() {
strokeWeight(2);
stroke(0);
if(!over())
fill(255);
else
fill(0);
rect(loc.x, loc.y, dim.x, dim.y);
noStroke();
if(!over())
fill(0);
else
fill(255);
if(!isPlaying()) {
triangle(loc.x + dim.x / 4, loc.y + dim.y / 4, loc.x + dim.x / 4, loc.y + dim.y / 4 * 3, loc.x + dim.x / 4 * 3, loc.y + dim.y / 2);
} else {
rect(loc.x + dim.x / 8 * 2, loc.y + dim.y / 4, dim.x / 5, dim.y / 2);
rect(loc.x + dim.x / 8 * 6, loc.y + dim.y / 4, -dim.x / 5, dim.y / 2);
}
}
abstract boolean isPlaying();
}
abstract class Slider {
PVector loc;
PVector dim;
boolean dragging;
Slider(float x, float y, float w, float h) {
loc = new PVector(x, y);
dim = new PVector(w, h);
}
void update() {
if(mousePressed && over()) {
updateValue(constrain(map(mouseX - loc.x, 0, dim.x, 0, 100), 0, 100));
dragging = true;
}
}
void updateDrag() {
if(mousePressed && dragging)
updateValue(constrain(map(mouseX - loc.x, 0, dim.x, 0, 100), 0, 100));
}
void updateRelease() {
dragging = false;
}
void display() {
strokeWeight(1);
stroke(0);
fill(250);
rect(loc.x, loc.y, dim.x, dim.y);
fill(0);
rect(loc.x, loc.y, map(getValue(), 0, 100, 0, dim.x), dim.y);
}
boolean over() {
return (mouseX > loc.x && mouseX < loc.x + dim.x && mouseY > loc.y && mouseY < loc.y + dim.y);
}
abstract void updateValue(float value);
abstract float getValue();
}

EDIT: I've had some time to play with your MP3 player and find that it works quite well. In general, I prefer it when I can see the song that I'm going to start playing when I click the skip button (but that's just a preference). Perhaps you could make it so that the file chooser retains its previous folder when reopened to make it easier to navigate. Also, nice tooltips...

Chrisir

Replies(16)

Statistics

Tags

Actions

Related Posts