How to program a 3D anaglyph brush??

General Discussion Other

genleguer..

How to program a 3D anaglyph brush??

in General Discussion • Other • 2 years ago

Hi,

I want to know if it's possible to program a 3D anaglyph brush?? Like this one below.

Thanks

Replies(8)

rapatski

Re: How to program a 3D anaglyph brush??

2 years ago

Uh.. am I colorblind? Is that anaglyph?

In general, anaglyphing just requires you to draw the scene (graphic) twice for each color, offset by some x that is determined by depth. When drawing in 2D, this would mean that you would need another control to determine the depth, or Z plane you're currently drawing in.

PhiLho

Re: How to program a 3D anaglyph brush??

2 years ago

I don't really see how this is 3D either... Perhaps the sample isn't significant.
I saw already, in exhibition or elsewhere in this forum, such request or demonstration. But doing a search with the wrong terms will be difficult...

arthurG

Re: How to program a 3D anaglyph brush??

2 years ago

This is not as complicated as it seems.

This is not 3D, just 2D I think.

You have to set an array with coordinates. When you add a new coordinate (e.g. the mouse one), you look into the array and draw a line between the new point and others points which are close.

I could post some codes here if you want.

genleguer..

Re: How to program a 3D anaglyph brush??

2 years ago

Yeah!

I would like too!! because I don't know where to start!

I have to code for the brush but I don't know how to make it 3D(anaglyph)

ArrayList hist = new ArrayList();
float joinDist = 90;

void setup() {
size(1260,640);
background(255);
}

void draw() {
}

void mouseMoved() {
stroke(0, 25);
PVector d = new PVector(mouseX, mouseY, 0);
hist.add(0,d);
for (int p = 0; p < hist.size(); p++) {
    PVector v = (PVector) hist.get(p);
    float joinChance = p/hist.size() +
      d.dist(v)/joinDist;
    if (joinChance < random(0.4))
      line(d.x, d.y, v.x, v.y);
}
}

void keyPressed() {
if (key == ' ') {
background(255);
hist.clear();
}
}

Thanks

arthurG

Re: How to program a 3D anaglyph brush??

2 years ago

Your code works fine,

For the anaglyph part, I first looked at this library : http://www.leebyron.com/else/redblue/#redblue

But it seems to be deprecated.

So I changed directly your code. I don't have anaglyph glasses to check but it seems to work :

//--------new part
float MAX_DEPTH = 40.0f;
float scaleNoise = 0.01f;
color leftColor = color (255,0,255);
color rightColor = color (0,255,255);
//------------------
ArrayList hist = new ArrayList();
float joinDist = 90;
void setup() {
size(1260,640);
background(255);
}
//--------new part
void drawAnaglyphLine (float x0, float y0, float depth0,
float x1, float y1, float depth1,
color left, color right) {
stroke (left,25);
line (x0-depth0,y0,x1-depth1,y1);
stroke (right,25);
line (x0+depth0,y0,x1+depth1,y1);
}
//------------------
void draw() {
}
void mouseMoved() {
stroke(0, 25);
PVector d = new PVector(mouseX, mouseY, 0);
hist.add(0,d);
for (int p = 0; p < hist.size(); p++) {
PVector v = (PVector) hist.get(p);
float joinChance = p/hist.size() +
d.dist(v)/joinDist;
//--------new part
if (joinChance < random(0.4)) {
float depth0 = noise (d.x*scaleNoise, d.y*scaleNoise);
depth0 = sq(depth0)*MAX_DEPTH; //sq for contrast
float depth1 = noise (v.x*scaleNoise, v.y*scaleNoise);
depth1 = sq(depth1)*MAX_DEPTH;
drawAnaglyphLine (d.x, d.y, depth0, v.x, v.y, depth1, leftColor, rightColor);
//line(d.x, d.y, v.x, v.y);
}
//------------------
}
}
void keyPressed() {
if (key == ' ') {
background(255);
hist.clear();
}
}

arthurG.

genleguer..

Re: Re: How to program a 3D anaglyph brush??

2 years ago

Wow! Thank you so much! It works very well!!

arthurG

Re: Re: How to program a 3D anaglyph brush??

2 years ago

You're welcome, it's a fun sketch. I hope I find anaglyph glasses to watch the result.

Maybe you should adjust the colors a bit. I don't think the ones I let are the best for anaglyph.

PhiLho

Re: How to program a 3D anaglyph brush??

2 years ago

Ah! It wasn't clear that you wanted to make the example to look 3D with the anaglyph method.
This method never worked for me, anyway...