a little bit different to your version:



Dot dots[] = new Dot[0];

boolean drag = false;

void setup(){
  size(600,600);
  smooth();
  frameRate(60);
}


void draw(){
  background(255);
 
  for(int i = 0; i < dots.length; i++)
    dots[i].updateRotation();
 
 
  for(int i = 1; i < dots.length; i++){
    if( dots[i].break_point_ || dots[i-1].break_point_)
      continue;
    line(dots[i].x_, dots[i].y_, dots[i-1].x_, dots[i-1].y_);
  }
 
 
  if( drag ){
    Dot d_new = new Dot(mouseX, mouseY);
    dots = (Dot[]) append(dots, d_new);
  }
}



class Dot{
  float x_, y_;    // coordinate
  float rotation_; // current rotation
  float radius_;   // radius to center
  float cx_, cy_;  // center
  boolean break_point_;
 
  Dot(float x, float y){
    x_  = x;
    y_  = y;
    cx_ = width/2;
    cy_ = height/2;
    rotation_ = atan2(y_ - cy_, x_ - cx_);
    radius_ = dist(cx_, cy_, x_, y_);
  }
 
  void updateRotation(){
    rotation_ += 0.02;
    x_ = cx_ + radius_*cos(rotation_) ;
    y_ = cy_ + radius_*sin(rotation_) ;
  }
 
  void draw(){
    stroke(0); strokeWeight(1);
    point(x_, y_);
  }
 
  void breakPoint(boolean break_point){
    break_point_ = break_point;
  }
}



void mousePressed(){
  drag = true;
}
void mouseReleased(){
  drag = false;
  dots[dots.length-1].breakPoint(true);
}