How to move more than one Object from a random startposition to a random endposition

Programming Questions

patrick457

How to move more than one Object from a random startposition to a random endposition

in Programming Questions • 9 months ago

Hello guys,

I'm new here and I make this this little Script for the university:

int anzahl = 50;
Innen q;
Kreis[] k;
Kreis[] k2;
Kreis[] k3;
void setup() {
frameRate(20);
size(1000, 500);
q = new Innen();
k = new Kreis[anzahl];
k2 = new Kreis[anzahl];
k3 = new Kreis[anzahl];
for (int i=0;i<anzahl;i++) {
k[i] = new Kreis();
k2[i] = new Kreis();
k3[i] = new Kreis();
}
}
void draw() {
background(0);
q.display();
if ((mouseX>q.rx)&&(mouseX<q.rx+q.rb)) {
if ((mouseY>q.ry)&&(mouseY<q.ry+q.rh)) {
for (int i=0;i<anzahl;i++) {
k[i].verfolgen(0.01, 7);
k2[i].verfolgen(0.005, 57);
k3[i].verfolgen(0.00125, 157);
}
}
else {
for (int i=0;i<anzahl;i++) {
k[i].display();
k2[i].display();
k3[i].display();
}
}
}
else {
for (int i=0;i<anzahl;i++) {
k[i].display();
k2[i].display();
k3[i].display();
}
}
}
class Innen {
int rx = (width/4);
int ry = (height/4);
int rb = (width/2);
int rh = (height/2);
void display() {
rect(rx, ry, rb, rh);
}
}
class Kreis {
float ex = random(q.rx, q.rx+q.rb);
float ey = random(q.ry, q.ry+q.rh);
int d = 20; //Durchmesser
float a = 25; //Abstand
//Maus-Verfolgung
void verfolgen(float easing, int z) {
noCursor();
float targetX = mouseX;
float targetY = mouseY;
if (dist(ex, ey, mouseX, mouseY)>45) {
ex += (targetX - ex) * easing;
ey += (targetY - ey) * easing;
}
else {
ex -= (targetX - ex) * easing * z;
ey -= (targetY - ey) * easing * z;
}
smooth();
stroke(255);
noFill();
ellipse(ex, ey, d, d);
stroke(100, 200, 200);
ellipse(mouseX, mouseY, d, d);
}
void display() {
noCursor();
smooth();
stroke(255);
noFill();
ellipse(ex, ey, d, d);
stroke(100, 200, 200);
ellipse(mouseX, mouseY, d, d);
float ex = random(q.rx, q.rx+q.rb);
float ey = random(q.ry, q.ry+q.rh);
}
}

I'm more or less fine with this code, but what I also want to do, is that the circles k move, if the mouse circle is outside from the rectangle, from their last position to another random position..

I was trying this thing with the random position with another Script and I really found a kind of solution, but only for ONE circle and not for more..

This is wath I try:

Kreis[] k;
int anzahl = 2;
void setup() {
size(1000, 500);
k = new Kreis[anzahl];
for (int i=0; i<anzahl; i++) {
k[i] = new Kreis();
}
}
void draw() {
background(0);
for (int i=0; i<anzahl; i++) {
k[i].display();
k[i].bewegen();
}
}
class Kreis {
float x;
float y;
float angle = 0.0; // Direction of motion
float speed = 1.5; // Speed of motion
int d = 10;
Kreis() {
x = 100; // X-coordinate
y = 50; // Y-coordinate
stroke(255);
//random(121);
}
void bewegen() {
angle += random(-0.2, 0.2);
translate(x, y);
rotate(angle);
if ((x>0) && (x<width-d)) {
if ((y>0) && (x<height-d)) {
pushMatrix();
x += cos(angle);// * speed; // Update x-coordinate
y += sin(angle);// * speed; // Update y-coordinate
popMatrix();
}
else {
angle = PI;
speed = 2.0;
}
}
else {
angle = PI;
speed = 2.0;
}
}
void display() {
ellipse(0, -10, d, d);
}
}

know.. if you put the variable "anzahl = 10".. then you will get completly another thing.. and I dont know how to match this problem..

Thx a lot for reading my Quetion.. I hope someone can help me..

Patrick

Replies(4)

GoToLoop

Re: How to move more than one Object from a random startposition to a random endposition

9 months ago

I can't quite get exactly what you want to accomplish.
However, I've made some cleanups and removed many redundancies.
Perhaps it can help you out a little:

/***
 * RunAway Bubbles (v2.0)
 * by Patrick457 (2013/Jan)
 *
 * forum.processing.org/topic/how-to-move-more-than-one-object-from-a-random-startposition-to-a-random-endposition
 */
final static byte  fps = 40;
final static byte  bubbleSize = 20;
final static float thickness = 1.5f;

final static color bg = 0, fg = 255;
final static color cursorCol = #64C8C8;

final static short kreisNum = 150;
final static Kreis[] k = new Kreis[kreisNum];

Innen q;

