loadStrings and analysing the line, help?

Programming Questions

xdemonx456

loadStrings and analysing the line, help?

in Programming Questions • 1 year ago

Hello and thanks for visiting my question,

What im trying to do is load a text document which has lots of lines of text and numbers (g-code to be exact). And i want to analyse each line and remove characters i dont want, then save this to a new text document.

The reason being is i have a custom made CNC and i want to take the G-Code and strip it so it only leaves the X Y and Z part. But the X Y and Z in the G-Code is arranged like this "X200 Y100 Z100" well i need it to be arranged like this "200X 100Y 100Z". I have this so far:

String[] lines; // file array
int index;
String current;

void setup(){
size(200, 200);

lines = loadStrings("GCode.txt");
println(Serial.list());

println("File is " + lines.length + " lines long");
}

void draw(){

if(index < lines.length){
    current = lines[index];
    println("Line " + index + ": " + lines[index]);
    index = index + 1;

}
}

But im not sure on how to check each line for characters i dont want, and remove them. I need to remove a decimal point, numbers and letters but only when in a certain order. For example "N153" i want to remove that completly from the text document but only when its arranged in that order, otherwise it could delete the nubmers in the X Y Z cord.

Any help would be amazing.

Thanks,

Calum.

Replies(8)

Chrisir

Re: loadStrings and analysing the line, help?

1 year ago

hello,

you need a for loop
at the end of setup().

In fact do all you do in setup(), draw is not needed, since you do it only once.

Go thru all lines.

Use split then with ' ' (space) as where to split (when there's spaces in each line).

Then another for loop over the result of the split, then remove X, N Y Z etc. and put it back together.

This only works when value for x,y and z is always in the same order...

Then write it to a nwew file with saveStrings I think.
http://www.processing.org/reference/saveStrings_.html

I can write you an example but then you need to be more precise as to which cases are there in your file ( For example "N153" meaning, you want to remove the whole line? Or is there still "200X 100Y 100Z" in that same line?).

Greetings, Chrisir

xdemonx456

Re: loadStrings and analysing the line, help?

1 year ago

Thanks for the quick reply,

Right so i can use saveStrings to save to a new document.
And ye but i dont know how to do the splitting and removal.

Ill give you 10 lines that are present in the text file of G-Code as an example

N060 G00 X279.5531 Y245.5999
N061 G00 Z000.500
N062 G01 X147.1669 Y245.5999
N063 G01 X147.158 Y245.6088
N064 G00 Z001.000
N065 G00 X147.1669 Y246.4001
N066 G00 Z000.500
N067 G01 X147.4857 Y246.4001
N068 G01 X279.2469 Y246.4001
N069 G01 X279.5531 Y246.4001
N070 G00 Z001.000

So in those lines, i need the first 2 sections removed for example, "N060" and "G00" then the "X279.5531" i need the decimal point removed, and then the X needs to be moved to the other side of the number, after it.

So if i had this in the G-Code text file "N067 G01 X147.4857 Y246.4001" i need it to output this in the new file "1474857X 2464001Y"

Thanks,

Calum.

Chrisir

Re: loadStrings and analysing the line, help?

1 year ago

here...

see below....

String lines[] = {
"N060 G00 X279.5531 Y245.5999",
// ------------------------------------------

calsign

Re: loadStrings and analysing the line, help?

1 year ago

You'll need the String functions, such as split() and substring().
See the String reference and the String functions (Go to Data > String Functions).

And... Chrisir beats me to it. Wow, I'm slow today...

Chrisir

Re: loadStrings and analysing the line, help?

1 year ago

this happend to me one hour ago....

xdemonx456

Re: loadStrings and analysing the line, help?

1 year ago

Thanks for your reply calsign.

And holy cow you are fast Chrisir. that is perfect just what i was looking for. Now i need to study this and work out how it does its job :)

Thanks you VERY much for your time, you have helped out a noob at processing alot and now my CNC may actually function as i wanted it to :)

Thanks again,

Calum.

Chrisir

Re: loadStrings and analysing the line, help?

1 year ago

new version...

