Limited run of a classic example

Programming Questions

dumbdora

Limited run of a classic example

in Programming Questions • 2 years ago

This being my first post I am sorry that it has to be a question but every start is not easy. I need just to limit the run time of the Brownian motion line example at the Processing website for a custom amount of time or a possible mouse click. Also at the presumed end of the run I should get the last two coordinates that were randomly chosen in order to plot a little ellipse with them at that very spot.

Thanks in advance, and I feel welcomed already....

Replies(3)

amnon.owed

Re: Limited run of a classic example

2 years ago

I've adapted the Brownian motion example to incorporate the things you mentioned. I've included both limiting after a custom amount of frames (you could also use millis() instead of framecount) and on a mouse click. Check it out...

Code Example

int num = 2000;
int range = 6;
float[] ax = new float[num];
float[] ay = new float[num];
// arraylist to store the final point coordinates
ArrayList <PVector> finals = new ArrayList <PVector> ();
void setup() {
size(640, 360);
for(int i = 0; i < num; i++) {
ax[i] = width/2;
ay[i] = height/2;
}
}
void draw() {
background(51);
// Shift all elements 1 place to the left
for(int i = 1; i < num; i++) {
ax[i-1] = ax[i];
ay[i-1] = ay[i];
}
// Put a new value at the end of the array
ax[num-1] += random(-range, range);
ay[num-1] += random(-range, range);
// Constrain all points to the screen
ax[num-1] = constrain(ax[num-1], 0, width);
ay[num-1] = constrain(ay[num-1], 0, height);
// Draw a line connecting the points
for(int i=1; i<num; i++) {
float val = float(i)/num * 204.0 + 51;
stroke(val);
line(ax[i-1], ay[i-1], ax[i], ay[i]);
}
// display the final points
for (PVector v : finals) {
ellipse(v.x,v.y,4,4);
}
// every 180 frames
if (frameCount % 180 == 0) {
addFinalReset();
}
}
// on mouse pressed
void mousePressed() {
addFinalReset();
}
// add the final point to the final points and reset the numbers
void addFinalReset() {
finals.add(new PVector(ax[num-1],ay[num-1]));
for(int i = 0; i < num; i++) {
ax[i] = width/2;
ay[i] = height/2;
}
}

dumbdora

Re: Limited run of a classic example

2 years ago

Wow great implementation I am amazed. Just one more question...what should I do to stop it alltogether? not to draw a line after the ellipse is drawn.

Thanks again this is really insightful especially on the use of PVector.

amnon.owed

Re: Limited run of a classic example

2 years ago

Multiple ways. You could use noLoop() to stop the drawing. Or you could use a boolean. Place the majority of what's in draw in an if (yourBoolean) statement, except the code displaying the final points. Toggle the boolean with a mouse click or keypress.

Top Reply