how to use strings in a calculation?

PhiLho

Re: how to use strings in a calculation?

3 years ago

It is not an easy problem... But there are a number of Java libraries / classes allowing such parsing and computation. Perhaps you can pick one suiting your needs (does it has to support trigonometry and other functions?) and use it.
One can also use the JavaScript interpreter built in Java (Rhino) to do such computations...

bluurryy

Re: Re: how to use strings in a calculation?

3 years ago

so there's no easier method to do this? it has to support every kind of functions..

I've worked out to do all on my own and without other libraries.. would be a pity to now (at the end) take one.. but thanks anyway..

are there other possibilities?

noncom

Re: how to use strings in a calculation?

3 years ago

First, try looking into this: http://en.wikipedia.org/wiki/Polish_notation, this way is usually implemented in all compilers to evaluate expressions.

Second, well, I can tell you about a method that I am thinking about for the last two weeks. It seems to be an interesting concept, although I did not yet implement it myself, so there may be some underwater stones, I do not know...

The idea is about using classes for completing the task. Each mathematical action like add/sub/mul/div each takes 2 arguments. So there has to be a class (let's name it Element) with a value property, an action property and with 2 references for Element objects. By parsing an expression into a tree-like structure of such objects, not only you can get it calculated, but also it gives you a very flexible expression manipulation. Evaluation order (like * must be done before +) is also very important to track.

In any way you will need to convert strings to ints and floats(if needed), so you might also be interested in diging up methods of doing this. Fortunately there are many examples over the net.

supermano..

Re: how to use strings in a calculation?

3 years ago

I may be missing the point or your intentions here, but the dirty (easy) way is simply too cast the tokenized values to a data type that can sustain a mathematical operation (ie anything but a String or Boolean).

Example:

//----- Some String values
String x = "240";
String y = "360";

//----- Do a calculation
float calculation = float(x) * float(y);
println( "The result of the calculation is " + calculation );

//----- Cast string to float
stroke(200);
strokeWeight(15);
point( float(x), float(y) );

noncom

Re: how to use strings in a calculation?

3 years ago

2Supermanoeuvre: Yes, but I think that it only partially covers what Bluurryy was trying to implement. The catch is in handling free-form expressions with all their custom mathematical operations. So that the problem is that you do not know the operations in the expression in advance..

bluurryy

Re: Re: how to use strings in a calculation?

3 years ago

yes.. exactly.. but would it be possible to first have a look at the different strings and compare them with some operators. and then if they're identic, I take the two strings and can calculate with them..

quite "dirty", too but also possible, or not?

but this wouldn't work with "sin" for sinus as string or something like that..

the people who have made this library, how have they solved this problem?

I think the method with the classes wouldn't be that bad. is this the solution the writer of this library used?

PhiLho

Re: how to use strings in a calculation?

3 years ago

As I wrote, the best is to search and look at some of the numerous implementations of this problem (search expression evaluator, for example).
The traditional way is to parse the expression, putting the found tokens (numbers, operators, functions) in a tree, showing the parenthesis levels (eg. (2 + x) * (5 + sqrt(x - 4)) would need several branches).
Then you evaluate the tree, replacing the parameter(s) with their values.

Jack Kern

Re: how to use strings in a calculation?

3 years ago

I can't say I'm very proud of the code in this implementation, but it works. I've extracted this expression evaluator from an old version of my l-script parser because it is more concise. Hopefully this will help you finish your project!

(edit: Updated to fix HTML formatting)


HashMap<String, Float> variables = new HashMap<String, Float>();

final int EXPR_VALUE  = 1;
final int EXPR_LPAREN = 2;
final int EXPR_RPAREN = 3;
final int EXPR_OP     = 4;

// ------------------------------------------------------------------------ //
void setup()
{
  size( 400, 400 );
  noLoop();
  
  // Simple expression evaluation:
  String expr = "1 + (10.5 + 5) /2";
  println( expr + " = " + Evaluate(expr) );
  
  background(255);
  
  // Draw the axis
  stroke(0);
  line(0,height/2,width,height/2);
  line(width/2,0,width/2,height);
  
  // Plot some expressions
  strokeWeight(2);
  stroke( 255,0,0 );
  PlotExpression( "x ^ 3" );
  
  stroke( 0,255,0 );
  PlotExpression( "2*x + 4" );
  
  stroke( 0,0,255 );
  PlotExpression( "x^(1/2)" );
}

// ------------------------------------------------------------------------ //
void PlotExpression( String expression )
{
  float previousY = width/2;
  for( int i=0; i<width; ++i )
  {
    SetValue( "x", map( i, 0, width, -10, 10 ) );
    
    float y = map( Evaluate( expression ), -10, 10, 0, height );
    line( i, y, i-1, previousY );
    previousY = y;    
  }    
}

// ------------------------------------------------------------------------ //
protected float Evaluate( String strExpression )
{
  return Evaluate( new StringTokenizer( strExpression.toLowerCase() ) );    
}

// ------------------------------------------------------------------------ //
protected float Evaluate( StringTokenizer st )
{
  // Let's get all the tokens into an array
  int       nTokens   = st.countTokens();
  int       nTok      = 0;
  String [] strTokens = new String[nTokens];
  char   [] Chars     = { '(',')','+','*','/','%','^' };
  
  for( int i = 0; i <  nTokens; ++i )
  {
    String    strTok  = st.nextToken();
    String [] NewToks = SplitAtChars( Chars, strTok );
    
    if( NewToks != null )
    {
      strTokens = expand( strTokens, strTokens.length + NewToks.length - 1 );
      for( int k=0; k < NewToks.length; ++k )
        strTokens[nTok++] = NewToks[k];
    }
    else
      strTokens[nTok++] = strTok;
  }

  return EvaluateExpr( strTokens );
}

// ------------------------------------------------------------------------ //
protected float GetValue( String name )
{
  if( name.length() == 0 ) return 0;
  if( (name.charAt(0) >= '0' && name.charAt(0) <= '9') ||
      name.charAt(0) == '.' )
  {
    float  value = 0;
    try  { value = Float.valueOf( name ); } catch ( Exception e ) {}
    return value;
  }
  
  if( variables.containsKey(name) )
    return variables.get(name); // Auto-unboxed
    
  return 0;
}

// ------------------------------------------------------------------------ //
protected void SetValue( String name, float value )
{
  variables.put( name, value );
}

// ------------------------------------------------------------------------ //
protected boolean ExprIsOp( char op )
{
  return op == '+' || op == '-' || op == '*' || op == '/' || op == '%' || op == '^';
}

// ------------------------------------------------------------------------ //
protected float ExprOperation( float v0, String strOp, float v1 )
{
  if( strOp == null )
    return 0.f;
    
  char op = strOp.charAt(0);
  switch( op )
  {
    case '+': return v0 + v1;
    case '-': return v0 - v1;
    case '*': return v0 * v1;
    case '/': return v0 / v1;
    case '%': return v0 % v1;
    case '^': return pow(v0, v1);
  }
  return 0.f;
}

// ------------------------------------------------------------------------ //
protected int GetExprTokenType( String strToken )
{
  if( strToken.length() == 1 )
  {
         if( strToken.charAt(0) == '('    ) return EXPR_LPAREN;
    else if( strToken.charAt(0) == ')'    ) return EXPR_RPAREN;
    else if( ExprIsOp(strToken.charAt(0)) ) return EXPR_OP;
  }
  return EXPR_VALUE;
}

// ------------------------------------------------------------------------ //
protected int FindMatchingParen( String [] strTokens )
{
  int nParen = 1;
  for( int i=1; i < strTokens.length; ++i )
  {
    if( strTokens[i] == null || strTokens[i].length() != 1 )
      continue;
    
         if( strTokens[i].charAt(0) == '(' ) ++nParen;
    else if( strTokens[i].charAt(0) == ')' ) --nParen;
    
    if( nParen == 0 )
      return i;
  }
  return strTokens.length;
}

// ------------------------------------------------------------------------ //
protected float EvaluateExpr( String [] strTokens )
{    
       if( strTokens.length == 1 ) return GetValue( strTokens[0] );
  else if( strTokens.length == 2 ) return 0.f;
  else if( strTokens.length == 3 )
  {
    return ExprOperation( GetValue( strTokens[0] ), strTokens[1], GetValue( strTokens[2] ) );
  }
  else if( strTokens.length > 3  )
  {
    int nType = GetExprTokenType( strTokens[0] );
    if( nType == EXPR_LPAREN )
    {
      int nIndex = FindMatchingParen( strTokens );
      
      // If we couldn't find it then return, incomplete expression
      if( nIndex == strTokens.length )
        return 0;
      
      // If the matching parenthesis is the last token, then the expression is just inside
      if( nIndex == strTokens.length - 1 )
      {
        return EvaluateExpr( subset( strTokens, 1, nIndex - 1 ) );
      }
      else
      {
        int nOpIndex    = nIndex   + 1;
        int nRightIndex = nOpIndex + 1;
        
        // Compute the left side
        float left = EvaluateExpr( subset( strTokens, 1, nIndex - 1 ) );
        
        // Compute the right side
        float right = EvaluateExpr( subset( strTokens, nRightIndex, strTokens.length - nRightIndex ) );
        
        // Return the result
        return ExprOperation( left, strTokens[nOpIndex], right );
      }
    }
    else if( nType == EXPR_VALUE ) // Value
    {
      float v1 = GetValue( strTokens[0] );
      float v2 = EvaluateExpr( subset( strTokens, 2, strTokens.length - 2 ) );
      return ExprOperation( v1, strTokens[1], v2 );
    }
  }
  
  return 0.f;
}

// ------------------------------------------------------------------------ //
String [] SplitAtChars( char[] ch, String strTok )
{
  // Don't return anything if the token's only a char
  if( strTok.length() <= 1 )
    return null;
    
  // Don't return anything if we don't have anything to split
  boolean bFound = false;
  for( int i=0; i < ch.length; ++i )
    if( strTok.indexOf(ch[i]) >= 0 )
    {
      bFound = true;
      break;
    }
    
  if( !bFound ) return null;

  // Split up the string
  int       nChrIndex = 0;
  int       nTok      = 0;
  int       nDone     = strTok.length();
  String [] ret       = new String[1];
  
  for(;;)
  { 
    int i=0;
    nChrIndex = -1;
    for( ; i < ch.length && nChrIndex == -1; ++i )
      nChrIndex = strTok.indexOf(ch[i]);
    if( nChrIndex == -1 )
    {
      ret[nTok++] = strTok;
      break;
    }
    --i;
    for( ; i < ch.length; ++i )
    {
      int nNewIndex = strTok.indexOf(ch[i], 0);
      if( nNewIndex == -1 ) nNewIndex = nDone;
      nChrIndex = min( nChrIndex, nNewIndex );
    }

    int nLen = strTok.length();
    if( nLen > 1 )
    {
      ret = expand( ret, ret.length + 3 );
      if( nChrIndex == 0 )
        nChrIndex = 1;

      ret[nTok++]   = strTok.substring(0, nChrIndex);
      strTok        = strTok.substring(nChrIndex);
    }
    else
    {
      ret[nTok++]   = strTok;
      break;
    }
  }

  return subset( ret, 0, nTok );
}

http://www.jackkern.com
http://www.twitter.com/ElectricJack

bluurryy

Re: Re: how to use strings in a calculation?

3 years ago

what I understand seems to be great, jack.kern

but I can't copy this code into my sketch because of following things:

1. what does the very first line mean? there's an error ?

2. there are more errors, because of this for example:

for( int i=0; iString strTok = st.nextToken();
String [] NewToks = SplitAtChars( Chars, strTok );

I don't know what this mean.. I've never seen such a for-loop.. so is this the code that should work? if yes, what is my mistake?

would be very nice of you to help me to get your sketch working, because this ( I think ) would be great.

Jack Kern

Re: how to use strings in a calculation?

3 years ago

Oh, make sure you're using the latest version of Processing (1.2.1) as it has support for generics - I'm using that in the HashMap <String, Float> declaration. It shouldn't have any other dependencies.

The for loop is just a single statement so it doesn't need the { and } brackets, which just tells the compiler to group the internal set of statements into one statement for the loop to execute. Make sense?

Jack

http://www.jackkern.com
http://www.twitter.com/ElectricJack

Jack Kern

Re: how to use strings in a calculation?

3 years ago

That last response was careless, my applogies -- I have updated my posting above and tested that it can be copied and pasted into Processing successfully. It appears there is a bug in the Copy to HTML from processing that leaves the < operator in the HTML inside for loops.

bluurryy

Re: Re: how to use strings in a calculation?

3 years ago

yes.. thanks.. now it works.. and seems to be what I was looking for..

but for example if you type in the equation: -x^2 the program only draws the line y=0 ?

PhiLho

Re: how to use strings in a calculation?

3 years ago

Apparently there is a small bug with negative values. If you try 0 - x ^ 2 it will work. As I wrote, math expression parsing isn't obvious... (but you did a good job, Jack!)