Looping through array: performance problem

Programming Questions

ankuanku

Looping through array: performance problem

in Programming Questions • 8 months ago

Hi there,

I have a performance problem with my Processing-code and hours of pondering about it rather drove me crazy instead of making it any better. I have to say that do not have too much experience in _good_ coding with lots of elegance, it just always worked out somehow. Maybe some elegance is needed here.. Thank you for reading!

=== About the project: woody ===

So, this script is about controlling an arduino, who controls two steppers (x and y) and a servo to sort of "write" with a soldering iron pixel per pixel. Cnc-like. Processing first prepares an image and sends coordinates and brightness for a pixel to arduino. When Arduino says: "go on", Processing sends the next pixel and so on. So when Arduino calls, the data need to be ready to send, and here lies the problem.

=== Problem ===

Within setup(), a 2d-array (braunmapB[][]) is created to store all pixels of an image.
Each pixel has a certain brightness that is being translated to miliseconds (for the soldering iron to burn on the workpiece). When the brightness is below a certain threshold, it is 0 in the array (no burning). So far, so good.

Called by setup():

void initBild() {
braunmapB = new int[img.width][img.height]; // ms Braunwerte
for (int gridY = 0; gridY < img.height; gridY++) {
for (int gridX = 0; gridX < img.width; gridX++) {
color farbe = img.get(gridX, gridY);
float braunwert =red(farbe)*0.222+green(farbe)*0.707+blue(farbe)*0.071;
float braunwertRGB = braunwert;
braunwert = map(braunwert, 255, 0, brenndauerHell, brenndauerDunkel);
if (braunwert < schwellenwert) { // Schwellenwert unterschritten
braunmapB[gridX][gridY] = 0;
braunwert = 0;
}
else {
braunmapB[gridX][gridY] = int(braunwert);
pointsToBurn++;
noStroke();
if (firstInit) {
braunXLast = gridX;
braunYLast = gridY;
firstInit = false;
}
fill(255-int(braunwertRGB));
rect (gridX+21+10+img.width, gridY+276, 1, 1);
}
}
}
}

Within draw(), the following function picks the next pixel and sends it to arduino (if > 0). The bold part is crucial: Every second row of the array is read backwards, so that when a full row of pixels has been sent to the arduino, the next pixel sent is at the same (or near) x position but in the next row. That means an improvement of speed, because the soldering iron doesnt always have to revert to the first colum.

void brennePunkt() {
if (burning && !burningFinish) { // burning-button betätigt und nicht fertig gebrannt
if (braunmapB[braunX][braunY] > 0) { // sende kein weiß an Woody
// X
woodyControlFull = woodyControl[2] + (braunX*int(multiX)) + "/";
myPort.write(woodyControlFull);
// Y
woodyControlFull = woodyControl[3] + (braunY*int(multiY)) + "/";
myPort.write(woodyControlFull);
// B
int braunwertOut = braunmapB[braunX][braunY];
woodyControlFull = woodyControl[4] + braunwertOut +"/";
myPort.write(woodyControlFull);
woodyReady = false;
pointsPosition++;
}
if (zeile == 0) { // Zeile 0
if (braunX + 1 == img.width) { // Zeile 0 (links -> rechts) durch
zeile = 1;
if (braunY+1 == img.height) {
burningFinish = true;
}
else {
braunY++;
}
}
else { // Zeile 0 noch nicht durch
braunX++;
}
}
else { // Zeile 1
if (braunX == 0) { // Zeile 1 (rechts -> links) durch
zeile = 0;
if (braunY+1 == img.height) {
burningFinish = true;
}
else {
braunY++;
}
}
else { // Zeile 1 noch nicht durch
braunX--;
}
}
}
}

The code works but is just too slow, because I think all the if/else cases to go through the array is not very fast. If the image contains lots of fileds that are just 0 (where the coordniates and brightness are not sent to the arduino), the loop will have to pass all of these, before there is a pixel to send.
I don't really know, how to avoid this, maybe there is another way to flip every second row in the array and have the next valid value at call...?

