how to pause & resume drawing a line ?

Programming Questions

leegs710

how to pause & resume drawing a line ?

in Programming Questions • 2 years ago

hi there :)

I'm trying to draw a line separate when some keys pressed...

I'm not using line(mouseX, mouseY, pmouseX, pmouseY)

because I want to change the code that can be used with kinect, 3D.

There is a code.

I want to make

if DOWN arrow pressed, a line ends and mouse cursor moves without drawing a line,

if UP arrow pressed, a second line starts to be drawn (separate from the first line)

any idea? TAT

It is driving me crazy plz help !!!!!!!

class Line {
ArrayList<PVector> polyline = new ArrayList<PVector>();
PVector origin;
Line() {
origin = new PVector(mouseX, mouseY);
}
void update() {
polyline.add(new PVector(mouseX, mouseY));
}
void display() {
noFill();
strokeJoin(ROUND);
stroke(0,0,255, 100);
strokeWeight(10);
beginShape();
for(PVector p : polyline){
vertex(p.x, p.y);
}
endShape();
}
}
Line l;
void setup() {
size(400, 400);
smooth();
l = new Line ();
}
void draw() {
background(0);
l.update();
l.display();
}

Replies(3)

veeableful

Re: how to pause & resume drawing a line ?

2 years ago

Do you need all those PVectors in your arraylist? If not, look at the first code. If yes, look at the second code. I disabled the alpha channel for the stroke and the background(0) on the draw() function for the first code.

class Line {
PVector[] polyline;
Line() {
polyline = new PVector[2];
}
void update() {
polyline[0] = preMousePos;
polyline[1] = curMousePos;
}
void display() {
noFill();
strokeJoin(ROUND);
stroke(0, 0, 100);
strokeWeight(10);
beginShape();
for (PVector p : polyline) {
vertex(p.x, p.y);
}
endShape();
}
}
Line l;
PVector curMousePos;
PVector preMousePos;
void setup() {
size(400, 400);
background(0);
smooth();
curMousePos = new PVector(0, 0);
preMousePos = new PVector(0, 0);
l = new Line();
}
boolean bDrawLine = true;
void draw() {
curMousePos = new PVector(mouseX, mouseY);
if (curMousePos != preMousePos) {
if (bDrawLine) {
l.update();
}
}
l.display();
preMousePos = curMousePos;
}
void keyPressed() {
if (keyCode == DOWN) {
bDrawLine = false;
}
else if (keyCode == UP) {
bDrawLine = true;
}
}

if you're really picky (just kidding :p), here's the one using ArrayList:

class Line {
ArrayList<ArrayList> slines = new ArrayList<ArrayList>();
ArrayList<PVector> polyline = new ArrayList<PVector>();
PVector origin;
Line() {
origin = new PVector(mouseX, mouseY);
slines.add(polyline);
}
void update() {
int last = slines.size()-1;
slines.get(last).add(new PVector(mouseX, mouseY));
}
void display() {
noFill();
strokeJoin(ROUND);
stroke(0, 0, 255, 100);
strokeWeight(10);
for (ArrayList<PVector> li : slines) {
beginShape();
for (PVector p : li) {
vertex(p.x, p.y);
}
endShape();
}
}
}
Line l;
void setup() {
size(400, 400);
smooth();
l = new Line ();
}
boolean bDrawLine = true;
void draw() {
background(0);
if (bDrawLine) {
l.update();
}
l.display();
}
void keyPressed() {
if (keyCode == DOWN) {
bDrawLine = false;
}
else if (keyCode == UP) {
bDrawLine = true;
l.polyline = new ArrayList<PVector>();
l.slines.add(l.polyline);
}
}

leegs710

Re: Re: how to pause & resume drawing a line ?

2 years ago

Thank you so much !!!!

You're my life saver :-D

I really appreciate your help, thanks!

veeableful

Re: how to pause & resume drawing a line ?

2 years ago

No problem! Glad it helped! :D

Top Reply