I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

Programming Questions

mult_ipli..

I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

in Programming Questions • 6 months ago

Hi There,

I have been writing a program and was going well until I encountered this seemingly small problem, which has stopped me from further programming. In the first few line of the code below (this is one of my tabs) I have continually gotten this "enexpected token: int" message when trying to run the program. I know these messages are usually given out by the program when the user has made a typo, but I have absolutely no idea what is wrong with the fuction I have written and I was hoping somone on this forum could help! Below is the tab that keeps giving me this error message, if anyone could spot the error and let me know that would be greatly appreciated!

Also, if anyone sees anything else wrong with the code, please let me know, I would be very grateful.

Thanks!

int PositionDifferenceX (int mousePositionX, int widthOfCell) { // <--- This line gives me "unexpected token: int"
return mousePositionX/widthOfCell;
}

int PositionDifferenceY (int mousePositionY, int widthOfCell) {
return mousePositionY/widthOfCell;
}

void mousePressed() {
for (float pathX = (CellVariableX*cellwidth) + cellwidth; pathX <= ((PositionDifferenceX (mouseX, (width/n)))*cellwidth); pathX = pathX + cellwidth) {
fill(random(255), random(255), random(255));
rect(pathX, CellVariableY*cellwidth, cellwidth, cellwidth);
}

for (float pathX = (CellVariableX*cellwidth) - cellwidth; pathX >= ((PositionDifferenceX (mouseX, (width/n)))*cellwidth); pathX = pathX - cellwidth) {
fill(random(255), random(255), random(255));
rect(pathX, CellVariableY*cellwidth, cellwidth, cellwidth);
}

for (float pathY = (CellVariableY*cellwidth); pathY <= ((PositionDifferenceY (mouseY, (width/n)))*cellwidth); pathY = pathY + cellwidth) {
    fill(random(255), random(255), random(255));
    rect(((CellVariableX*cellwidth) + (PositionDifferenceX (mouseX, (width/n))) - (CellVariableX*cellwidth)), pathY, cellwidth, cellwidth);
}

for (float pathY = (CellVariableY*cellwidth); pathY >= ((PositionDifferenceY (mouseY, (width/n)))*cellwidth); pathY = pathY - cellwidth) {
    fill(random(255), random(255), random(255));
    rect(((CellVariableX*cellwidth) + ((PositionDifferenceX (mouseX, (width/n)))*cellwidth) - (CellVariableX*cellwidth)), pathY, cellwidth, cellwidth);
}

fill(63, 255, 46);
rect((PositionDifferenceX (mouseX, (width/n)))*(width/n), ((PositionDifferenceY (mouseY, (width/n)))*width/n), cellwidth, cellwidth);
}

Replies(5)

pauline303

Re: I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

6 months ago

post the whole code into code bracket please !!
I have no problem with this line :

int PositionDifferenceX (int mousePositionX, int widthOfCell) { // <--- This line gives me "unexpected token: int"
return mousePositionX/widthOfCell;
}

mult_ipli..

Re: Re: I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

6 months ago

Thanks

Sorry I didn't post the whole code, here it is.

TAB 1

int n = 8;

float cellwidth;

float CellVariableX = 0.0;
float CellVariableY = 0.0;

void setup() {
size(300, 300);
background(255);
cellwidth = width/(n+0.0);
}

void draw(){
background(255);
CellVariableX = constrain(CellVariableX, 0.0, n-1.0);
CellVariableY = constrain(CellVariableY, 0.0, n-1.0);
for (float n = 0; n <= width; n = n+cellwidth) {
    line(0, n, width, n);
    line(n, 0, n, width);
    fill(0, 7, 185);
    rect(CellVariableX*cellwidth, CellVariableY*cellwidth, cellwidth, cellwidth);

}

TAB 2

int PositionDifferenceX (int mousePositionX, int widthOfCell) { // <--- This line gives me "unexpected token: int"
return mousePositionX/widthOfCell;
}

int PositionDifferenceY (int mousePositionY, int widthOfCell) {
return mousePositionY/widthOfCell;
}

TAB 3

void keyPressed() {
if (keyCode == RIGHT) {
    CellVariableX += 1;
}
if (keyCode == LEFT) {
    CellVariableX -= 1;
}
if (keyCode == UP) {
    CellVariableY -= 1;
}
if (keyCode == DOWN) {
    CellVariableY += 1;
}
}

GoToLoop

Re: I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

6 months ago

Washed them up and glued them together:

final static byte NUM = 8;
int cellWidth;
int cellVariableX, cellVariableY;

final static String GFX = P2D; // use JAVA2D for Processing 2+

void setup() {
  size(400, 400, GFX);
  noLoop();
  smooth();
  cellWidth = width/NUM;
}

void draw() {
  background(-1);
  fill(0, 7, 185);

  cellVariableX = constrain(cellVariableX, 0, NUM - 1);
  cellVariableY = constrain(cellVariableY, 0, NUM - 1);

  for (int q = 0; q < width; q += cellWidth) {
    line(0, q, width, q);
    line(q, 0, q, width);

    rect(cellVariableX*cellWidth, cellVariableY*cellWidth, 
    cellWidth, cellWidth);
  }

  if (mousePressed)  drawPath();
}

void keyPressed() {
  redraw();

  final int k = keyCode;

  if (k == UP | k == 'W')          --cellVariableY;
  else if (k == DOWN  | k == 'S')  ++cellVariableY;
  else if (k == LEFT  | k == 'A')  --cellVariableX;
  else if (k == RIGHT | k == 'D')  ++cellVariableX;
}

void mousePressed() {
  redraw();
}

void mouseReleased() {
  redraw();
}

void drawPath() {
  int cellX = cellVariableX*cellWidth;
  int cellY = cellVariableY*cellWidth;

  for (int pathX = cellX + cellWidth; pathX <= mouseX; pathX += cellWidth) {
    fill( (color) random(0x1000000) | #000000 );
    rect(pathX, cellY, cellWidth, cellWidth);
  }

  for (int pathX = cellX - cellWidth; pathX >= mouseX; pathX -= cellWidth) {
    fill( (color) random(0x1000000) | #000000 );
    rect(pathX, cellY, cellWidth, cellWidth);
  }

  for (int pathY = cellY; pathY <= mouseY; pathY += cellWidth) {
    fill( (color) random(0x1000000) | #000000 );
    rect(mouseX/cellWidth, pathY, cellWidth, cellWidth);
  }

  for (int pathY = cellY; pathY >= mouseY; pathY -= cellWidth) {
    fill( (color) random(0x1000000) | #000000 );
    rect(mouseX, pathY, cellWidth, cellWidth);
  }

  fill(63, 255, 46);
  rect(mouseX, mouseY, cellWidth, cellWidth);
}

mult_ipli..

Re: Re: I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

6 months ago

Thank you very very much, I really appreciate the help

. You just save me a lot of time. Yeah I was trying to put my code that draws a path into different setups and whenever I paste it the indenting gets stuffed up again, which is annoying :/ The error started happening after I pasted it, so maybe I accidentally deleted the closing bracket of draw(). Anyway, thank you very much for your help.

PhiLho

Re: I have no idea why I keep getting this "unexpected token: int" in the first line of this function :/

6 months ago

Little trick: not only Ctrl+T (or Edit > Auto Format) makes your code to look better, but also it allows to spot this kind of error.
Here, after pasting the whole code into one tab only, I hit Ctrl+T and I immediately see that draw() is lacking its last closing brace, as expected (this error often happens when you try to define a function inside another function).

Top Reply