I'd love to hear your opinions about it, maybe just a basic appoach. And sorry for the german variables and comments, but I think it should be readable though..

Best, Philip

Replies(9)

PhiLho

Re: Looping through array: performance problem

8 months ago

IMHO, the slowdown might come actually from the myPort.write() instruction. Comment it out and see if there is an improvement. If not, perhaps the culprit is elsewhere in the code.

ankuanku

Re: Looping through array: performance problem

8 months ago

Thaks for your comment, but I am afraid myPort.write() is not causing the slowness, because there is a long delay when the script loops through blank areas of the image, (value 0). Then there is not myPort.write().
It must be somewhere else..

GoToLoop

Re: Looping through array: performance problem

8 months ago

Can you also publish setup() and the global variables parts?
For example, why do you need to convert variables multiX & multiX to int?

Have you noticed that you need to increase braunX when braunY is even; and decrease it otherwise?

Is your program button-click based? That is, you just need to refresh the screen when a user clicks a button?
If yes, just turn off draw() w/ noLoop(). And use redraw() within mousePressed()!

ankuanku

Re: Looping through array: performance problem

7 months ago

Hi,

I attached the whole script below for a better understanding.

The multiX and Y are the multipliers to sync the run of the stepper motors, which have different step sizes. The simple protocol I set up for communicaton with Arduino is not able to transmit floats (or at least I think so), so I convert them first to int.
But this only happens, when an actual value (not 0) pixel is being sent. I think the delay happens while parsing the array and passing all the 0 values.

> Have you noticed that you need to increase braunX when braunY is even; and decrease it otherwise?

I am sorry, I can't follow you here..

The script needs some user clicking to start (sending initial parameters to Arduino and initialise burning). I do not need to refresh (at least I do not do it). Might this slow down everything? I will try as you suggested..

best
Philip

