Inner points of an hexagon

Programming Questions

simonecar..

in Programming Questions • 2 years ago

Hi,

I'm developing a software that draw a regular polygon based on an array of PVectors.

Now, I'd like to get a n random points from the area of the hexagon.

What is the best practice to do this?

Replies(3)

toxmeister

Re: Inner points of an hexagon

2 years ago

One solution is to use barycentric coordinates to pick a point within a polygon:

/**
* This demo uses barycentric coordinates to choose a random point within a polygon.
*
* (c) 2011 Karsten Schmidt // LGPLv2 licensed
*/
import toxi.geom.*;
import toxi.processing.*;
Polygon2D poly;
ToxiclibsSupport gfx;
void setup() {
size(640, 480);
gfx=new ToxiclibsSupport(this);
poly=new Circle(new Vec2D(width/2, height/2), 200).toPolygon2D(6);
background(255);
noFill();
gfx.polygon2D(poly);
frameRate(999);
}
void draw() {
// create a random barycentric coordinate
// for a hexagon these coordinates have 6-dimensions (one per vertex)
// with each component indicating the impact of its related polygon vertex
// IMPORTANT:
// the sum of all components MUST BE 1.0 for the point to lie inside
int num=poly.getNumVertices();
float[] barycentric=new float[num];
float sum=0;
int start=(int)random(num);
for(int i=0; i<num-1; i++) {
float rnd=random(1-sum);
barycentric[(start+i)%num]=rnd;
sum+=rnd;
}
// ensure final sum will be 1.0
barycentric[(start+num-1)%num]=1-sum;
// now compute the actual point in cartesian space
// by summing and scaling each polygon vertex with its
// barycentric value
Vec2D p=new Vec2D();
for(int i=0; i<num; i++) {
p.addSelf(poly.vertices.get(i).scale(barycentric[i]));
}
// draw a circle at the final point
gfx.circle(p,5);
}

http://postspectacular.com | http://toxiclibs.org

simonecar..

Re: Inner points of an hexagon

2 years ago

thank you for your answer (and excuse my delay).

I given a try to the snippets you posted.

It is quite near the result I was expecting, even if I need a better algorithm, because I need points to be generated randomly, but I need them to be more homogeneous.

Note that this

int num = poly.getNumVertices();

Returns me an unknown function error (I managed the software to working by setting num to the number of the polygon's vertices).

Thank you again, I hope to update this discussion.

I'm new to Processing but have experience with programming and scripting languages, even if trigonometry is becoming a problem right now :)

simone.

toxmeister

Re: Inner points of an hexagon

2 years ago

Yes, the barycentric approach does NOT produce uniform distribution. Below is another approach based on random interpolating between randomly chosen polygon edges... This one is much more homogeneous, but will only work with regular polygons...

/**
* This demo creates random points within a polygon by interpolating between polygon edges.
* This process only works for regular polygons.
*
* (c) 2011 Karsten Schmidt // LGPLv2 licensed
*/
import toxi.geom.*;
import toxi.processing.*;
Polygon2D poly;
ToxiclibsSupport gfx;
void setup() {
size(640, 480);
gfx=new ToxiclibsSupport(this);
poly=new Circle(new Vec2D(width/2, height/2), 200).toPolygon2D(6);
background(255);
noFill();
gfx.polygon2D(poly);
frameRate(999);
}
void draw() {
// pick a random edge
Line2D ea=getRandomEdge(poly);
Line2D eb=null;
// and another one, making sure it's different
while (eb==null || eb.equals(ea)) {
eb=getRandomEdge(poly);
}
// pick a random point on edge A
Vec2D p=ea.a.interpolateTo(ea.b, random(1));
// then randomly interpolate to another random point on edge B
p.interpolateToSelf(eb.a.interpolateTo(eb.b, random(1)), random(1));
// draw a circle at the final point
gfx.circle(p, 5);
}
public Line2D getRandomEdge(Polygon2D poly) {
int num = poly.vertices.size();
int i=(int)random(num);
return new Line2D(poly.vertices.get(i), poly.vertices.get((i + 1) % num));
}

http://postspectacular.com | http://toxiclibs.org

Top Reply