if within if - really stupid - Processing Forum

Loading...

Processing Forum

Programming Questions

d.dora_92

if within if - really stupid

in Programming Questions • 8 months ago

Hello!

I want to create a program that will accept the click of the mouse twice. first time, the user should click on an image and hear a sound. the sounds that I use are in an array (named test), and by each click, they are playing random. then, depending on which sound is heard, the user should click on an other image, and if he does well, another sound of applauses (sound7) will be heard. if the user click out of this image, a sound of failure will be heard. If it doesn't make scene, think I am trying to build a game for little children. every time they click on an ear image, they will hear a sound of an animal and they should match it with the correct animal image. it works pretty well, until the random sound of the clicks, but when i put a second "if" under the first, the program doesn't response. Here is my problematic part of the code:

void mousePressed(){

//if the user clicks on the first image, play random a sound
if (mouseX > 475 && mouseX < 525 && mouseY > 25 && mouseY < 75) {
int index = int( random(0,5) );
test[index].play();

//if the sound that played is the first one then and the user clicks on the right animal image, play song7 (applause)
if (test[index] == test[0]){
boolean mousePressed = true;
if (mousePressed == true && mouseX > 100 && mouseX < 300 && mouseY > 100 && mouseY < 250) {
song7.play();
//else if the user clicks out of this image, play sound8 (fail)
} else if (mousePressed == true && mouseX <100 && mouseX > 300 && mouseY < 100 && mouseY > 250) {
song8.play();
}
}
}
}

well, it doesn't get any error, it runs, but when i click in the right image, it does nothing at all... :( why?

of course there will be more than one images, but first I have to learn how to write the code...

any help appreciated! thanks in advance!

1

Replies(15)

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

you have to remember that draw() is done 60 times per second and that your function mousePressed is as well.

So to test two different mouse positions (regarding buttons) within each other (with if) makes no sense since the mouse can only be in one position at a time.

So let's assume your program has two basic situations:

first time, the user should click on an image and hear a sound.
then he or she should click on an animal image

So you need a var (e.g. named soundButtonHasBeenPressed) to monitor in which situation you are in.

at the beginning (before setup() ):

boolean soundButtonHasBeenPressed=false;

the var has global scope.

Then in mousePressed we want to achieve that

when soundButtonHasBeenPressed is false processing waits for the user to click on an image (and hear a sound). Then we set soundButtonHasBeenPressed to true.
When the soundButtonHasBeenPressed is true wait for an animal to be clicked. Then we set soundButtonHasBeenPressed to false again.

Note that the order is animal first then sound button (wrong order)

void mousePressed() {
if (soundButtonHasBeenPressed == true) // or just if (soundButtonHasBeenPressed)
{
// situation 2 !!!!!!!!!!!!
// soundButtonHasBeenPressed == true
//if the sound that played is the first one then and the user clicks on the right animal image, play song7 (applause)
if (test[index] == test[0]) {
boolean mousePressed = true;
if (mousePressed == true && mouseX > 100 && mouseX < 300 && mouseY > 100 && mouseY < 250) {
song7.play();
soundButtonHasBeenPressed = false;
//else if the user clicks out of this image, play sound8 (fail)
}
else if (mousePressed == true && mouseX <100 && mouseX > 300 && mouseY < 100 && mouseY > 250) {
song8.play();
soundButtonHasBeenPressed = false;
} // else
} // if
} // if
else
{
// situation 1 !!!!!!!!!!!!
// soundButtonHasBeenPressed == false
//if the user clicks on the first image, play random a sound
if (mouseX > 475 && mouseX < 525 && mouseY > 25 && mouseY < 75) {
int index = int( random(0, 5) ); // make that a global var!
test[index].play();
soundButtonHasBeenPressed = true;
} // if
} // else
} // function
//

remember: ctrl-t gives you better indents / formatting.

mousePressed == true not necessary...

Greetings, Chrisir

d.dora_92

Re: if within if - really stupid

8 months ago

First of all thank you very much for your help.

But now it says: cannot find anything named "index", it's something I faced when I tried to solve the problem by myself, that's why I tried not to separate the two "if" with }.

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

yes.

please have before setup()

int index;

and in line 26 no int.

so you make index a global variable, a variable with a global scope.

d.dora_92

Re: if within if - really stupid

8 months ago

Yes, it works! and most important I understand much better now!

Thank you very much!

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

there are other questions:

e.g. line 7