import controlP5.*;
import processing.serial.*;
boolean debug = true;
// Variablen Processing
String imageToLoad = "BollesTools.png";
int brenndauerHell = 0;
int brenndauerDunkel = 800; // pappel // werden in P auf 0-255 gemappt
int schwellenwert = 1; // darunter wird nicht gebrannt. in ms
float multiX = 4; //2
float multiY = 8.5; //5
// Setup an Woody
boolean demoMode = true;
int servoStandbyDauer = 60;
int servoBurn = 51; // Burnposition: 4mm (Pappel?)
int tempMax = 118;
int schriftfarbe = 200;
ControlP5 controlP5;
Numberbox nx;
Serial myPort;
PFont myFont;
String[] woodyControl = new String[10]; //anpassen!
String[] inputLabels = new String[5]; //anpassen!
boolean woodyReady = false;
boolean woodySetupOk = false;
boolean woodyDoneX = false;
boolean woodyDoneY = false;
boolean woodyDoneZ = false;
int temperatur;
boolean heize = false;
String message = null;
String woodyControlFull; // geht jew raus.
PImage img;
boolean burning = false;
boolean burningFinish = false;
int zeile = 0;
boolean firstInit = true; // erster punkt fürs grüne überschreiben
int[][] braunmapB; // Braunwert ms
int braunX = 0; // 2D-Koordinaten für braunmapB, hier wird der aktuelle Punkt gespeichert
int braunY = 0;
int[] braunmapX = new int[0];
int[] braunmapY = new int[0];
float[] braunmapB = new float[0]; // Braunwert ms
int[] braunmapRGB = new int[0]; // Braunwert RGB
int braunXLast;
int braunYLast;
int pointsToBurn = 0;
int pointsPosition = 0;
float laufzeit;
float restlaufzeit;
int laufzeitDisplaySek;
int laufzeitDisplayMin;
int restlaufzeitDisplaySek;
int restlaufzeitDisplayMin;
// Action an Woody / manuell ein pixel
int gotoX = 0;
int gotoY = 0;
int brenndauer = 0;
void setup() {
size(560, 600);
background(70);
frameRate(30);
smooth();
// fill(10);
// rect(0, 0, 560, 600); // Hintergrund
myFont = createFont("Helvetica", 12, true);
textFont(myFont);
img = loadImage(imageToLoad);
img.loadPixels();
image(img, 21, 276); // könnte beim brennen überschrieben werden
initBild();
// Befehle an Woody
// Wertzuweisungen müssen im Setup stehen
woodyControl[2] = "2/1/"; // Fahre zu x -> + Position/
woodyControl[3] = "2/2/"; // Fahre zu y -> + Position/
woodyControl[4] = "2/3/"; // Brenne -> + Brenndauer/
woodyControl[5] = "3/1/"; // demomode
woodyControl[6] = "3/2/"; // servoStandbyDauer
woodyControl[7] = "3/3/"; // servoBurn - Kontaktposition
woodyControl[9] = "3/5/"; // tempMax
// Input-Labels
inputLabels[0] = "";
inputLabels[1] = "Upload";
inputLabels[2] = "go!";
inputLabels[3] = "burn!";
inputLabels[4] = "pause!";
controlP5 = new ControlP5(this);
ControlGroup l = controlP5.addGroup("Brenne Punkt", 20, 20, 200);
controlP5.addNumberbox("xAchse", gotoX, 10, 10, 40, 15)
.setGroup(l)
//.setMultiplier(10)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 2600);
controlP5.addNumberbox("yAchse", gotoY, 60, 10, 40, 15)
.setGroup(l)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 6500);
controlP5.addNumberbox("Brenndauer", brenndauer, 110, 10, 40, 15)
.setGroup(l)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 255);
controlP5.addButton(inputLabels[2], 1, 160, 10, 30, 15).setGroup(l);
//controlP5.addButton(inputLabels[1], 1, 10,40, 120, 20).setGroup(l);
l.setBackgroundColor(color(100));
l.setBackgroundHeight(45);
ControlGroup s = controlP5.addGroup("Setup an Woody", 20, 85, 200);
controlP5.addToggle("DemoMode", demoMode, 10, 10, 40, 40)
.setGroup(s);
controlP5.addNumberbox("ServoWarteDauer", servoStandbyDauer, 80, 10, 110, 15)
.setGroup(s)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 500);
controlP5.addNumberbox("PositionHolz", servoBurn, 80, 45, 110, 15)
.setGroup(s)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 500);
controlP5.addNumberbox("TempMax", tempMax, 80, 80, 110, 15)
.setGroup(s)
.setDirection(Controller.HORIZONTAL)
.setRange(0, 500);
s.setBackgroundColor(color(100));
s.setBackgroundHeight(150);
controlP5.addButton(inputLabels[1], 1, 10, 115, 40, 15)
.setGroup(s);
ControlGroup b = controlP5.addGroup("Burn, baby burn!", 400, 20, 140);
b.setBackgroundColor(color(150));
b.setBackgroundHeight(70);
controlP5.addButton(inputLabels[3], 1, 10, 10, 40, 15)
.setGroup(b);
controlP5.addButton(inputLabels[4], 1, 60, 10, 40, 15)
.setGroup(b);
/* nx = controlP5.addNumberbox("BrennPunkt", imgPunkt+1, 10, 35, 40, 15)
.setGroup(b)
.setRange(0, braunmapX.length)
.setDirection(Controller.HORIZONTAL);*/
myPort = new Serial(this, Serial.list()[0], 57600);
myPort.clear();
println("Warte bis Woody bereit ist...");
}
void initBild() {
// Erster Schritt
// Bild zunächst in 2D-Array übertragen, dabei in Grauwerte konvertieren
// Eins zu eins Übertragung, 0 steht für Nicht-Brennen
braunmapB = new int[img.width][img.height]; // ms Braunwerte
for (int gridY = 0; gridY < img.height; gridY++) {
for (int gridX = 0; gridX < img.width; gridX++) {
color farbe = img.get(gridX, gridY);
//float braunwert = (red(farbe)+green(farbe)+blue(farbe))/3;
float braunwert =red(farbe)*0.222+green(farbe)*0.707+blue(farbe)*0.071;
float braunwertRGB = braunwert;
braunwert = map(braunwert, 255, 0, brenndauerHell, brenndauerDunkel);
if (braunwert < schwellenwert) { // Schwellenwert unterschritten
braunmapB[gridX][gridY] = 0;
braunwert = 0;
}
else {
braunmapB[gridX][gridY] = int(braunwert);
pointsToBurn++;
noStroke();
if (firstInit) {
braunXLast = gridX;
braunYLast = gridY;
firstInit = false;
}
fill(255-int(braunwertRGB));
rect (gridX+21+10+img.width, gridY+276, 1, 1);
}
laufzeit = laufzeit + braunwert + servoStandbyDauer; // ms
}
}
if (debug) {
println(pointsToBurn+" zu brennende Punkte");
}
restlaufzeit = laufzeit;
laufzeitDisplaySek = (int(laufzeit)/1000);
laufzeitDisplayMin = laufzeitDisplaySek / 60;
laufzeitDisplaySek = laufzeitDisplaySek - (laufzeitDisplayMin * 60);
// Zweiter Schritt: Sortieren.
// Jede zweite Zeile wird abwechselnd von rechts oder links angefahren.
}
// Greift sich den nächsten Pixel und sendet Koordinaten und Braunwert
// an Woody, wenn dieser bereit ist.
void brennePunkt() {
if (burning && !burningFinish) { // burning-button betätigt und nicht fertig gebrannt
if (braunmapB[braunX][braunY] > 0) { // sende kein weiß an Woody
if (debug) {
println("Punkt x="+braunX+" y="+braunY+" b="+braunmapB[braunX][braunY]+"(ms)");
}
fill(0, 180, 0); // letzten punkt grün färben
rect (braunXLast+21+10+img.width, braunYLast+276, 1, 1);
fill(255, 0, 0); // aktuellen punkt rot färben
rect (braunX+21+10+img.width, braunY+276, 1, 1);
braunXLast = braunX;
braunYLast = braunY;
// X
woodyControlFull = woodyControl[2] + (braunX*int(multiX)) + "/";
myPort.write(woodyControlFull);
// Y
woodyControlFull = woodyControl[3] + (braunY*int(multiY)) + "/";
myPort.write(woodyControlFull);
// B
int braunwertOut = braunmapB[braunX][braunY];
woodyControlFull = woodyControl[4] + braunwertOut +"/";
myPort.write(woodyControlFull);
woodyReady = false;
restlaufzeit = restlaufzeit - braunmapB[braunX][braunY] - servoStandbyDauer;
pointsPosition++;
}
if (zeile == 0) { // Zeile 0
if (braunX + 1 == img.width) { // Zeile 0 (links -> rechts) durch
zeile = 1;
if (braunY+1 == img.height) {
burningFinish = true;
}
else {
braunY++;
}
}
else { // Zeile 0 noch nicht durch
braunX++;
}
}
else { // Zeile 1
if (braunX == 0) { // Zeile 1 (rechts -> links) durch
zeile = 0;
if (braunY+1 == img.height) {
burningFinish = true;
}
else {
braunY++;
}
}
else { // Zeile 1 noch nicht durch
braunX--;
}
}
}
if (burning && burningFinish) {
fertigGebrannt();
}
}
void fertigGebrannt() {
println("Gehe in Demomodus");
woodyControlFull = woodyControl[5]+1+"/"; // Demomodus = 1
myPort.write(woodyControlFull);
demoMode = true;
println("Fahre auf Standbyposition");
woodyControlFull = woodyControl[2]+0+"/"; // X = 0
myPort.write(woodyControlFull);
woodyControlFull = woodyControl[3]+0+"/"; // Y = 0
myPort.write(woodyControlFull);
woodyControlFull = woodyControl[4]+0+"/"; // Braunwert = 0
myPort.write(woodyControlFull);
woodyReady = false;
burning = false;
burningFinish = false;
println("Fertig gebrannt! WOHOOO!");
}
void serialEvent(Serial bla) // Is called everytime there is new data to read
{
message = myPort.readStringUntil('*');
// just if there is data
if (message != null) {
String[] messageItem = split(message, '*');
//println(messageItem[0]);
if (messageItem[0].equals("A")) {
woodyReady = true;
println("WOODY: ALL RIGHT!");
}
else if (messageItem[0].equals("X")) {
woodyDoneX = true;
print("WOODY: x: ok");
}
else if (messageItem[0].equals("Y")) {
woodyDoneY = true;
print(" y: ok");
}
else if (messageItem[0].equals("Z")) {
woodyDoneZ = true;
println(" burn: ok");
println("");
}
if (woodyDoneX && woodyDoneY && woodyDoneZ) {
woodyDoneX = false;
woodyDoneY = false;
woodyDoneZ = false;
woodyReady = true;
}
else if (messageItem[0].equals("S")) {
woodySetupOk = true;
//woodyReady = true;
println("WOODY: SETUP OK!");
}
else if (messageItem[0].equals("T")) {
woodySetupOk = false;
//woodyReady = true;
println("WOODY: SETUP NICHT OK!");
}
else if (messageItem[0].equals("F")) {
woodyReady = true;
println("WOODY: FEHLER! (Maximalpositionen überschritten?)");
}
else if (messageItem[0].equals("H")) {
heize = true;
//println("WOODY: HEIZE!");
}
else if (messageItem[0].equals("I")) {
heize = false;
//println("WOODY: HEIZE NICHT MEHR!");
}
else if (int(messageItem[0]) > 0) {
temperatur = int(messageItem[0]);
}
}
}
void controlEvent(ControlEvent theEvent) {
if (theEvent.isController()) {
if (theEvent.controller().name()==inputLabels[2]) { // Brenne Punkt
if (theEvent.controller().value()==1) {
if (woodyReady && woodySetupOk) {
// x
woodyControlFull = woodyControl[2]+gotoX+"/";
println(woodyControlFull);
myPort.write(woodyControlFull);
// y
woodyControlFull = woodyControl[3]+gotoY+"/";
println(woodyControlFull);
myPort.write(woodyControlFull);
// Burn
float braunwert = map(brenndauer, 255, 0, brenndauerHell, brenndauerDunkel);
int braunwertOut = int(braunwert);
woodyControlFull = woodyControl[4]+braunwertOut+"/";
println(woodyControlFull);
myPort.write(woodyControlFull);
woodyReady = false;
}
else {
println("STOP: Woody ist beschäftigt!");
}
}
}
if (theEvent.controller().name()==inputLabels[1]) { // Setup-Upload
if (theEvent.controller().value()==1) {
if (woodyReady) {
// demomode
int demoModeOut;
if (demoMode) {
demoModeOut = 1;
}
else {
demoModeOut = 0;
}
println("Sende Setup");
woodyControlFull = woodyControl[5]+demoModeOut+"/";
/* print("Demomode: ");
print(demoMode);
print(". ");
println(woodyControlFull);*/
myPort.write(woodyControlFull);
// servoStandbyDauer
woodyControlFull = woodyControl[6]+servoStandbyDauer+"/";
/* print("Servo Standby Dauer: ");
print(servoStandbyDauer);
print(". ");
println(woodyControlFull); */
myPort.write(woodyControlFull);
// servoBurn
woodyControlFull = woodyControl[7]+servoBurn+"/";
/* print("Servo Kontaktposition Holz: ");
print(servoBurn);
print(". ");
println(woodyControlFull);*/
myPort.write(woodyControlFull);
// tempMax
woodyControlFull = woodyControl[9]+tempMax+"/";
/* print("Temperatur Maximum: ");
print(tempMax);
print(". ");
println(woodyControlFull);*/
myPort.write(woodyControlFull);
woodyReady = false;
}
else {
println("STOP: Woody ist beschäftigt!");
}
}
}
if (theEvent.controller().name()==inputLabels[3]) { // BURN IMAGE Punkt für Punkt
if (theEvent.controller().value()==1) {
if (woodyReady && woodySetupOk) {
burning = true;
}
else {
println("STOP: Woody ist beschäftigt!");
}
}
}
if (theEvent.controller().name()==inputLabels[4]) { // Pause
if (theEvent.controller().value()==1) {
burning = false;
}
}
}
}
// Brenne Punkt
void xAchse(int zuX) {
gotoX = zuX;
}
void yAchse(int zuY) {
gotoY = zuY;
}
void Brenndauer(int wieLang) {
brenndauer = wieLang;
}
// Setup
void DemoMode(int bla) {
if (bla == 1) {
demoMode = true;
}
else {
demoMode = false;
}
}
void ServoWarteDauer(int bla) {
servoStandbyDauer = bla;
}
void PositionHolz(int bla) {
servoBurn = bla;
}
/*void TempMin(int bla) {
tempMin = bla;
}*/
void TempMax(int bla) {
tempMax = bla;
}
// Burn, baby burn!
/*void BrennPunkt(int bla) {
imgPunkt = bla-1;
}*/
void draw() {
smooth();
//noFill();
//stroke(105, 199, 211);
//rect(20, 275, (img.width+1), (img.height+1)); // Rahmen ums Bild
noStroke();
fill(70);
rect(235, 20, 160, 120); // Hintergrund für Schrift machts schön glatt...
if (woodyReady) { // Woody ready
fill(5, 202, 50);
}
else {
fill(200, 38, 5);
}
rect(240, 22, 8, 8);
fill(schriftfarbe);
text("Woody Status", 255, 30);
if (woodySetupOk) { // Woody Setup
fill(5, 202, 50);
}
else {
fill(200, 38, 5);
}
rect(240, 42, 8, 8);
fill(schriftfarbe);
text("Woody Setup", 255, 50);
if (demoMode) { // Heizen
fill(57, 63, 250); // mitternachtsblau
rect(240, 62, 8, 8);
fill(schriftfarbe);
text("Demomodus: kalt", 255, 70);
}
else if (heize) {
fill(248, 95, 56); // orange
rect(240, 62, 8, 8);
fill(schriftfarbe);
text("heize", 255, 70);
}
else {
fill(255, 236, 90); // gelb
rect(240, 62, 8, 8);
fill(schriftfarbe);
text("heize nicht", 255, 70);
}
restlaufzeitDisplaySek = (int(restlaufzeit)/1000);
restlaufzeitDisplayMin = restlaufzeitDisplaySek / 60;
restlaufzeitDisplaySek = restlaufzeitDisplaySek - (restlaufzeitDisplayMin * 60);
fill(schriftfarbe);
text("Laufzeit: " + laufzeitDisplayMin + " Min " + laufzeitDisplaySek + " Sek", 240, 90);
text("Restlaufzeit: " + restlaufzeitDisplayMin + " Min " + restlaufzeitDisplaySek + " Sek", 240, 110);
fill(schriftfarbe);
text("Temperatur: " + temperatur + " °", 240, 130);
// Horiz Linie Status/Setup
//stroke(200);
//line(240,63, 380,63);
// Brennstatus: Statusbalken
fill(80);
rect(20, 250, 360, 8);
fill(5, 202, 50);
float brennStatus = map(pointsPosition, 0, pointsToBurn, 0, 360);
int brennStatusOut = int(brennStatus);
rect(20, 250, brennStatusOut, 8);
if (woodyReady && woodySetupOk) {
brennePunkt();
}
}

