Keep wordcram on sketch without calling noLoop?

fari

Keep wordcram on sketch without calling noLoop?

in Contributed Library Questions • 3 months ago

I would like to call draw() of wordcram in the main draw() method of my sketch. But the problem is that wordcram is drawn only once and disappears after being drawn. If I call noLoope() right after calling wordcram's draw() method, then the entire program stops, but wordcram remains there.

Please help! Thank you

Replies(10)

PhiLho

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Not knowing this library, so I give a generic advice: either make it to draw on a PGraphics, if possible, or draw on screen and use get() to capture this rendering.
Then you can use image() to draw the result on each frame.

fari

Re: Re: Keep wordcram on sketch without calling noLoop?

3 months ago

I tried a lot, nothing worked

I think I have to find another library for the tagcloud/wordle purpose!

PhiLho

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Can you show a simple sketch illustrating your problem?

fari

Re: Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Here is a simple sketch:

(link to the text file: usconst.txt)

import wordcram.*;
Cloud cloud;
float x = 0;
boolean flag = false;
void setup() {
size(800, 500);
}
void draw() {
//background(255);
x+=10;
if (x==width)
x=0;
if (mousePressed) {
flag = true;
cloud = new Cloud();
wordCram = new WordCram(this)
.fromTextFile("usconst.txt")
.withColor(#892727)
.sizedByWeight(8, 70);
cloud.draw();
}
if (flag ==true)
cloud.draw();
fill(255);
ellipse(width-x, 200, 50, 50);
}
import wordcram.*;
WordCram wordCram;
class Cloud {
Cloud() {
background(20, 20, 30);
}
void draw() {
wordCram.drawAll();
}
}//end of class

So the background in the main draw() should be disabled, otherwise wordcram is drawn only once and then wiped out by the background. What I want is to keep the bubble* moving on top of the wordcram without leaving its trails behind.

*Bubble is just for demo purposes. I am working on a bigger project so showing that code here is kind of difficult.

It will be great if you could help me with creating a PGraphics from it. Then I will be able to reuse it (and not just place it in the background of my sketch).

datguy

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

I found a solution for you. After you draw the word cloud, save it to an image, then reload that image to use as a background.

               
                import wordcram.*;
                Cloud cloud;
                PImage img;
                

                float x = 0;
                boolean flag = false;
                

                void setup() {
                  size(800, 500);
                  save("background.gif");
                  img = loadImage("background.gif");
                  fill(255);
                }
                

                void draw() {
                  background(img);
                  x+=10;
                  if (x==width)
                    x=0;
                

                

                  ellipse(width-x, 200, 50, 50);
                }
                

                void mousePressed() {
                    flag = true;
                    cloud = new Cloud();
                    wordCram = new WordCram(this)
                      .fromTextFile("usconst.txt")
                        .withColor(#892727)
                          .sizedByWeight(8, 70);
                    cloud.draw();
                    
                  save("background.gif");
                  img = loadImage("background.gif");
                  }
                

                

                import wordcram.*;
                WordCram wordCram;
                class Cloud {
                  Cloud() {
                    background(20, 20, 30);
                  }
                

                  void draw() {
                    wordCram.drawAll();
                  }
                }//end of class

fari

Re: Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Thank you so much. It worked for me.

datguy

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

I just couldn't leave it alone...

I created another version that creates the cloud in the background and displays it when it's done. It's partially based on the renderToBuffer example that comes with the library.

                
                 Cloud cloud;
                 float x = 0;
                 

                 void setup() {
                   size(800, 500);
                   cloud = new Cloud(this);
                   fill(255);
                 }
                 

                 void draw() {
                   x+=10;
                   if (x>=width) x=0;
                 

                   background(cloud.getImage());
                   ellipse(width-x, 200, 50, 50);
                 }
                 

                 void mousePressed() {
                   thread("drawCloud");
                 }
                 

                 void drawCloud() {
                   cloud.init();
                   cloud.draw();
                 }
                 

                 

                 import wordcram.*;
                 

                 WordCram wordCram;
                 PApplet parent;
                 PGraphics buffer, image;
                 

                 class Cloud {
                   Cloud(PApplet aPApplet) {
                     parent = aPApplet;
                     createBlankBackground();
                   }
                 

                   void createBlankBackground() {
                     image = createGraphics(width, height, JAVA2D);
                     image.beginDraw(); 
                     image.background(20, 20, 30);
                     image.endDraw();
                   }
                 

                   void init() {
                     buffer = createGraphics(width, height, JAVA2D);
                     buffer.beginDraw(); 
                     buffer.background(20, 20, 30);
                     wordCram = new WordCram(parent)
                       .fromTextFile("usconst.txt")
                         .withCustomCanvas(buffer)
                           .withColor(#892727)
                             .sizedByWeight(8, 70);
                   }
                 

                   PGraphics getImage() {
                     return image;
                   }
                 

                   void draw() {
                     wordCram.drawAll();
                     buffer.endDraw();
                     image = buffer;
                   }
                 }//end of class

PhiLho

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

datguy illustrated what I meant, the second sketch being better as it doesn't use a file on disk...

To the sample you show: you should not use the mousePressed variable in draw() for such usage, as usually the mouse down event lasts for several frames, leading to lot of renderings and probably your problem at the end.
As show, use the mousePressed() function instead, called only once.

fari

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Thank you datguy!

PhiLho, I am using mousePressed because I have several screens that should have different functions. For example, at the start of the program, there is a world map where a user can click and choose a particular country, then another screen shows latest trends for that country, and the user can then click again but this time it is choosing one of the trends to explore. And the story continues...So in my opinion, and based on all the trials, I managed to get such multi-tasks done by mousePressed. I used mousePressed(), but that was giving me trouble since a user clicking in any screen was affecting many other functions and screens.

PhiLho

Re: Keep wordcram on sketch without calling noLoop?

3 months ago

Well, perhaps you should correct your strategy around mousePressed() instead of having multiple mousePressed fires.
It is more a matter of correctly handling states and context than a problem with the function.
Ie. you have to check, in mousePressed(), if you are in a given state (screen), and handle the event accordingly.
It can be harder when you are not used to this way of thinking, but it pays at the end.

Top Reply