loadStrings() question

Programming Questions

milesking..

in Programming Questions • 4 months ago

So I have a text file called list.txt, and it has this in it:

750

500

600

300

1100

550

600

899

500

750

350

and I used the loadStrings() function to import it into the file. But I have a problem.

What Im trying to do is use those values for the x and y coordinates for an object I make at the setup.

void setup() {

size(1500, 700, P3D);

// start with one ball

balls.add( new Ball(width/2, 0, 0));

background(0);

}

Where it says Ball(width/2, 0, 0)) Im trying to replace width/2, 0 with two values from the txt file, such as the first two (750, 500). How would I go about doing this?

Replies(7)

Jan Vanto..

Re: loadStrings() question

4 months ago

The best thing would be if you add your X/Y coordinates in a .csv (comma separated values) file. The first value is X, the second one is Y.

100, 200

300, 400

700, 280

This code should do the trick:

void setup()

{

size( 1500, 700, P3D );

String[] lines = loadStrings("balls.csv");

for ( int i = 0; i < lines.length; i++ ) {

String[] coordinates = trim( split( lines[i], ',' ) );

float x = float( coordinates[ 0 ] );

float y = float( coordinates[ 1 ] );

balls.add( new Ball( x, y, 0 ) );

}

milesking..

Re: loadStrings() question

4 months ago

The code tells me that it cannot find anything named lines

Jan Vanto..

Re: loadStrings() question

4 months ago

You probably forgot this line?

String[] lines = loadStrings("balls.csv");

This uses the loadStrings() function to load the text file into a String arary.

GoToLoop

Re: loadStrings() question

4 months ago

Here's an example more in line w/ original post.

Although I agree a more compact csv (x, y) pair model would be better!

More examples @ link below:

http://forum.processing.org/topic/reading-arrays-from-a-text-file-please-help

import java.util.List;
final List<Ball> balls = new ArrayList();

final static String FILE_NAME = "coords.txt";

final static color BG = 0100;

void setup() {
  size(1500, 700, P2D);
  smooth();

  fill(Ball.FG);
  stroke(0);
  strokeWeight(2);

  initCoords();
}

void draw() {
  background(BG);

  for (Ball b: balls)  b.script();
}

void initCoords() {
  final int[] coords = int( loadStrings(FILE_NAME) );

  for (int row = 0; row != coords.length;
    balls.add( new Ball(coords[row++], coords[row++]) ));
}

final class Ball {
  static final short DIM = 30;
  static final color FG = #FFFF00;

  short x, y;

  Ball(int xx, int yy) {
    x = (short) xx;
    y = (short) yy;
  }

  void script() {
    update();
    display();
  } 

  void update() {
    x += random(1) < .5 ? -1 : 1;
    y += random(1) < .5 ? -1 : 1;
  }

  void display() {
    ellipse(x, y, DIM, DIM);
  }
}

milesking..

Re: loadStrings() question

4 months ago

Thanks, Im sure itll work.

Im only running into problems actually running the file. It says its missing or inaccessible , even though its already been added to the data folder multiple times. :/

GoToLoop

Re: loadStrings() question

4 months ago

Press <CTRL> + K to open up current's sketch folder.

Check out whether there is a data subfolder there.

And inside /data, the "coords.txt" file!

GoToLoop

Re: loadStrings() question

4 months ago

To assure loadString() will read from correct path, use function dataPath().

See initCoords() modified to use it:

void initCoords() {
  final String path = dataPath(FILE_NAME);
  
  final int[] coords = int( loadStrings(path) );

  for (int row = 0; row != coords.length;
    balls.add( new Ball(coords[row++], coords[row++]) ));
}

Top Reply