GoToLoop

Re: Looping through array: performance problem

7 months ago

Hey ankuanku!

1st of all, I'd like to give ya some tips about variable declarations.

You see, your program has lotsa variables.
And do you remember that I've asked ya 'bout variables multiX & multiY, right?

Checking them out, I've found out that they were declared as float.
However, the only places they're used in your whole program are at lines #199 & #202.
And you convert them all to int() before using them in your math expression!
So I ask you: Why not declare them as int from the beginning anyways?

Also, you do not assign different values to them later after their declaration.
Thus, they have constant values throughout your code!

It's a very good practice to declare such global field variables as final.
Even better, final static!
Doing so, you both state their intention usage and make their access faster across your program!

Here's how to do it:

final static int multiX = 4, multiY = 8;

You may try to find more variables which are constant and do that to them as well!

Another tip is about local variables:
If you have variables which are only temporary within a function/method.
That is, the other functions don't need to know what value was stored in them from another 1.
Rather than declaring them as global field variables, declare them inside the function which needs them.
Local variables are faster than global field ones. Except if the latter are final ones!

GoToLoop

Re: Re: Looping through array: performance problem

7 months ago

Now, about your function brennePunkt().

I've ended up splitting it into 3 more functions:

naechstenPunkt()
checkenFinish()
zeichnenPunkt()