// from http://forum.processing.org/topic/loadstrings-and-analysing-the-line-help
String lines[] = {
"N060 G00 X279.5531 Y245.5999",
"N061 G00 Z000.500",
"N062 G01 X147.1669 Y245.5999",
"N063 G01 X147.158 Y245.6088",
"N064 G00 Z001.000",
"N065 G00 X147.1669 Y246.4001",
"N066 G00 Z000.500",
"N067 G01 X147.4857 Y246.4001",
"N068 G01 X279.2469 Y246.4001",
"N069 G01 X279.5531 Y246.4001",
"N070 G00 Z001.000"
};
// String lines[] = loadStrings("GCode.txt");
//
// target
String arrayTarget[] = {
};
//
//
void setup ()
{
// 1st: show array ------------------------------------
println("there are " + lines.length + " lines");
for (int i=0; i < lines.length; i++) {
println(trim(lines[i]));
}
// 2nd: go thru ---------------------------------------
println ("===========================");
String buffer="";
println("there are " + lines.length + " lines");
//
// go thru lines
for (int i=0; i < lines.length; i++) {
print(lines[i] + " -> ");
lines[i] = trim(lines[i]);
lines[i] = lines[i].replace(".", "");
print(lines[i] + " >>>> ");
//
String[] arrayCurrentLine=split(lines[i], ' ');
buffer="";
// go thru the elements of one line
for (int j=0; j < arrayCurrentLine.length; j++) {
//
print(trim(arrayCurrentLine[j]) + ":");
arrayCurrentLine[j] = trim(arrayCurrentLine[j]);
arrayCurrentLine[j] = arrayCurrentLine[j].replace(".", "");
//
if (arrayCurrentLine[j].contains("X")) {
print("X,");
buffer=buffer+arrayCurrentLine[j].replace("X", "");
buffer=buffer+"X";
buffer=buffer+" ";
}
//
else if (arrayCurrentLine[j].contains("Y")) {
print("Y,");
buffer=buffer+arrayCurrentLine[j].replace("Y", "");
buffer=buffer+"Y";
buffer=buffer+" ";
}
//
else if (arrayCurrentLine[j].contains("Z")) {
print("Z,");
buffer=buffer+arrayCurrentLine[j].replace("Z", "");
buffer=buffer+"Z";
}
else {
print("/,");
}
//
// println("**");
} // for j
println("");
// if buffer is not empty, put it to array
if (!buffer.equals("")) {
arrayTarget = append ( arrayTarget, buffer );
}
} // for i
// ----------------------------------------
//
// 3rd: show --------------------------------------------
println("");
println ("++++++++++++++++++++++++++++++");
println("there are " + arrayTarget.length + " lines");
for (int i=0; i < arrayTarget.length; i++) {
println(trim(arrayTarget[i]));
}
// 4th: save -----------------------------------------------
println ("++++++++++++++++++++++++++++++");
// now write the strings to a file, each on a separate line
saveStrings("result.txt", arrayTarget);
println ("Done");
}
//
void draw() {
//
}
// ------------------------------------------

PhiLho

Re: loadStrings and analysing the line, help?

1 year ago

For the record, a little alternative, with regular expressions:

// Result of loadStrings
String[] loaded =
{
"N060 G00 X279.5531 Y245.5999",
"N061 G00 Z000.500",
"N062 G01 X147.1669 Y245.5999",
"N063 G01 X147.158 Y245.6088",
"N064 G00 Z001.000",
"N065 G00 X147.1669 Y246.4001",
"N066 G00 Z000.500",
"N067 G01 X147.4857 Y246.4001",
"N068 G01 X279.2469 Y246.4001",
"N069 G01 X279.5531 Y246.4001",
"N070 G00 Z001.000",
};
String[] newLines = new String[loaded.length];
Pattern patXY = Pattern.compile("N\\d+ G\\d+ X(\\d+)\\.\\d+ Y(\\d+)\\.\\d+");
Pattern patZ = Pattern.compile("N\\d+ G\\d+ Z(\\d+)\\.\\d+");
int i = 0;
for (String line : loaded)
{
Matcher matXY = patXY.matcher(line);
if (matXY.matches())
{
newLines[i++] = matXY.group(1) + "X " + matXY.group(2) + "Y";
}
else
{
Matcher matZ = patZ.matcher(line);
if (matZ.matches())
{
newLines[i++] = matZ.group(1) + "Z";
}
}
}
println(newLines);
exit();

Top Reply