i need explanation about that formulation

Programming Questions

sachaamm

i need explanation about that formulation

in Programming Questions • 9 months ago

hello

i saw a recent code replied by amnon owed

it's:

int gridDim = 15;
int numCharges = 3;
float maxStrengthPerCharge = 100/numCharges;
ArrayList <Vector> field = new ArrayList <Vector> ();
ArrayList <Electron> charges = new ArrayList<Electron>();
float value;
void setup() {
size(600, 600);
smooth();
strokeWeight(0.5);
int w = width/gridDim;
int h = height/gridDim;
for (int y = 0; y<gridDim; y++) {
for (int x = 0; x<gridDim; x++) {
field.add(new Vector((x+0.5)*w, (y+0.5)*h));//ARRAY OF GRID POINTS
}
}
charges.add(new Electron(400, 400, 20));
charges.add(new Electron(200, 300, 20));
charges.add(new Electron(500, 200, 20));
}
void draw() {
background(255);
for (Electron e : charges) { e.display(); }
for (Vector v : field) { v.update(); }
for (Vector v : field) { v.display(); }
value = 0.5+sin(frameCount*0.01);
}
class Electron {
PVector pos;
float charge;
Electron(float x, float y, float charge) {
pos = new PVector (x, y);
this.charge=charge;
}
void display() {
pushMatrix();
translate(pos.x, pos.y);
noStroke();
fill(0);
ellipse(0, 0, charge, charge);
popMatrix();
}
}
class Vector {
PVector pos, dir, fin;
Vector(float x, float y) {
pos = new PVector(x, y);
dir = new PVector();
}
void update() {
dir.set(0, 0, 0);
for (Electron e : charges) {
PVector currentDir = e.pos.get();
float magnitude = map(currentDir.dist(pos), 0, width, maxStrengthPerCharge, 0);
currentDir.sub(pos);
currentDir.normalize();
currentDir.mult(magnitude);
dir.add(currentDir);
dir.mult(value);
fin = PVector.add(pos, dir);
}
}
void display() {
fill(0);
ellipse(fin.x, fin.y, 10, 10);
stroke(0);
for (Vector v : field) {
if (v.fin.dist(fin) < 50) {
line(v.fin.x, v.fin.y, fin.x, fin.y);
}
}
}
}

///////////////////////////

i dont know this type of formulation " for (Electron e : charges) { "

could you explain me how function this formulation and why we use it

many thanks

Replies(2)

dimiro

Re: i need explanation about that formulation

9 months ago

its called enhanced for loop....

String [] arr={"a","b","c"};
for(int i=0; i<arr.length; i++)
print(arr[i]+" ");
println("");
for (String s:arr)
print(s+" ");
println("");

for (Object s:arr)
print((String)s+" ");

these are the same...i didnt check the code, it might be array or an arraylist, it works the same and it also works for primitives

edit:
just saw it is an arraylist so it is the same as this

for (int i=0; i<charges.size(); i++){
charges.get(i).doSomethingWithEachElement();
}

amnon.owed

Re: i need explanation about that formulation

9 months ago

You can find more about this when you google search terms like: java generics, for-each loop.

Reasons to use it are because it's shorter (less typing) and you don't need to cast to an Object type.

In words it would be for each Electron in the list charges run the code within brackets.