line to line Collisions

Programming Questions

olga075

in Programming Questions • 5 months ago

Hi!

I made a program that draw 2 lines and they are not suppose to cross each other, but they do (if you run the program several times you'll see) and when they do it stops and there is a black circle appears))) That's funny, but what I did wrong here?

float x1=180;

float y1=400;
float x11=220;
float y11=400;

void setup() {
size(400, 400);
background(200);
}

void draw () {
float x2=x1+random(-10, 10);
float y2=y1-random(5);
line(x1, y1, x2, y2);
x1=x2;
y1=y2;

float x22=x11+random(-10,10);
float y22=y11-random(5);
line(x11, y11, x22, y22);
x11=x22;
y11=y22;

}

Replies(4)

amnon.owed

Re: line to line Collisions

5 months ago

Nothing in your program stops the lines from crossing. They move randomly, so it's not likely but still possible that they will cross. I don't see how the code you posted can cause the behavior you describe (program stopping, black circle). You were probably running different code or something.

olga075

Re: line to line Collisions

5 months ago

Oh! Sorry about that, This is the code. To see the black dot's you might need to run it several times.

float x1=180;

float y1=400;
float x11=220;
float y11=400;
float dx;

void setup() {
size(400, 400);
background(200);
}

void draw () {
float x2=x1+random(-10, 10);
float y2=y1-random(5);
float x22=x11+random(-10,10);
float y22=y11-random(5);
if (lineLine( x1, y1, x2, y2, x11, y11, x22, y22)==false) {
line(x1, y1, x2, y2);
x1=x2;
y1=y2;
line(x11, y11, x22, y22);
x11=x22;
y11=y22;
} else {}
}

boolean lineLine(float x1, float y1, float x2, float y2, float x3, float y3, float x4, float y4) {

float uA = ((x4-x3)*(y1-y3) - (y4-y3)*(x1-x3)) / ((y4-y3)*(x2-x1) - (x4-x3)*(y2-y1));
float uB = ((x2-x1)*(y1-y3) - (y2-y1)*(x1-x3)) / ((y4-y3)*(x2-x1) - (x4-x3)*(y2-y1));

if (uA >= 0 && uA <= 1 && uB >= 0 && uB <= 1) {

float intersectionX = x1 + (uA * (x2-x1));
float intersectionY = y1 + (uA * (y2-y1));
noStroke();
fill(0);
ellipse(intersectionX, intersectionY, 10,10);

return true;
}
else {
return false;
} }

amnon.owed

Re: line to line Collisions

5 months ago

General tip: press CTRL-T to autoformat your code.

Indeed this code will display the behavior you describe. Because that's what you tell it to do. First, the black circles are for the intersections. Second, the code doesn't stop. It's just that you call noStroke() at the first collision and after that never call stroke(0) again so the lines from that point on are invisible. Third, it's bad practice to draw stuff inside you collision detection. Instead of a boolean, just return the coordinates. Fourth, you only change some variables when they don't collide. The question is if you really want that. According to these points, I've made some changes to your code.

Adapted Code

float x1 = 180;
float y1 = 400;
float x11 = 220;
float y11 = 400;
float dx;
void setup() {
size(400, 400);
background(200);
}
void draw () {
float x2 = x1 + random(-10, 10);
float y2 = y1 - random(5);
float x22 = x11 + random(-10, 10);
float y22 = y11 - random(5);
stroke(0);
line(x1, y1, x2, y2);
line(x11, y11, x22, y22);
float[] isec = lineLine(x1, y1, x2, y2, x11, y11, x22, y22);
if (isec[0]>-1) {
noStroke();
fill(0);
ellipse(isec[0], isec[1], 10,10);
}
x1 = x2;
y1 = y2;
x11 = x22;
y11 = y22;
}
float[] lineLine(float x1, float y1, float x2, float y2, float x3, float y3, float x4, float y4) {
float uA = ((x4-x3)*(y1-y3) - (y4-y3)*(x1-x3)) / ((y4-y3)*(x2-x1) - (x4-x3)*(y2-y1));
float uB = ((x2-x1)*(y1-y3) - (y2-y1)*(x1-x3)) / ((y4-y3)*(x2-x1) - (x4-x3)*(y2-y1));
float[] intersection = { -1, -1 };
if (uA >= 0 && uA <= 1 && uB >= 0 && uB <= 1) {
intersection[0] = x1 + (uA * (x2-x1));
intersection[1] = y1 + (uA * (y2-y1));
}
return intersection;
}

olga075

Re: line to line Collisions

5 months ago

Thank you very much!

Top Reply