Invert() and primitive() functions?

General Discussion Other

asimes

Invert() and primitive() functions?

in General Discussion • Other • 1 year ago

I've been looking at this reference of distance functions trying to understand how they work: http://www.iquilezles.org/www/articles/distfunctions/distfunctions.htm

They are so compact I can barely understand them though. I have a sphere and cube working correctly, but they are aligned with the world grid (not rotated at all, although in the case of the sphere it doesn't matter obviously). The domain operation for rotation uses something called an invert() function. Does anyone know what this is? Does Processing have something like this if so? It also uses something called a primitive() function, no idea what that is either.

EDIT: Maybe primitive() is any one of the functions listed at the top, not something built in? If someone math knowledgeable could confirm this that would be great.

Replies(7)

maleo

Re: Invert() and primitive() functions?

1 year ago

yep, under "domain operations" it says:

Where "primitive", in the examples below, is any distance formula really (one of the basic primitives aboce, a combination, or a complex distance field).

I guess invert(m) refers to the matrix inverse of m.

asimes

Re: Invert() and primitive() functions?

1 year ago

If that is what was meant I can't seem to see how to apply it to a distance field. It seems like Iñigo Quilez (the guy that wrote the article) was working with vectors instead of matrices. I wrote my own cube just using floats like this:

float cubeDist = max(abs(rayX)-5, max(abs(rayY-10)-5, abs(rayZ-50)-5));

Here is another way to write it that is more like how it is explained in the link:

float cubeDist = sqrt(sq(max(abs(rayX)-5, 0))+sq(max(abs(rayY-10)-5, 0))+sq(max(abs(rayZ-50)-5, 0)));

Either one makes a cube that is 10x10x10 units big at coordinates (0, 10, 50) with no rotation applied to it. I can't see how to apply your link to these...

Here is the complete code (makes one sphere and one cube at the moment):

float minThreshold = 0.0001;
int maxDepth = 800;
void setup() {
size(800, 600, P2D);
noLoop();
}
void draw() {
background(0);
loadPixels();
for (int i = 0; i < width; i++) {
for (int j = 0; j < height; j++) {
float dx = (float)i/(float)width-0.5;
float dy = ((float)j/(float)height-0.5)*(float)height/(float)width;
float dz = 1.0;
float normVec = 1.0/sqrt(dx*dx+dy*dy+dz*dz);
dx *= normVec;
dy *= normVec;
dz *= normVec;
float rayX = 0;
float rayY = 0;
float rayZ = 0;
float rayLength = 0;
int steps = 255;
while (steps > 0 && rayLength < maxDepth) {
// Sphere
float sphereDist = sqrt(sq(rayX)+sq(rayY-5)+sq(rayZ-100))-20;
// Cube
//float cubeDist = max(abs(rayX)-5, max(abs(rayY-10)-5, abs(rayZ-50)-5));
float cubeDist = sqrt(sq(max(abs(rayX)-5, 0))+sq(max(abs(rayY-10)-5, 0))+sq(max(abs(rayZ-50)-5, 0)));
float smallestDist = min(sphereDist, cubeDist)*0.5;
if (smallestDist < minThreshold) {
pixels[i+j*width] = (steps<<16)+(steps<<8)+steps;
break;
}
else {
rayLength += smallestDist;
rayX = dx*rayLength;
rayY = dy*rayLength;
rayZ = dz*rayLength;
steps--;
}
}
}
}
updatePixels();
}

maleo

Re: Invert() and primitive() functions?

1 year ago

Iñigo Quilez' function and type names (lengh, inv, vec3) look very much like GLSL.

Here I translated some of his distance functions to java as close as possible using the PVector class instead of his vec3.

to visualize I use a 3d grid of points around the origin and a threshold to the distance value.

looks like udBox (unsigned box) gives a zero distance for all points inside the box. I might be missing something...

Click to switch functions, move mouse to rotate:

import processing.opengl.*;
int res = 10;
float thresh = 7;
int r = 150;
int object = 0;
void setup() {
size(300, 300, OPENGL);
stroke(255);
}
void draw() {
background(0);
translate(width/2, height/2);
rotateY(map(mouseX, 0, width-1, 0, TWO_PI));
rotateX(map(mouseY, 0, width-1, 0, TWO_PI));
for (int x=-r; x<r; x+=res) {
for (int y=-r; y<r; y+=res) {
for (int z=-r; z<r; z+=res) {
PVector p = new PVector(x, y, z);
float dist = 0;
switch (object) {
case 0:
dist = sdSphere(p, 100);
break;
case 1:
dist = udBox(p, new PVector(100, 75, 50));
break;
case 2:
dist = sdBox(p, new PVector(100, 75, 50));
break;
}
if (abs(dist) < thresh) point(x,y,z);
}
}
}
}
void mousePressed() {
object = (++object) % 3;
}
/*
float sdSphere( vec3 p, float s )
{
return length(p)-s;
}
*/
// s ... radius
float sdSphere(PVector p, float s) {
return length(p) - s;
}
/*
float udBox( vec3 p, vec3 b )
{
return length(max(abs(p)-b,0.0));
}
*/
// b ... dimensions of box
float udBox(PVector p, PVector b) {
return length(max(PVector.sub(abs(p), b), 0.0));
}
/*
float sdBox( vec3 p, vec3 b )
{
vec3 di = abs(p) - b;
float mc = maxcomp(di);
return min(mc,length(max(di,0.0)));
}
*/
float sdBox(PVector p, PVector b)
{
PVector di = PVector.sub(abs(p), b);
float mc = maxcomp(di);
return min(mc, length(max(di, 0.0)));
}
/*
utility functions
*/
// length of vector (magnitude)
float length(PVector v) {
return v.mag();
}
// component-wise abs()
PVector abs(PVector v) {
return new PVector(abs(v.x), abs(v.y), abs(v.z));
}
// component-wise max()
PVector max(PVector v, float f) {
return new PVector(max(v.x, f), max(v.y, f), max(v.z, f));
}
// maximum of the components
float maxcomp(PVector v) {
return max(max(v.x, v.y), v.z);
}

asimes

Re: Invert() and primitive() functions?

1 year ago

Nice shapes, I especially like the res variable you put in.

Unfortunately I can't use rotateX / rotateY for my own sketch. The idea is to shoot rays from the viewer / camera and just project the geometry it hits so the geometry's distance field actually has to get rotated (I think). Ray marching is only interested in the surface of an object, so maybe it makes sense that your udBox doesn't have a distance for internal points.

asimes

Re: Invert() and primitive() functions?

1 year ago

I have rotation around the Y-Axis working, I haven't tried rotating around two axes at the moment yet, I'll leave that headache for later.

So far I have three shapes from the link I posted originally working, but I have a new problem, does anyone know what dot() is? Here's the link again: http://www.iquilezles.org/www/articles/distfunctions/distfunctions.htm

Here is my code so far, it has a sphere, cube, and torus. The cube and torus spin on the Y-Axis and are translated to be always in front of the screen. I'm making this up as I go, if any one has comments or suggestions I'm all ears:

float minThreshold = 0.0001;
int maxDepth = 800;
float angle = 0;
void setup() {
size(400, 300, P2D);
//noLoop();
}
void draw() {
float x = cos(angle+HALF_PI)*50;
float z = sin(angle+HALF_PI)*50;
background(0);
loadPixels();
for (int i = 0; i < width; i++) {
for (int j = 0; j < height; j++) {
float dx = (float)i/(float)width-0.5;
float dy = ((float)j/(float)height-0.5)*(float)height/(float)width;
float dz = 1.0;
float normVec = 1.0/sqrt(dx*dx+dy*dy+dz*dz);
dx *= normVec;
dy *= normVec;
dz *= normVec;
float rayX = 0;
float rayY = 0;
float rayZ = 0;
float rayLength = 0;
int steps = 255;
while (steps > 0 && rayLength < maxDepth) {
// Rotation Y-axis
float rotX = rayX*cos(angle)-rayZ*sin(angle);
float rotZ = rayZ*cos(angle)+rayX*sin(angle);
// Sphere
float sphereDist = sqrt(sq(rayX)+sq(rayY)+sq(rayZ-50))-5;
// Cube
//float cubeDist = max(abs(rayX)-5, max(abs(rayY-10)-5, abs(rayZ-50)-5));
float cubeDist = max(abs(rotX-x)-5, max(abs(rayY-10)-5, abs(rotZ-z)-5));
// Torus
//float q = sqrt(sq(rayX)+sq(rayY+10))-3.33;
//float torusDist = sqrt(sq(q)+sq(rayZ-50))-1.67;
float q = sqrt(sq(rotX-x)+sq(rayY+10))-3.33;
float torusDist = sqrt(sq(q)+sq(rotZ-z))-1.67;
float smallestDist = min(sphereDist, min(cubeDist, torusDist))*0.5;
if (smallestDist < minThreshold) {
pixels[i+j*width] = (steps<<16)+(steps<<8)+steps;
break;
}
else {
rayLength += smallestDist;
rayX = dx*rayLength;
rayY = dy*rayLength;
rayZ = dz*rayLength;
steps--;
}
}
}
}
updatePixels();
angle += TWO_PI/36;
}

amnon.owed

Re: Invert() and primitive() functions?

1 year ago

I've been doing some research on other topics (isosurfaces/metaballs etc.) and in the process of collecting useful information I found several links that may of may not be of interest in the light of this thread. Let me just share these interesting links as is...

http://blog.hvidtfeldts.net/index.php/2011/08/distance-estimated-3d-fractals-iii-folding-space/

http://pouet.net/topic.php?which=6675&page=1

http://pouet.net/topic.php?which=7931&page=1

http://directtovideo.wordpress.com/2012/03/15/get-my-slides-from-gdc2012/

maleo

Re: Invert() and primitive() functions?

1 year ago

dot() would be the dot product of two vectors, a.k.a. scalar product.

again, the syntax used on the site you referenced looks very much like GLSL (OpenGL Shading Language). check out this reference card:

http://www.khronos.org/files/opengl-quick-reference-card.pdf

on page 7 under "built-in functions" you will find most of the functions and how they work.

Top Reply