void setup() {
  size(1000, 500);
  frameRate(fps);
  smooth();
  noCursor();
  noFill();
  strokeWeight(thickness);

  q = new Innen();

  for (short i=0; i!=kreisNum; i+=3) {
    k[i]   = new Kreis(.01f, 7, bubbleSize);
    k[i+1] = new Kreis(.005f, 57, bubbleSize);
    k[i+2] = new Kreis(.00125f, 157, bubbleSize);
  }
}

void draw() {
  background(bg);
  q.drawRect();
  //for ( short kk=kreisNum; kk!=0; k[--kk].run() );
  for (Kreis kk: k)  kk.run();
}

class Innen {
  final int rx = width>>2, ry = height>>2;
  final int rw = width>>1, rh = height>>1;

  void drawRect() {
    rect(rx, ry, rw, rh);
  }
}

class Kreis extends Innen {
  float ex, ey, ea;
  int z, d;

  Kreis (float easing, int zz, int dd) {
    ea = easing;
    z  = zz;
    d  = dd;

    ex = random(rx, rx+rw);
    ey = random(ry, ry+rh);
  }

  void update() {
    if (dist(ex, ey, mouseX, mouseY) > d<<1) {
      ex += (mouseX - ex) * ea;
      ey += (mouseY - ey) * ea;
    }
    else {
      ex -= (mouseX - ex) * ea * z;
      ey -= (mouseY - ey) * ea * z;
    }
  }

  void display() {
    stroke(fg);
    ellipse(ex, ey, d, d);

    stroke(cursorCol);
    ellipse(mouseX, mouseY, d, d);
  }

  void run() {
    update();
    display();
  }
}

patrick457

Re: Re: How to move more than one Object from a random startposition to a random endposition

9 months ago

Hello GoToLoop and thank you very much for this cleaning. I dont understand everything, but I'll try.

Well you've done a good job, but I guess you dont really understand what I want to do. I have posted two codes. The first code is my real project. The second code is only a test. The second Code has nothing to do with the first.

In the first code, you see a lot of circles in a rectangle. They orbiting the mouse-circle, but only in this rectangle. When the mouse-circle leaves the rectangle, the other circles stop to orbit the mouse-circle and the other circles become freezed.

And thats the point, for what the second code is necessary. At least for me. The circles shouldn't freeze, but they also shouldn't leave the rectangle, like in your version.

What I want to do, is that the other circles doesn't will freeze. They should start to move themselves to another random point in the rectangle and then freeze at this point. Now, when the mouse-circle comes back to the rectangle, the other circles should orbit the mouse circle again. Well and the same way everytime, when the mouse goes outside and inside.

I hope, this explanation was understandable. I'm sorry, that I didn't have explained it correctly the first time. But I was thinking, that my explanation was clear. Now I see, that it wasn't so.

regards

Patrick

GoToLoop

Re: How to move more than one Object from a random startposition to a random endposition

9 months ago

Almost figuring out, but still not there.

This time, I did one more serious cleanup:
Cursor drawing was inside class Kreis, and was being redrawn kreisNum times!!!

New method checkCursorInBox() @ class Innen .
New method update2() @ class Kreis
New method checkCageLimit() @ class Kreis
New boolean variable isCursorInside
And some other minor tweaks.

Here's the revised v3.00:

/***
 * RunAway Bubbles (v3.0)
 * by Patrick457 (2013/Jan)
 *
 * http://forum.processing.org/topic/how-to-move-more-than-one-object-from-a-random-startposition-to-a-random-endposition
 * http://studio.processingtogether.com/sp/pad/export/ro.9XaKJjWlS$Lz2/latest
 */
final static byte  fps = 50;
final static byte  bubbleSize = 15;
final static byte  cursorSize = 15;
final static color cursorCol  = #64C8C8;
final static color bg = 0;
final static float thickness  = 2f;

final static short kreisNum = 50 * 3;
final static Kreis[] k = new Kreis[kreisNum];

boolean isCursorInside;
Innen q;

void setup() {
  size(1000, 500);
  frameRate(fps);
  smooth();
  noCursor();
  noFill();
  strokeWeight(thickness);
  ellipseMode(CORNER);
  rectMode(CORNER);

  q = new Innen();

  for (short i=0; i!=kreisNum; i+=3) {
    k[i]   = new Kreis(.01f, 7, bubbleSize);
    k[i+1] = new Kreis(.005f, 57, bubbleSize);
    k[i+2] = new Kreis(.00125f, 157, bubbleSize);
  }
}

void draw() {
  background(bg);

  q.drawCage();
  isCursorInside = q.checkCursorInBox();

  stroke(cursorCol);
  ellipse(mouseX, mouseY, cursorSize, cursorSize);

  for (Kreis kk: k)  kk.run();
}

class Innen {
  final int rx = width>>2, ry = height>>2;
  final int rw = width>>1, rh = height>>1;
  final int w  = rx+rw, h = ry+rh;

  final static color cageCol = #FF0000;

  void drawCage() {
    stroke(cageCol);
    rect(rx, ry, rw, rh);
  }

