How to remember where the cursor went.....

Programming Questions

sanspot

How to remember where the cursor went.....

in Programming Questions • 2 years ago

Dear all

I've been trying to this for a few days but I'm ashamed to say I'm stuck....

The code I'm doing is meant to visualize a project I'm working on. Basically it's a bunch of lamps that reacts to the user interaction by dimming on and off...Pretty straightforward....

On the screen you have two light sources ( two ellipses) and the mouse cursor is playing as the visitor: the closest the visitor/cursor the more the light dim; and this is what I called first behavior. Now I'd like to add a new behavior that is triggered whenever the visitor/cursor stands still; I'd like to make Processing understand that the cursor is still for, let's say 3 seconds, and start a new behavior, like changing color to the light (I haven't figure out exactly what but let's stick to that now).

Here is the code;

Lamp myLamp;

Lamp myLamp2;

void setup(){

size(800,600);

background(0);

smooth();

myLamp = new Lamp(200,150);

myLamp2 = new Lamp (500,300);

}

void draw() {

myLamp.display();

myLamp2.display();

println(" c value is " + myLamp.c + " and mouse X is " + mouseX);

}

This is the class used to define the Lamp Object attributes

class Lamp {

//data

float posX;

float posY;

int ellipseWidthHeight;

float c; // the color of the speheres (will change with mouse positioning)*/

constructors assign values to the attributes.

Lamp(float tempPosX, float tempPosY) {

posX = tempPosX;

posY = tempPosY;

ellipseWidthHeight = 50;

}

methods determine what to do with the constructors

void display() {

ellipseMode(CENTER);

//color c is set by calculating distance beteween mouse pointer and center of te circles

c = dist(posX, posY, mouseX, mouseY);

fill (c);

ellipse(posX, posY, ellipseWidthHeight, ellipseWidthHeight);

}

So the dimming effect is done by assigning to the fill() a value (C) that is the Distance between MouseX and Y and the center of the ellipses.

What I tried to do without success is reading the Mouse XandY: if the value stays the same for 3 seconds ( = the cursor is still ) then do something.....

Any idea on how to do this?

Replies(3)

ignivome

Re: How to remember where the cursor went.....

2 years ago

To get the last mouse position value, look at pmouseX
http://processing.org/reference/pmouseX.html

Also, take a look at millis()
http://processing.org/reference/millis_.html

amnon.owed

Re: How to remember where the cursor went.....

2 years ago

Your question is not so much about where the cursor went, but about if it moved. Fortunately there is a function in Processing already that keeps track of this and it is called mouseMoved(). You can use that function to track if the mouse has moved or inversely for how long it hasn't moved.

I've adapted your code, see below. The changes I made are:

I've added color to the lamps and constrained the transparency between 0 and 255.
If the mouse is moved the time of movement (in milliseconds since the start of the sketch) is saved to lastMove. If more than 3000 milliseconds (aka 3 seconds) pass since the last movement of the mouse, something happens. In this case the colors of both lamps change. To prevent constant color changes from that point onwards, the lastTime is also set again. So when the mouse is not moved, the color changes every 3 seconds.
Moved background(0) to draw. This looks better and also once things start moving you will really see the difference. ;-)

Code Example

Lamp myLamp;
Lamp myLamp2;
int lastMove;
void setup() {
size(800, 600);
smooth();
myLamp = new Lamp(200, 150);
myLamp2 = new Lamp (500, 300);
}
void draw() {
background(0);
myLamp.display();
myLamp2.display();
if (millis() - lastMove > 3000) {
lastMove = millis();
myLamp.c = color(random(255),random(255),random(255));
myLamp2.c = color(random(255),random(255),random(255));
// myLamp.doSomething(); // you could also call a function
}
}
void mouseMoved() {
lastMove = millis();
}
class Lamp {
float posX;
float posY;
int ellipseWidthHeight;
float transparency;
color c;
Lamp(float tempPosX, float tempPosY) {
posX = tempPosX;
posY = tempPosY;
ellipseWidthHeight = 50;
c = color(random(255),random(255),random(255));
}
void display() {
ellipseMode(CENTER);
transparency = dist(posX, posY, mouseX, mouseY);
transparency = constrain(transparency,0,255);
fill (c,transparency);
ellipse(posX, posY, ellipseWidthHeight, ellipseWidthHeight);
}
}

sanspot

Re: Re: How to remember where the cursor went.....

2 years ago

Greeeeeat...That's what I needed to do....

I'm not very practical with coding logic and such....I know what I wanted to do and I was trying seconds() more than millis but I didn't know it was possible to make logical subtraction like that....

Basically you're saying that if actual millisecond - the last one stored in the int lastMove since the moused moved is more than 3 sec you'll start what's inside the { }, otherwise repeat after resetting the lastMove() ( just as it is in the curly brackets )...

Top Reply