I believe what you wanted was to skip all braunmapB[ braunX][ braunY] == 0, right?
So, I did a while block, looping until it finds a non-zero value.
When it finds instead a zero value, it calls function naechstenPunkt() to get next coordinates.
Or until array is finished!

With this strategy, brennePunkt() plots at least 1 point within a draw() cycle,
instead of previous behavior which coulda just returned w/o doing anything but setting next point!

Have you noticed that you need to increase braunX when braunY is even; and decrease it otherwise?
I am sorry, I can't follow you here...

Within naechstenPunkt(), I use :

  if (braunY % 2 == 0) {..};

to determine whether braunX should increase or decrease.

As you can notice, it uses the modulo of current braunY by 2
to determine whether it's an even or an odd value.

Later, either the if or the else if block are executed,
that is, to increase (go right) or decrease (go left) braunX!
Hope you were able to understand it now!

... I do not need to refresh (at least I do not do it)...

Unfortunately, library controlP5 kinda demands draw() to loop constantly I'm afraid.

However, you may try to lower the FPS using for example -> frameRate (30);

GoToLoop

Re: Re: Looping through array: performance problem

7 months ago

Now's the tweaked functions.
Hope it can make some difference for you!

void brennePunkt() {

  if (!burning)    return;

  while (braunmapB[braunX][braunY] == 0) {
    naechstenPunkt();

    if (burningFinish) {
      fertigGebrannt();
      return;
    }
  }

  zeichnenPunkt();

  int braunwertOut = braunmapB[braunX][braunY];

  myPort.write( woodyControl[2] + (braunX*multiX) + "/" );
  myPort.write( woodyControl[3] + (braunY*multiY) + "/" );
  myPort.write( woodyControl[4] + braunwertOut + "/" );

  woodyReady = false;
  ++pointsPosition;
  restlaufzeit = restlaufzeit - braunwertOut - servoStandbyDauer;

  naechstenPunkt();

  if (burningFinish)    fertigGebrannt();
}

