How to specify P3D renderer in a subsidiary frame?

Programming Questions

rjh1230

How to specify P3D renderer in a subsidiary frame?

in Programming Questions • 1 year ago

I have some 3D graphics running ok in a simple application where the 3D functionality is obtained by specifying P3D in the size() call.
I am now extending and re-organising the application to put the 3D graphics in a subsidiary window.
I am creating the second window with - "class animationFrame extends JFrame { etc etc" - but the size() call is not recognised in this and so I can see no way of specifying P3D.
I suspect that the problem comes from choosing JFrame, but this was because it allows me to specify setDefaultCloseOperation() which is one of my requirements.
Can anyone help me untangle this?

Replies(2)

hellochar

Re: How to specify P3D renderer in a subsidiary frame?

1 year ago

size() and all of the methods used in Processing are possible because the sketches are subclasses of PApplet, which itself extends javax.swing.Applet. To put 3D drawing in a second frame, I'd suggest creating a subclass of PApplet and then instantiating one which is then added into a new JFrame. Like this:

import javax.swing.JFrame; //import JFrame
void setup() {
size(500, 500);
JFrame f = new JFrame(); //create your new frame
Draw3D d = new Draw3D(); //create your new Processing sketch
f.add(d); //add the sketch to the frame
d.init(); //You must call init() for Processing to set itself up
f.pack(); //Properly sets the size of the frame to that of the sketch
f.setVisible(true); //show it
}
void draw() {
println("drawing 2D stuff!");
background(204);
translate(width/2, height/2);
rotate(millis() / 1000f);
rect(0, 0, 100, 100);
}
//I declare a new class that extends PApplet, meaning it now has access to all of Processing's drawing capabilities
class Draw3D extends PApplet {
void setup() {
size(500, 500, P3D);
}
void draw() {
println("drawing 3D stuff!");
background(204);
translate(width/2, height/2);
rotateX(millis() / 1000f);
rotateY(millis() / 1250f);
box(25, 25, 25);
}
}

rjh1230

Re: Re: How to specify P3D renderer in a subsidiary frame?

1 year ago

So simple eh? - Many thanks,
Jim

Top Reply