How to use rotate() function to giving degrees to rotate to certain angle

Programming Questions

pixelated..

How to use rotate() function to giving degrees to rotate to certain angle

in Programming Questions • 5 months ago

Hi,

I am very new to processing but each day i learn a new thing. Here is my setup explained below.

I have a Variable resistor connected to Arduino A0 pin and when it turns the serial data goes to PC and in the processing i draw some thing like in the image. Assume the grey color object is a flap of an ROV.

Now i turn the VR it moves to both direction. What i want is when i send 5 degrees it should go 5 degrees and when i send negative 5 degrees or some other way it should go down.

Arduino code

int vr = 0;

float midvr = 90;

float vrdef = 0;

void setup(){

Serial.begin(9600);

}

void loop(){

Serial.println(analogRead(A0));

delay(200);

}

Processing code

import processing.serial.*;

Serial myPort;// serial port

float r = 0;

float d = 90;

void setup(){

size(400,400);

background(147,147,147);

rectMode(CENTER);

println(Serial.list());

myPort = new Serial(this, Serial.list()[1], 9600);

myPort.bufferUntil('\n');

//rotate(0);z

//rect(0,0,200,20);

frameRate(20);

noStroke();

smooth();

}

void draw(){

background(147,147,147);

fill(165,232,42);

translate(width/2,height/2);

//translate(mouseX,mouseY);

String inString = myPort.readStringUntil('\n');

if (inString != null) {

// trim off any whitespace:

inString = trim(inString);

// convert to an int and map to the screen height:

float inByte = float(inString);

inByte = map(inByte, 0, 1023, 0,180 );

//println(inByte);

float deg = inByte;

float rad = radians(deg);

// if(deg >= d){

// rotate(rad/2);

// // rotate(rad);

// ellipse(0, 0, 200, 25);

// } else if (deg <= d) {

// rotate(rad/2);

// ellipse(0, 0, 200, 25);

// } else if (deg == 0); {

// rotate(rad/2);

// ellipse(0, 0, 200, 25);}

//float deg = degrees(rad);

println(rad + " radians is " + deg + " degrees");

rotate(rad);

textSize(32);

text(deg + " °",0,50);

// text(" °");

//rect(0,0,200,20);

ellipse(0, 0, 200, 25);

//r= inByte + 1;

}

Hope to get a solution or some guidelines to follow

Thanks

Replies(11)

amnon.owed

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

So what's the problem?

pixelated..

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

problem is i could not make it work the way i want to...

The way i want it to work:

When the VR is at center position the flap should be like this diagram below.

Sorry that i am not so good at explaining this in degrees..

Thats how it should work so is there any idea or help?

quarks

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

First thing is that in computer graphics increasing the rotation angle rotates an object in the clockwise direction. Zero degrees is facing east so 90 degrees faces south (not north as you have drawn it).

In your sketch you need to 'map' the range of possible output values from the Arduino borad to a suitable angle.

In the sketch below I have two 'flaps' which rotate from -PI to +PI radians (-180 to + 180 degrees) depending on the mouse position. The left flap depends on X position and the right flap depends on the Y position.

The key to the problem are lines 9 and 10 which map the mouse positional value to a suitable angle range

float ang1, ang2; // radians
void setup() {
size(400, 400);
}
void draw() {
background(255);
ang1=map(mouseX, 0, width, -PI, PI);
ang2=map(mouseY, 0, height, -PI, PI);
drawFlap(width/4, height/2, ang1);
drawFlap(3*width/4, height/2, ang2);
}
void drawFlap(float x, float y, float a) {
pushMatrix();
translate(x, y);
rotate(a);
stroke(64, 64, 255);
fill(200, 200, 255);
ellipse(0, 0, 80, 20);
fill(64, 64, 255);
ellipse(0, 0, 6, 6);
line(0, 0, 40, 0);
popMatrix();
}

pixelated..

Re: Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

Since i am new to this i was not aware or sure of that. Anyway quarks, thank you a lot for the help and will let you know if there is any issue after Arduino sketch modifications..

So my processing code is not a correct way of coding for computer graphics right? with your all help someday i will be able to learn this much better..

Thank you quarks

quarks

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

So my processing code is not a correct way of coding for computer graphics right?

No, it was just that I observed that you had 90 degrees facing north rather than south. OK for school geometry where we learnt that the y axis went up, but on computer displays the y axis goes down.

with your all help someday i will be able to learn this much better..

there are lots of people on this forum that have extensive programming experience who can help you, but don't forget they all started the same way as you.

pixelated..

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

Quarks, yes you are right. The thing we learn from school is bit different from what computer display does.

Yes someday i will also be like you all... thanks for support.

I already done some modifications to the processing code and it work now when the VR is turned.

pixelated..

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

hi Quarks, this is what i did later and when VR is in center position (Arduino outputs 512) the flap is in horizontal position. so i assume now this is working.. am i doing it correct or anything silly.

//float ang1, ang2; // radians
import processing.serial.*;
Serial myPort;// serial port
void setup() {
size(400, 400);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 9600);
myPort.bufferUntil('\n');
frameRate(5);
}
void draw() {
background(255);
String inString = myPort.readStringUntil('\n');
if (inString != null) {
// trim off any whitespace:
inString = trim(inString);
// convert to an int and map to the screen height:
float ang2 = float(inString);
println(ang2);
//inByte = map(inByte, 0, 1023, 0,180 );
//ang1=map(mouseX, 0, width, -PI, PI);
ang2=map(ang2, 0, 1023, -PI, PI);
//drawFlap(width/4, height/2, ang1);
drawFlap(3*width/4, height/2, ang2);
}
}
void drawFlap(float x, float y, float a) {
// println(x);
// println(y);
println(a);
pushMatrix();
translate(300,200);
rotate(a);
stroke(64, 64, 255);
fill(200, 200, 255);
ellipse(0, 0, 80, 20);
fill(64, 64, 255);
ellipse(0, 0, 6, 6);
line(0, 0, 40, 0);
popMatrix();
}

quarks

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

Looks good to me - line 30 assumes suggests that the Arduino output varies from 0 to a maximum 1023 for other output ranges simply change the second and third parameter.

pixelated..

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

Yep Arduino outputs from 0-1023. if i want to display the values in degrees on processing side what should i do..

quarks

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

ang2 - is the angle in radians you can convert this to degrees with

float ang2Deg = degrees(ang2);

to display the result use the text method e.g.

fill(255,0,0); // want red text
text("" + ang2Deg, 20,50); // (text to display, x pos, y os

pixelated..

Re: How to use rotate() function to giving degrees to rotate to certain angle

5 months ago

Thanks quarks...i also tried the same concept as in my old code...it works perfectly ...

thankyou

Top Reply