IjeomaMotion Event Listeners

shontek

in Contributed Library Questions • 2 years ago

I created some basic tweens with IjeomaMotion and inserted them into a tween sequence. The examples show a TweenSequenceEventListener class that tracks the start, end and repeat of a tween sequence. I was wondering if there was a way to track the start of individual tweens within the sequence. It seems like it should be pretty simple, but I'm a bit of a novice programmer. I used the examples to track the END of individual tweens within a tween sequence, but not the start of the individual tweens. Perhaps the answer is in keyframes or timelines? Pseudocode posted below. Thanks!

Tween tw1;

Tween tw2;

Tween tw3;

TweenSequence ts;

TweenSeqEvtListener tsel;

...

void setup(){

tw1 = new Tween("tw1", 0, 1, 4, 0f, Tween.LINEAR_BOTH);

tw2 = new Tween("tw2", 0, 1, 4, 0f, Tween.LINEAR_BOTH);

tw3 = new Tween("tw3", 0, 1, 4, 0f, Tween.LINEAR_BOTH);

...

ts.appendChild(tw1);

ts.appendChild(tw2);

ts.appendChild(tw3);

ts.addEventListener(tsel);

...

}

void draw() {

// Do some animation stuff

...

}

class TweenSequenceEventListener implements MotionEventListener {

public void onMotionEvent(MotionEvent te) {

if (te.type == MotionEvent.TWEEN_SEQUENCE_STARTED) {

println("Tween Sequence '" + ((TweenSequence) te.getSource()).getName() + "' started");

} else if (te.type == MotionEvent.TWEEN_SEQUENCE_ENDED) {

println("Tween Sequence '" + ((TweenSequence) te.getSource()).getName() + "' ended");

} else if (te.type == MotionEvent.TWEEN_SEQUENCE_REPEATED) {

println("Tween Sequence '" + ((TweenSequence) te.getSource()).getName() + "' repeated");

}

// This notifies the user of tween sequence events but not individual tween events

Replies(1)

ijeoma

Re: IjeomaMotion Event Listeners

2 years ago

You can add eventlisteners to each tween before theyre appended to the tweensequence. But theres a bug with the TWEEN_STARTED (only when appended to a TweenSequence) so youll have to use the TWEEN_SEQUENCE_STARTED event to see when the first tween has started and then after use the TWEEN_ENDED event to see when the tweens after start. It should be fixed in the next release.

import ijeoma.motion.*;
import ijeoma.motion.event.*;
import ijeoma.motion.tween.*;
PFont font;
TweenSequence ts;
TweenEventListener tel;
TweenSequenceEventListener tsel;
public void setup() {
size(400, 400);
smooth();
font = createFont("Arial", 12);
textFont(font);
Motion.setup(this);
tel = new TweenEventListener();
Tween t1 = new Tween("t1", -width, width, 100);
Tween t2 = new Tween("t2", -width, width, 75);
Tween t3 = new Tween("t3", -width, width, 50);
Tween t4 = new Tween("t4", -width, width, 25);
t1.addEventListener(tel);
t2.addEventListener(tel);
t3.addEventListener(tel);
t4.addEventListener(tel);
tsel = new TweenSequenceEventListener();
ts = new TweenSequence();
ts.setName("ts");
ts.appendChild(t1);
ts.appendChild(t2);
ts.appendChild(t3);
ts.appendChild(t4);
ts.repeat();
ts.addEventListener(tsel);
ts.play();
}
public void draw() {
background(255);
noStroke();
fill(0);
for (int i = 0; i < ts.getChildCount(); i++)
rect(ts.getTween(i).getPosition(), i * 100, width, 100);
drawUI();
}
public void drawUI() {
String time;
// This draws the seek for the ts TweenParallel object
stroke(lerpColor(0xFF00FF00, 0xFFFF0000, ts.getSeekPosition()));
line(ts.getSeekPosition() * width, 0, ts.getSeekPosition() * width,
height);
// This draws the time for every Tween object
for (int i = 0; i < ts.getChildCount(); i++) {
Tween t = ts.getTween(i);
time = (int) t.getTime() + " / " + (int) t.getDuration();
fill(lerpColor(0xFF00FF00, 0xFFFF0000, t.getSeekPosition()));
text(time, 10, i * 100 + 10 + 12);
}
// This draws the time for the ts TweenSequence object
time = (int) ts.getTime() + " / " + (int) ts.getDuration();
fill(lerpColor(0xFF00FF00, 0xFFFF0000, ts.getSeekPosition()));
text(time, width - textWidth(time) - 10, height - 10);
}
public void keyPressed() {
ts.play();
}
class TweenEventListener implements MotionEventListener {
public void onMotionEvent(MotionEvent te) {
if (te.type == MotionEvent.TWEEN_STARTED)
println(((Tween) te.getSource()).getName() + " started");
else if (te.type == MotionEvent.TWEEN_ENDED)
println(((Tween) te.getSource()).getName() + " ended");
}
}
class TweenSequenceEventListener implements MotionEventListener {
public void onMotionEvent(MotionEvent te) {
if (te.type == MotionEvent.TWEEN_SEQUENCE_STARTED)
println(((TweenSequence) te.getSource()).getName() + " started");
else if (te.type == MotionEvent.TWEEN_SEQUENCE_ENDED)
println(((TweenSequence) te.getSource()).getName() + " ended");
}
}

Animation library for timeline/keyframe based tweens and more: www.ekeneijeoma.com/processing/ijeomamotion/

Top Reply