how to reset a class function variable

Programming Questions

v.k.

how to reset a class function variable

in Programming Questions • 1 year ago

I isolated this piece of code to make this question. I feel that there is an easy and obvious way to do this, but i just can't see it... So i came here for help.

How to reset the "amount" after color finished to change. I'd like the object to do this by it self. Is that possible?

Just click to change color, with line commented out, if you click again and again the color will not animate because the amount is already 1. If you uncomment the line inside mouseClicked(), will get the behaviour i'd like.

ColorAnimator blender = new ColorAnimator();
color c1 = color (255, 100, 100);
color c2 = color ( 50, 240, 120);
boolean animate =false;
void setup()
{
size (300,300);
background(c1);
}
void draw()
{
if (animate)
background(blender.animate(c1, c2, 0.02));
else
background(c1);
}
void mouseClicked()
{
animate = !animate;
//blender.amount = 0; // uncomment this to get the desired behavior
}
class ColorAnimator
{
float amount = 0;
ColorAnimator()
{}
color animate(color c1, color c2, float speed)
{
color ccc;
while(amount< 1.0)
{
ccc= lerpColor(c1,c2, amount);
println(ccc);
amount+=speed;
return ccc;
}
return c2;
}
}// eof Animator class

Replies(5)

Christian..

Re: how to reset a class function variable

1 year ago

i don't know exactly if i understood your problem, but you can tell me after trying this:

blender.amount = 0;
animate = !animate;
return c2;

add the two lines before the return in the animator class.

Cheers,
Chris

PhiLho

Re: how to reset a class function variable

1 year ago

You wrote:

color animate(color c1, color c2, float speed)
{
color ccc;
while(amount< 1.0)
{
ccc= lerpColor(c1,c2, amount);
println(ccc);
amount+=speed;
return ccc;
}
return c2;
}

The while isn't useful with an unconditional return there.
The code might be:

color animate(color c1, color c2, float speed)
{
if (amount< 1.0)
{
color ccc= lerpColor(c1,c2, amount);
println(ccc);
amount+=speed;
return ccc;
}
amount = 0; // Reset the animation at the end
return c2;
}

instead.
And you should report the end of the animation to the main program:

boolean isAnimating()
{
return amount == 0;
}

Thus the draw becomes:

void draw()
{
if (animate)
background(blender.animate(c1, c2, 0.02));
else
background(c1);
animate = blender.isAnimating();
}

Or something like that (untested).

Looking closer at Chris' solution, I see that's close of mine, except in general I prefer to use as little as possible global variables like animate in classes.

v.k.

Re: how to reset a class function variable

1 year ago

Thanks PhiLho and Chris. Chris solution works just as expected, after animation ends the color is hold and the program waits for a user click, to re-run the animation, while PhiLho's way the animation resets as desired but goes forever in a loop. I wanted the first behaviour, though I also try to avoid using global variables in classes... In fact the question was more this, I'm sure I could handle this behaviour in "draw/mouseClicked" but I was trying to avoid this to make the class more independent...

It's more a learning best practices issue, than of this program specifically.

Any way I don't understand why the animation goes in a loop if we are setting animate to 'false' after animation is done in line:

animate =blender.isAnimating();

Shouldn't it stops once "if(animate)" doesn't met? And one more thing. PhiLho, although i tested an see it works i did not know this kind of notation " return amount == 0;" How does this works? Is it possible just because 'amount' is constrained in between 0.0 and 1.0 (booleans are 1 or 0 right)? Thanks guys, below the two suggestions incorporated in the code for easy trying:

Chris suggestion:

ColorAnimator blender = new ColorAnimator();
color c1 = color (255, 100, 100);
color c2 = color ( 50, 240, 120);
boolean animate =false;
void setup()
{
size (300, 300);
background(c1);
}
void draw()
{
if (animate)
{
background(blender.animate(c1, c2, 0.02));
}
else
{
background(c1);
}
}
void mouseClicked()
{
animate = !animate;
//blender.amount = 0; // uncomment this to get the desired behavior
}
class ColorAnimator
{
float amount = 0;
ColorAnimator()
{
}
color animate (color c1, color c2, float speed)
{
color ccc;
while (amount< 1.0 )
{
ccc= lerpColor(c1, c2, amount);
println(ccc);
amount+=speed;
return ccc;
}
amount = 0; // here i used amount instead blender.amount as we are inside class...
animate = !animate;
return c2;
}
}// eof Animator class

PhiLho's suggestion

ColorAnimator blender = new ColorAnimator();
color c1 = color (255, 100, 100);
color c2 = color ( 50, 240, 120);
boolean animate =false;
void setup()
{
size (300, 300);
background(c1);
}
void draw()
{
if (animate)
{
background(blender.animate(c1, c2, 0.02));
}
else
{
background(c1);
animate =blender.isAnimating();
}
}
void mouseClicked()
{
animate = !animate;
//blender.amount = 0; // uncomment this to get the desired behavior
}
class ColorAnimator
{
float amount = 0;
ColorAnimator()
{
}
color animate (color c1, color c2, float speed)
{
color ccc;
while (amount< 1.0 )
{
ccc= lerpColor(c1, c2, amount);
println(ccc);
amount+=speed;
return ccc;
}
amount = 0;
return c2;
}
boolean isAnimating()
{
return amount == 0;
}
}// eof Animator class

PhiLho

Re: how to reset a class function variable

1 year ago

You forgot to change the while with an if (not important, but more logical) and you put the animate = blender.isAnimating(); line at the wrong place: I haven't put it in the else part!
On my side, I made an error too: isAnimating should be return amount != 0;

v.k.

Re: how to reset a class function variable

1 year ago

"edited" I found it here .

Ops, true... fixed and working. thanks. ~~Still, the " return amount != 0;" means return true if not zero?~~

Top Reply