if (test[index] == test[0]) {

better

if (index == 0) {

??

or line 14 :
I think a simple else would be enough, because when the mouse is not in the button it is just without the button, right?

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

oh, it works already?

Great, then forget my remarks, sorry

d.dora_92

Re: if within if - really stupid

8 months ago

Yes, you're right. I have a lot of things to learn. Some of them come out from my mind, and they are not so good

d.dora_92

Re: if within if - really stupid

8 months ago

Haha! both ways work. But yours is better, so your advice is not wasted!

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

you are doing good!

Sounds like a fun game to play!

Good luck!

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

ok, advice:

when this works:

if (index == 0) {

in line 7
you have to do that 6 times, right? Or how many animals you have.

Instead of

if (index == 0) {
...
if (index == 1) {
...
if (index == 2) {
...

you can say

switch (index) {
case 0:
...
break;
case 1:
.....
break;
case 2:
....
break;
.....
} // switch

nice.
You need break every time.

http://www.processing.org/reference/switch.html

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

or like this with two functions

d.dora_92

Re: if within if - really stupid

8 months ago

Really helpful! I knew about "break" (I'm sorry, I know the terminology only in my language), but I was trying to think about the two functions' solution you gave me. I am going to do it right now!

many many thanks!

Chrisir

Chrisir

Re: if within if - really stupid

8 months ago

Good luck!

GoToLoop

GoToLoop

Re: if within if - really stupid

8 months ago

Hey! I'm the one who helped ya @ http://forum.processing.org/topic/array-of-audio-files-failed
I've expanded my previous alternative tweak of your code there.

Now, your program has 2 more arrays ( imgsX[] & imgsY[] )
to store the coordinates where each image from imgs[] is drawn.
So now, mouseX & mouseY can be checked against the coordinates of each imgs[]!

[v3.0] Also, I'm assuming that each imgs[] has 50px -> sizeImg = 50;

[Edit v3.1] Now I use -> sizeImg = imgs[0].width;
to determine imgs[] size!

[Edit v3.2] Function buttonCheck() works w/ any img[] dimensions,
since it uses -> imgs[idx]. width & imgs[idx]. height;
instead of just imgs[0]. width!

Since I can't run your code w/o making bogus files, you have to check for yourself weather it's working.

/**
 * Animal Sounds (v3.2)
 * by d.dora_92 (2013/Feb)
 * tweaked by GoToLoop
 *
 * http://forum.processing.org/topic/array-of-audio-files-failed
 * http://forum.processing.org/topic/if-within-if-really-stupid
 */

import ddf.minim.*;

final static String[] fileNames = {
  "dog", "horse", "frog", "rooster", "cat", "duck", "ear"
};

final static int   numImgs = fileNames.length;
final static PImage[] imgs = new PImage[numImgs];

final static short[] imgsX = new short[numImgs];
final static short[] imgsY = new short[numImgs];

final static int numSounds = fileNames.length - 1;
final static AudioPlayer[] sounds = new AudioPlayer[numSounds];

final Minim minim = new Minim(this);
AudioPlayer correct, wrong;

byte chosenSound;
boolean wasButtonPressed;

void setup() {
  size(1000, 600);
  background(170, 245, 120);
  rectMode(CORNER);
  frameRate(30);
  noLoop();

  for ( byte idx = 0; idx != numImgs; 
  imgs[idx] = loadImage(fileNames[idx++] + ".jpg") );

  for ( byte idx = 0; idx != numSounds; 
  sounds[idx] = minim.loadFile(fileNames[idx++] + ".wav") );

  correct = minim.loadFile("applauses.wav");
  wrong   = minim.loadFile("fail.wav");

  for (short idx = 0, row = 100; row <= 350; row += 200)
    for (short col = 100; col <= 700; ++idx, col += 300)
      image(imgs[idx], imgsX[idx] = col, imgsY[idx] = row);

  image(imgs[numImgs-1], 
  imgsX[numImgs-1] = (short) (width/2 - imgs[numImgs-1].width/2), 
  imgsY[numImgs-1] = 25);
}

void mousePressed() {

  if (wasButtonPressed) {
    wasButtonPressed = false;

    if ( buttonCheck(chosenSound) )    correct.play();
    else                               wrong.play();
  }

  else if ( buttonCheck(numImgs-1) ) {
    wasButtonPressed = true;

    chosenSound = (byte) random(numSounds);
    sounds[chosenSound].play();
  }
}

boolean buttonCheck(final int idx) {
  return mouseX > imgsX[idx] & mouseX < imgsX[idx] + imgs[idx].width 
    &&   mouseY > imgsY[idx] & mouseY < imgsY[idx] + imgs[idx].height;
}

void stop() {
  for ( AudioPlayer audio: sounds )  audio.close();

  correct.close();
  wrong.close();

  minim.stop();
  super.stop();
}

d.dora_92

Re: if within if - really stupid

8 months ago

I've tried both ways, and they are working good enough. Only after a few clicks, they start lagging. Of course your way GoToLoop, lags less, and I tried to finish the project using this code, too. But, I need this for a student project of my university. So, my teacher needs me to do that, and I am very new to processing to program like you..

despite that, I will give him my code (the bad one), and I will keep yours for my studies. I will understand it line by line, as soon as I will finish with the presentation

. Unfortunately, I can work efficiently, only when my university project is completed. Ironic?

thanks anyway, I appreciate all of your advices and I am definitely coming back soon just because I want it and nobody else. Dora.

Top Reply