It is possible to change the string input after i run the code?

Programming Questions

rainywenn

It is possible to change the string input after i run the code?

in Programming Questions • 1 year ago

Hi there,
I tried to create some unique shape with alphabets with the following codes. But i have to keep change the string variable manually. Is there a way to change the string input after i run the code? Means after i run the code, it will output the default unique shape, but when i key in any letter or symbol, it will over-write the previous string and display the new unique shape with the new string input. I tried to name the string and using keypress function, but it does not allow me to do so. Please advise me. Thanks.The following is the code:

//declare variable myFont
PFont myFont;

void setup(){
size(800,800);

background(255,255,255);

//String[] fontList = PFont.list();
//println(fontList);

myFont = createFont("GenBasB.ttf",48);
textFont(myFont,272);
fill(0,0,0);
translate(400,400);

for (int i=0; i<12; i=i+1) {
fill(0,0,0);
textAlign(CENTER); //LEFTCENTERRIGHT
pushMatrix();
rotate(PI*i/1.5);
text("type",0,0);
popMatrix();
}
}

Replies(3)

Chrisir

Re: It is possible to change the string input after i run the code?

1 year ago

here you go...

In-build functions
You need two functions setup() and draw().
Both are build in and known by processing:

setup(), as the name indicates, runs only once.
draw() runs again and again. There the cool stuff happens.
In keyPressed() the keys are registered.

Your text is stored in a global variable called myText which gets
printed and changed in the program.

Usage
Use cursor left to delete your word,
type something to get a new word.

//declare variable myFont
PFont myFont;
String myText="type";
void setup() {
size(800, 800);
// String[] fontList = PFont.list();
// println(fontList);
myFont = createFont("GenBasB.ttf", 48);
// myFont = createFont("Arial", 48);
//
} // func
void draw() {
background(255, 255, 255);
textFont(myFont, 272);
fill(0, 0, 0);
translate(400, 400);
for (int i=0; i<12; i=i+1) {
fill(0, 0, 0);
textAlign(CENTER); //LEFT CENTER RIGHT
pushMatrix();
rotate(PI*i/1.5);
text(myText, 0, 0);
popMatrix();
}
} // func
void keyPressed() {
if (key == CODED)
{
if (keyCode == LEFT)
{
myText = "";
}
}
else
{
// key is NOT coded
myText = myText + key;
} // else
} // func

rainywenn

Re: Re: It is possible to change the string input after i run the code?

1 year ago

Thanks! It works!

Chrisir

Re: It is possible to change the string input after i run the code?

1 year ago

extended version for further tests

you can use backspace now
and return to slowly change the color (press often)

/*
In-build functions
You need two functions setup() and draw().
Both (or all three) are build in and known by processing:
setup(), as the name indicates, runs only once.
draw() runs again and again. There the cool stuff happens.
In keyPressed() the keys are registered.
Your text is stored in a global variable called myText which gets
printed and changed in the program.
Usage
Use cursor left to delete your word,
type something to get a new word.
*/
//declare variable myFont
PFont myFont;
//declare variable myText
String myText="type";
// declare variable colorRedPart
int colorRedPart=0;
void setup() {
// runs only once
size(800, 800);
// String[] fontList = PFont.list();
// println(fontList);
// myFont = createFont("GenBasB.ttf", 48);
myFont = createFont("Arial", 48);
textFont(myFont, 48);
//
} // func
// ------------------------------------------------
void draw() {
// runs on and on
background(255, 255, 255);
translate(400, 400);
// loop
for (int i=0; i<12; i=i+1) {
fill(colorRedPart, 0, 0);
textAlign(CENTER); //LEFT CENTER RIGHT
pushMatrix();
rotate(PI*i/1.5);
text(myText, 20, 0);
popMatrix();
}
} // func
// ------------------------------------------------
void keyPressed() {
// here keys are registered.
// Is it a special key?
if (key == CODED)
{
// the key is a special key like cursor keys -------
// left cursor?
if (keyCode == LEFT)
{
// delete the text
myText = "";
} // if
} // if (key == CODED)
else
{
// key is NOT coded --------------------------------
if (key == BACKSPACE)
{
// BACKSPACE: delete last letter at the end of word
myText = shortenString(myText);
}
// return
else if (key == RETURN || key == ENTER)
{
// change color
colorRedPart+=10;
if (colorRedPart>270)
colorRedPart=0;
}
else
{
// just add any input to the word
myText = myText + key;
} // else
} // else
//
} // func
// --------------------------------------------------
String shortenString( String myText1 ) {
// make the local String myText1 shorter by one letter
// check if it is long enough
if (myText1.length()>0) {
// take a substring one shorter than current length
myText1 = myText1.substring(0, myText1.length()-1);
} // if
// return the result as output of the function
return myText1;
}