void naechstenPunkt() {

  if (braunY % 2 == 0) {
    if ( ++braunX == img.width ) {
      --braunX;
      checkenFinish();
    }
  }

  else if ( --braunX < 0 ) {
    ++braunX;
    checkenFinish();
  }
}

void checkenFinish() {

  if ( ++braunY == img.height ) {
    burningFinish = true;
    braunX = 0;
    braunY = 0;
    braunXLast = 0;
    braunYLast = 0;
  }
}

void zeichnenPunkt() {

  fill(#00B400);
  rect (braunXLast + 31 + img.width, braunYLast + 276, 1, 1);

  fill(#FF0000);
  rect (braunX + 31 + img.width, braunY + 276, 1, 1);

  braunXLast = braunX;
  braunYLast = braunY;
}

ankuanku

Re: Looping through array: performance problem

7 months ago

Hi GoToLoop,

wow, thank you so much, you really took some effort to go through the code. Also, localizing the new functions is very beautiful to look at =)

I think I understand well what you explained. So I followed your suggestions, cleaned up the code, pasted your modifications and changed variables where possible. Can't wait to try it out when I am home again!

So thanks again, I will post the results of the next run..

best, Philip

ankuanku

Re: Looping through array: performance problem

7 months ago

Hello again,

I tested your changes and it works like a charm now! Thank you again, your notes really helped my to better understand the code.

Best, Philip