if touched,send once

Programming Questions

karlhungus

in Programming Questions • 6 months ago

when line touches the circle
i want to send OSC message
but just once when it happens,
not every frame, while line is touching the circle

like when i put it here
if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true) {
fill(0);
sendOsc; // sends every frame
}
else {
fill(255);

float circleX = 200;
float circleY = 200;
float circleRadius = 100;

float lineX1 = 350;
float lineY1 = 350;
float lineX2, lineY2;

void setup() {
size(400, 400);
ellipseMode(RADIUS);
smooth();
}

void draw() {
background(204);

lineX2 = mouseX;
lineY2 = mouseY;

if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true) {
    fill(0);
}
else {
    fill(255);
}

ellipse(circleX, circleY, circleRadius, circleRadius);
line(lineX1, lineY1, lineX2, lineY2);

}

// Code adapted from Paul Bourke:
// http://local.wasp.uwa.edu.au/~pbourke/geometry/sphereline/raysphere.c
boolean circleLineIntersect(float x1, float y1, float x2, float y2, float cx, float cy, float cr ) {
float dx = x2 - x1;
float dy = y2 - y1;
float a = dx * dx + dy * dy;
float b = 2 * (dx * (x1 - cx) + dy * (y1 - cy));
float c = cx * cx + cy * cy;
c += x1 * x1 + y1 * y1;
c -= 2 * (cx * x1 + cy * y1);
c -= cr * cr;
float bb4ac = b * b - 4 * a * c;

//println(bb4ac);

if (bb4ac < 0) { // Not intersecting
    return false;
}
else {

    float mu = (-b + sqrt( b*b - 4*a*c )) / (2*a);
    float ix1 = x1 + mu*(dx);
    float iy1 = y1 + mu*(dy);
    mu = (-b - sqrt(b*b - 4*a*c )) / (2*a);
    float ix2 = x1 + mu*(dx);
    float iy2 = y1 + mu*(dy);

    // The intersection points
    //ellipse(ix1, iy1, 10, 10);
    //ellipse(ix2, iy2, 10, 10);

    float testX;
    float testY;
    // Figure out which point is closer to the circle
    if (dist(x1, y1, cx, cy) < dist(x2, y2, cx, cy)) {
      testX = x2;
      testY = y2;
    } else {
      testX = x1;
      testY = y1;
    }

    if (dist(testX, testY, ix1, iy1) < dist(x1, y1, x2, y2) || dist(testX, testY, ix2, iy2) < dist(x1, y1, x2, y2)) {
      return true;
    } else {
      return false;
    }
}
}

Replies(5)

pauline303

Re: if touched,send once

6 months ago

you would need to create a second boolean value to track changes of state of the condition "line touching the circle".
that should do the trick =

float circleX = 200;
float circleY = 200;
float circleRadius = 100;
boolean CIRCLE_LINE;
float lineX1 = 350;
float lineY1 = 350;
float lineX2, lineY2;

void setup() {
size(400, 400);
ellipseMode(RADIUS);
smooth();
CIRCLE_LINE=circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
}

void draw() {
background(204);
lineX2 = mouseX;
lineY2 = mouseY;

if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true && CIRCLE_LINE != circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius))
{
    fill(0);
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    println("SEND");
}
else {
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    fill(255);
}

ellipse(circleX, circleY, circleRadius, circleRadius);
line(lineX1, lineY1, lineX2, lineY2);
}

// Code adapted from Paul Bourke:
// http://local.wasp.uwa.edu.au/~pbourke/geometry/sphereline/raysphere.c
boolean circleLineIntersect(float x1, float y1, float x2, float y2, float cx, float cy, float cr ) {
float dx = x2 - x1;
float dy = y2 - y1;
float a = dx * dx + dy * dy;
float b = 2 * (dx * (x1 - cx) + dy * (y1 - cy));
float c = cx * cx + cy * cy;
c += x1 * x1 + y1 * y1;
c -= 2 * (cx * x1 + cy * y1);
c -= cr * cr;
float bb4ac = b * b - 4 * a * c;

//println(bb4ac);

if (bb4ac < 0) { // Not intersecting
    return false;
}
else {

    float mu = (-b + sqrt( b*b - 4*a*c )) / (2*a);
    float ix1 = x1 + mu*(dx);
    float iy1 = y1 + mu*(dy);
    mu = (-b - sqrt(b*b - 4*a*c )) / (2*a);
    float ix2 = x1 + mu*(dx);
    float iy2 = y1 + mu*(dy);

    // The intersection points
    //ellipse(ix1, iy1, 10, 10);
    //ellipse(ix2, iy2, 10, 10);

    float testX;
    float testY;
    // Figure out which point is closer to the circle
    if (dist(x1, y1, cx, cy) < dist(x2, y2, cx, cy)) {
      testX = x2;
      testY = y2;
    }
    else {
      testX = x1;
      testY = y1;
    }

    if (dist(testX, testY, ix1, iy1) < dist(x1, y1, x2, y2) || dist(testX, testY, ix2, iy2) < dist(x1, y1, x2, y2)) {
      return true;
    }
    else {
      return false;
    }
}
}

karlhungus

Re: if touched,send once

6 months ago

hi, thank you very much for response
the tricky part (for me)
is how to separate the 2 things now
because
a.
i want to send OSC message
just once when intersection happens,
not every frame, while line is touching the circle

b.
but all other actions need to be as before -
happening every frame, while line is touching the circle

is this doable?
best,k.

if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true && CIRCLE_LINE != circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius))
{
    fill(random(255));
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    println("SEND");
}
else {
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    fill(255);
}

