How to make a function return more than one variable?

Programming Questions

ernifusio

How to make a function return more than one variable?

Answered

Need more info
Answered
Working on it

in Programming Questions • 2 years ago

Hi. I'm new to processing so sorry if this is a silly question, but i havent managed to find the answer...

I need to write a function that returns more than one variable. How is that done in processing?

for example, i have

Copy code

int dosomething(inputtype inputname){
int outputname;
// some calculation is done here and the output is outputname
return(outputname);
}

Now, lets say i want the function to return two values, lets say an integer and a string. Is this possible?

Replies(9)

blindfish

Re: How to make a function return more than one variable?

2 years ago

Not directly... but it is possible to return an object that contains several values. An obvious example is to use an array. This could only be of a single type, but it's not too difficult to convert a number stored in a String array to an int. Alternatively you could write a class that has int and string fields...

blindfish

Re: Re: How to make a function return more than one variable?

2 years ago

Here's an example of such a class:

Copy code

void setup() {
size(200,200);
MyContainer foo = getStringAndInt();
println(foo.number + " " + foo.word);
}
// here's a function that returns a class object
MyContainer getStringAndInt() {
return new MyContainer(3, "little pigs");
}
// the Class that contains the two variable types
class MyContainer {
int number;
String word;
MyContainer(int number, String word) {
this.number = number;
this.word = word;
}
// in strict OOP you'd probably add getter methods here,
// but in Processing this isn't strictly necessary
}

Writing a class like this simply to store values can often be a simpler solution than relying on arrays: it avoids the need to convert variables to the appropriate type and you can reference them directly with their field name, which makes code easier to read than looking at an array[index] reference...

ernifusio

Re: How to make a function return more than one variable?

2 years ago

Thank you for answering so quickly and concisely. Thats just what I needed...

wired632

Re: How to make a function return more than one variable?

1 year ago

What if you want it to return two float variables?

v.k.

Re: How to make a function return more than one variable?

1 year ago

Well, here goes a silly useless example:

void setup(){

//and to use

println(doubleFloats(10,20)[0] +" "+ doubleFloats(10,20)[1]);

}

float[] doubleFloats(float a, float b)

{

float[] results= new float[2];

results[0] = a*2;

results[1] = b*2;

return results;

}

thomashol..

Re: How to make a function return more than one variable?

1 year ago

I would use an ArrayList as follows:

Copy code

ArrayList testing() {
ArrayList returnedObject = new ArrayList();
returnedObject.add( (String) "a" );
returnedObject.add( (Integer) 666 );
returnedObject.add( (PVector) new PVector(2, 2) );
return returnedObject;
}
void setup() {
ArrayList justChecking = testing();
println(justChecking.get(0));
println(justChecking.get(1));
println(justChecking.get(2));
// just to be safe, you can also enforce the type by casting the values
println((String) justChecking.get(0));
println((Integer) justChecking.get(1));
println((PVector) justChecking.get(2));
}

PhiLho

Re: How to make a function return more than one variable?

1 year ago

Or how to make Java an untyped (thus unsafe, prone to error) language...

Perhaps convenient as you don't have to create a class, but not very practical will all these casts.

thomashol..

Re: How to make a function return more than one variable?

1 year ago

True. Call it a python infirmity...

webwarrio..

Re: How to make a function return more than one variable?

11 months ago

Returning multiple values is usually done by packing them into tuple. Java supports generics, so there must be some generic tuple libraries - try to google them. That will probably not be very elegant (because of Java syntax), but still better than writing class each time or using untyped ArrayList.

Top Reply