How to mirror the left half of the canvas?

Programming Questions

karenpunk

How to mirror the left half of the canvas?

in Programming Questions • 1 month ago

i want to mirror the left half to the right half, but i have problem using the scale() function

my code goes like this:

void setup(){
size(800,400);
background(250);
smooth();
}
void draw(){
fill(0);
rect(0,0,200,400);
fill(255);
rect(0,200,200,400);
scale(-1,1);
copy(800,0,400,400,0,0,400,400);
}

Replies(7)

tfguy44

Re: How to mirror the left half of the canvas?

1 month ago

PImage leftHalf;
void setup() {
size(800, 400);
smooth();
}
void draw() {
background(250);
fill(0);
rect(0, 0, 200, 400);
fill(255);
rect(0, 200, 200, 400);
//fill(255,0,0);
//ellipse(mouseX, mouseY,20,20);
leftHalf = get(0, 0, width/2, height);
translate(width, 0);
scale(-1, 1);
image(leftHalf, 0, 0);
}

Chrisir

Re: How to mirror the left half of the canvas?

1 month ago

here

as often I have no idea what's going on...

void setup() {
size(800, 400);
background(250);
smooth();
}
void draw() {
fill(0);
rect(0, 0, 200, 400);
fill(255);
rect(0, 200, 200, 400);
fill(255, 0, 255);
rect(220, 200, 20, 4);
//
PImage x1= get (0, 0, width/2, height);
scale (-1, 1);
image (x1, -width, 0);
noLoop();
}

Greetings, Chrisir

If you need an answer, please send me a personal message since this forum doesn't notify.

amnon.owed

Re: How to mirror the left half of the canvas?

1 month ago

Pixel-based solution...

Adapted Code

void setup(){
size(800,400);
}
void draw(){
background(250);
fill(0);
rect(0,0,200,400);
fill(255);
rect(0,200,200,400);
fill(255,0,0);
ellipse(mouseX, mouseY,20,20);
flipHalf();
}
void flipHalf() {
loadPixels();
for (int x=width/2; x<width; x++) {
for (int y=0; y<height; y++) {
pixels[x+y*width] = pixels[(width-x)+y*width];
}
}
updatePixels();
}

amnon.owed

Re: How to mirror the left half of the canvas?

1 month ago

texture()-based solution (requires OpenGL renderer)...

Adapted Code

void setup(){
size(800,400, P2D);
}
void draw(){
background(250);
fill(0);
rect(0,0,200,400);
fill(255);
rect(0,200,200,400);
fill(255,0,0);
ellipse(mouseX, mouseY,20,20);
flipHalf();
}
void flipHalf() {
beginShape();
texture(get());
vertex(width/2, 0, width/2, 0);
vertex(width, 0, 0, 0);
vertex(width, height, 0, height);
vertex(width/2, height, width/2, height);
endShape();
}

tfguy44

Re: Re: How to mirror the left half of the canvas?

1 month ago

Neat. Didn't even think of doing it like that.

amnon.owed

Re: How to mirror the left half of the canvas?

1 month ago

Shader-based solution...

Code Example

PShader flipHalf;
void setup(){
size(800,400, P2D);
flipHalf = loadShader("flipHalf.glsl");
}
void draw(){
background(250);
fill(0);
rect(0,0,200,400);
fill(255);
rect(0,200,200,400);
fill(255,0,0);
ellipse(mouseX, mouseY,20,20);
filter(flipHalf);
}

GLSL Shader (filename called "flipHalf.glsl" in the main sketch)

#define PROCESSING_TEXTURE_SHADER
uniform sampler2D texture;
varying vec4 vertTexCoord;
void main(void) {
vec2 p = vertTexCoord.x < 0.5 ? vertTexCoord.xy : vec2(1.0-vertTexCoord.x, vertTexCoord.y);
gl_FragColor = texture2D(texture, p);
}

RyanJP

Re: How to mirror the left half of the canvas?

1 month ago

Amazing, the shader method is SO FAST. Love it. Gotta learn me some GLSL asap

Top Reply