pauline303

Re: if touched,send once

6 months ago

simply make several conditions no ?

float circleX = 200;
float circleY = 200;
float circleRadius = 100;
boolean CIRCLE_LINE;
float lineX1 = 350;
float lineY1 = 350;
float lineX2, lineY2;

void setup() {
size(400, 400);
ellipseMode(RADIUS);
smooth();
CIRCLE_LINE=circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
}

void draw() {
background(204);
lineX2 = mouseX;
lineY2 = mouseY;

if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true && CIRCLE_LINE != circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius))
{
    fill(0);
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    println("SEND");
}
if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true)
{
    fill(0);
}
else {
    CIRCLE_LINE= circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius);
    fill(255);
}

ellipse(circleX, circleY, circleRadius, circleRadius);
line(lineX1, lineY1, lineX2, lineY2);
}

boolean circleLineIntersect(float x1, float y1, float x2, float y2, float cx, float cy, float cr ) {
float dx = x2 - x1;
float dy = y2 - y1;
float a = dx * dx + dy * dy;
float b = 2 * (dx * (x1 - cx) + dy * (y1 - cy));
float c = cx * cx + cy * cy;
c += x1 * x1 + y1 * y1;
c -= 2 * (cx * x1 + cy * y1);
c -= cr * cr;
float bb4ac = b * b - 4 * a * c;

if (bb4ac < 0) { return false;
}
else {

    float mu = (-b + sqrt( b*b - 4*a*c )) / (2*a);
    float ix1 = x1 + mu*(dx);
    float iy1 = y1 + mu*(dy);
    mu = (-b - sqrt(b*b - 4*a*c )) / (2*a);
    float ix2 = x1 + mu*(dx);
    float iy2 = y1 + mu*(dy);

    float testX;
    float testY;

    if (dist(x1, y1, cx, cy) < dist(x2, y2, cx, cy)) {
      testX = x2;
      testY = y2;
    }
    else {
      testX = x1;
      testY = y1;
    }

    if (dist(testX, testY, ix1, iy1) < dist(x1, y1, x2, y2) || dist(testX, testY, ix2, iy2) < dist(x1, y1, x2, y2)) {
      return true;
    }
    else {
      return false;
    }
}
}

karlhungus

Re: if touched,send once

6 months ago

but of course, thank you very much

GoToLoop

Re: if touched,send once

6 months ago

Here's an alternative similar version.

A very recent post today had a very similar situation too:

forum.processing.org/topic/game-score-is-updating-too-much

/**
 Line vs Circle Intersection
 by KarlHungus (2013/Apr)
 
 http://forum.processing.org/topic/if-touched-send-once
 
 http://studio.processingtogether.com/sp/pad/export/ro.9gGiJpQZIcTte/latest
 */

int circleX, circleY, circleR;
int lineX, lineY;

boolean isIntersecting;

final static String GFX = P2D; // Use JAVA2D for Processing 2+

void setup() {
  size(600, 400, GFX);
  noLoop();  // turn off draw()!;
  smooth();
  ellipseMode(RADIUS);
  strokeWeight(2);

  circleX = width  >> 1;
  circleY = height >> 1;
  circleR = height >> 2;

  lineX = width  - width/8;
  lineY = height - height/8;

  mouseX = mouseY = lineX;
}

void mouseMoved() {
  redraw();  // 1 round of draw()!
}

void draw() {
  background(0300);

  if ( checkIntersection(lineX, lineY, mouseX, mouseY, 
  circleX, circleY, circleR) ) {
    if (!isIntersecting)   println("Sending OSC...");
    isIntersecting = true;
  } 
  else {
    if (isIntersecting)    println("Stopped intersecting!");
    isIntersecting = false;
  }

  noStroke();
  fill(isIntersecting? 0 : -1);
  ellipse(circleX, circleY, circleR, circleR);

  stroke(#00FF00);
  line(lineX, lineY, mouseX, mouseY);
}

// Code adapted from Paul Bourke:
// http://local.wasp.uwa.edu.au/~pbourke/geometry/sphereline/raysphere.c

boolean checkIntersection(float x1, float y1, float x2, float y2, 
float cx, float cy, float cr ) {
  float dx = x2 - x1;
  float dy = y2 - y1;

  float a = dx*dx + dy*dy;
  float b = (dx*(x1 - cx) + (y1 - cy)*dy) * 2;
  float c = cx*cx + cy*cy;

  c += x1*x1 + y1*y1;
  c -= (cx*x1 + cy*y1) * 2;
  c -= cr*cr;

  float delta = b*b - 4*a*c;

  if (delta < 0)   return false; // Not intersecting

  delta = sqrt(delta);

  float mu = (-b + delta) / (2*a);
  float ix1 = x1 + mu*dx;
  float iy1 = y1 + mu*dy;

  mu = (b + delta) / (-2*a);
  float ix2 = x1 + mu*dx;
  float iy2 = y1 + mu*dy;

  // Intersection points
  fill(#FF0000);
  ellipse(ix1, iy1, 5, 5);
  ellipse(ix2, iy2, 5, 5);

  // Figure out which point is closer to the circle
  boolean test = dist(x1, y1, cx, cy) < dist(x2, y2, cx, cy);

  float closerX = test? x2:x1;
  float closerY = test? y2:y1;

  return dist(closerX, closerY, ix1, iy1) < dist(x1, y1, x2, y2) || 
    dist(closerX, closerY, ix2, iy2) < dist(x1, y1, x2, y2);
}