  boolean checkCursorInBox() {
    return mouseX>rx && mouseX<w && mouseY>ry && mouseY<h;
  }
}

class Kreis extends Innen {
  float ea, ex, ey;
  int z, sz;

  final static byte  repel = 2;
  final static color bubbleCol = #00FF00;

  Kreis (float easing, int repelSpd, int size) {
    ea = easing;
    z  = repelSpd;
    sz = size;

    ex = random(rx, w-sz);
    ey = random(ry, h-sz);
  }

  void update1() {
    if ( dist(ex, ey, mouseX, mouseY) > sz<<repel ) {
      ex += (mouseX - ex) * ea;      //Attracts
      ey += (mouseY - ey) * ea;
    }
    else {
      ex -= (mouseX - ex) * ea * z;  //Repels
      ey -= (mouseY - ey) * ea * z;
    }
  }

  void update2() {
    ex += ea * z;
    ey += ea * z;
  }

  void checkCageLimit() {
    if (ex > w-sz)     ex = w-sz;
    else if (ex < rx)  ex = rx;

    if (ey > h-sz)     ey = h-sz;
    else if (ey < ry)  ey = ry;
  }

  void display() {
    stroke(bubbleCol);
    ellipse(ex, ey, sz, sz);
  }

  void run() {
    if (isCursorInside)  update1();
    else                 update2();

    checkCageLimit();
    display();
  }
}

patrick457

Re: Re: How to move more than one Object from a random startposition to a random endposition

9 months ago

Hello GoToLoop,

I appreciate it a lot, that you help me. Thank you for the time you took for my code. The new code wasn't exactly what I had in mind, but now I've changed the update2() method a little bit. So, now I'm to 99 percent satisfied.

Their are other things, that I want to do with this code, but first I'll try to do it alone and if I doesn't find a solution. It's not a problem, because now I know how, to find help. And that is very good :)

Here my last Version:

/***
* RunAway Bubbles (v3.1)
* by Patrick457 (2013/Jan)
*
* http://forum.processing.org/topic/how-to-move-more-than-one-object-from-a-random-startposition-to-a-random-endposition
* http://studio.processingtogether.com/sp/pad/export/ro.9XaKJjWlS$Lz2/latest
*/
final static byte fps = 50;
final static byte bubbleSize = 15;
final static byte cursorSize = 15;
final static color cursorCol = #64C8C8;
final static color bg = 0;
final static float thickness = 2f;
final static short kreisNum = 50 * 3;
final static Kreis[] k = new Kreis[kreisNum];
boolean isCursorInside;
Innen q;
void setup() {
size(1000, 500);
frameRate(fps);
smooth();
noCursor();
noFill();
strokeWeight(thickness);
ellipseMode(CORNER);
rectMode(CORNER);
q = new Innen();
for (short i=0; i!=kreisNum; i+=3) {
k[i] = new Kreis(.01f, 7, bubbleSize);
k[i+1] = new Kreis(.005f, 57, bubbleSize);
k[i+2] = new Kreis(.00125f, 157, bubbleSize);
}
}
void draw() {
background(bg);
q.drawCage();
isCursorInside = q.checkCursorInBox();
stroke(cursorCol);
ellipse(mouseX, mouseY, cursorSize, cursorSize);
for (Kreis kk: k) kk.run();
}
class Innen {
final int rx = width>>2, ry = height>>2;
final int rw = width>>1, rh = height>>1;
final int w = rx+rw, h = ry+rh;
final static color cageCol = #FF0000;
void drawCage() {
stroke(cageCol);
rect(rx, ry, rw, rh);
}
boolean checkCursorInBox() {
return mouseX>rx && mouseX<w && mouseY>ry && mouseY<h;
}
}
class Kreis extends Innen {
float ea, ex, ey, angle, i;
int z, sz;
final static byte repel = 2;
final static color bubbleCol = #00FF00;
Kreis (float easing, int repelSpd, int size) {
ea = easing;
z = repelSpd;
sz = size;
ex = random(rx, w-sz);
ey = random(ry, h-sz);
}
void update1() {
if ( dist(ex, ey, mouseX, mouseY) > sz<<repel ) {
ex += (mouseX - ex) * ea; //Attracts
ey += (mouseY - ey) * ea;
}
else {
ex -= (mouseX - ex) * ea * z; //Repels
ey -= (mouseY - ey) * ea * z;
}
}
void update2() {
i+=0.3;
angle+=map(random(i), 0, 1, -80, 80);
ex += cos(radians(angle));
ey += sin(radians(angle));
}
void checkCageLimit() {
if (ex > w-sz) ex = w-sz;
else if (ex < rx) ex = rx;
if (ey > h-sz) ey = h-sz;
else if (ey < ry) ey = ry;
}
void display() {
stroke(bubbleCol);
ellipse(ex, ey, sz, sz);
}
void run() {
if (isCursorInside) update1();
else update2();
checkCageLimit();
display();
}
}

Top Reply