How would you write this code?

Programming Questions

clankill3r

How would you write this code?

in Programming Questions • 2 years ago

For the purpose of learning i always like to see how others would do it (like here: link ).
So i hope some of you guys give it a try.

PFont font1;

String t1 = "HOW WOULD YOU WRITE THIS CODE?";

int[] bytes = {
};

HackText ct; //

void setup() {
size(100, 100);
frameRate(200);

font1 = createFont("Courier", 12);
textFont(font1);

bytes = createBytes(bytes);
ct = new HackText(t1, 10, 10, bytes, 80, 80);
}

void draw() {
background(255);
fill(0);
ct.display();
}

int[] createBytes(int[] intArray) {
float charWidth;
for(int i = -128; i <= 127; i++) {
    charWidth = textWidth(char(i));
    if(charWidth > 0) {
      intArray = append(intArray, i);
    }
}
return(intArray);
}

class HackText {
boolean isHacked = false;
String data;
String hacked_data = "";
int dataIndex = 0;
int byteIndex = 0;
float x;
float y;
float tWidth;
float tHeight;
int[] bytes;

HackText(String t_data, float t_x, float t_y, int[] t_bytes) {//
    data = t_data;
    x = t_x;
    y = t_y;
    bytes = t_bytes;
}

HackText(String t_data, float t_x, float t_y, int[] t_bytes, float t_width, float t_height) {//
    data = t_data;
    x = t_x;
    y = t_y;
    bytes = t_bytes;
    tWidth = t_width;
    tHeight = t_height;
}

void display() {

    if(isHacked == false) {

      char tryByte = char(bytes[byteIndex]);//the byte to try
      char theByte = data.charAt(dataIndex);//the byte to find

      //found
      if(tryByte == theByte) {
        //add the char
        hacked_data += tryByte;
        //check if everything is found
        if(hacked_data.length() == data.length()) {
          isHacked = true;
        }
        else {
          byteIndex = 0;
          dataIndex++;
        }
      }
      //not found
      else {
        byteIndex++;

        if(byteIndex > bytes.length-1) {
          println("can't be found");
          hacked_data += theByte;
          //check if the String is complete now
          if(hacked_data.length() == data.length()) {
            isHacked = true;
          }
          else {
            byteIndex = 0;
            dataIndex++;
          }
        }
      }
      if(tWidth > 0) {
        text(hacked_data+tryByte, x, y, tWidth, tHeight);
      }
      else {
        text(hacked_data+tryByte, x, y);
      }
    }
    else {//text is hacked
      if(tWidth > 0) {
        text(hacked_data, x, y, tWidth, tHeight);
      }
      else {
        text(hacked_data, x, y);
      }
    }
}
}

Replies(5)

davbol

Re: How would you write this code?

2 years ago

aside - i'd suggest that this type of experiment is better if you provide a "functional spec", not just code, otherwise it can be hard to tell what is required behavior or not. graphically, this seems similar:

String source = "HOW WOULD YOU WRITE THIS CODE?";
String hacked = "";
int index, ascii;

void setup() {
size(100, 100);
frameRate(200);
textFont(createFont("Courier", 12));
}

void draw() {
background(255);
fill(0);
if (index < source.length()) {
    char testchar = (++ascii < 32) ? 0 : (char)(ascii);
    hacked = hacked.substring(0,index) + testchar;
    if (testchar == source.charAt(index)) {
      index++;
      ascii = 0;
    }
}
text(hacked,10,10,80,80);
}

clankill3r

Re: How would you write this code?

2 years ago

what do you mean with "functional spec"?

Anyway your code is nice, much more understandable.
The substring is smart (does that make you smart?).

Can you explain this:

char testchar = (++ascii < 32) ? 0 : (char)(ascii);

I don't get (++ascii < 32) and (char)(ascii)

thanks btw

PhiLho

Re: How would you write this code?

2 years ago

"functional spec"
Describe what you want your program to do.

(++ascii < 32)
Increment the variable, and test if it is below 32 (the Ascii code for space: if below, it is a non-displayable control char).

(char)(ascii)
Convert the int number to a char. Could have been written (char) ascii

davbol

Re: How would you write this code?

2 years ago

yep, phi.lho answered it. i put that bit in only to simulate the "delay" present in your original. another "challenge" exercise, if you'd like, might be to try to rewrite it without using that "hacked" variable at all, just the source string and the indices - it's very possible, give it a shot. cheers

clankill3r

Re: How would you write this code?

2 years ago

Thx,

are you aware that you first show 31 times a white character each time?

Here is my code without the hacked value (and without the white char 31 times)
Thx for tip :)

String source = "HOW";
int index;
int ascii = 32;
char testchar;

void setup() {
size(100, 100);
frameRate(50);
textFont(createFont("Courier", 12));
}

void draw() {
background(255);
fill(0);
if (index < source.length()) {
    ascii++;
    testchar = char(ascii);
    if (testchar == source.charAt(index)) {
      index++;
      ascii = 32;
    }
}
if(index != source.length())text(source.substring(0, index) + testchar,10,10,80,80);
else text(source.substring(0, index),10,10,80,80);
}

Top Reply