How to insert a new line?

Contributed Library Questions

l00psler

in Contributed Library Questions • 1 year ago

Hi there,

I've tried to insert a new line with + "\n" , but it doesn't work.

/*
//////////////////////////////////////////////
--------- GEOMERATIVE TUTORIALS --------------
//////////////////////////////////////////////
Title : Geo_Font_02_b
Date : 01/03/2011
Version : v0.5
We access a number of points on a font's outline.
In this variation we draw vertex instead of ellipses.
Licensed under GNU General Public License (GPL) version 3.
http://www.gnu.org/licenses/gpl.html
A series of tutorials for using the Geomerative Library
developed by Ricard Marxer.
http://www.ricardmarxer.com/geomerative/
More info on these tutorial and workshops at :
www.freeartbureau.org/blog
*/
//////////////////////////////////////////////
import geomerative.*;
RFont font;
String myText = "This is line 1 " + "\n" "This is line 2 ";
//----------------SETUP---------------------------------
void setup() {
size(800, 300);
background(255);
smooth();
RG.init(this);
font = new RFont("FreeSans.ttf", 100, CENTER);
stroke(255, 0, 0);
noFill();
translate(width/2, height/1.7);
RCommand.setSegmentLength(20);//TRY DIFFERENT VALUES HERE
RCommand.setSegmentator(RCommand.UNIFORMLENGTH);
RGroup myGroup = font.toGroup(myText);
RPoint[] myPoints = myGroup.getPoints();
//HERE WE DRAW LINES USING VERTEX.
beginShape();
//TRY ADDING DIFFERENT MODES HERE LIKE LINES OR TRIANGLES.
//beginShape(QUAD_STRIP);//THIS CHANGES DRAMATICALLY THE FORM.
for (int i=0; i<myPoints.length; i++) {
vertex(myPoints[i].x, myPoints[i].y);
//TRY CURVEVERTEX TOO BUT CHOOSE POLYGON MODE IN BEGINSHAPE()
// curveVertex(myPoints[i].x, myPoints[i].y);
}
endShape();
}
//----------------DRAW---------------------------------
void draw() {
}
//////////////////////////////////////////////

Replies(6)

tfguy44

Re: How to insert a new line?

1 year ago

Works fine for me:

String myString = "Did she take the high road?\nOr did she take the low road?";
void setup(){
size(200,200);
}
void draw(){
background(0);
text(myString,5,17);
}

Maybe it's because, as seen in your code, you're not appending the string properly with two plus signs?

String myText = "This is line 1 " + "\n" + "This is line 2 ";

There's no need to append strings together if you know exactly what the string is, of course...

velvetkev..

Re: How to insert a new line?

1 year ago

As far as I recall Geomerative doesn't support multiple lines of text- the only way to get around it is to use multiple groups, AFAIK.

l00psler

Re: Re: How to insert a new line?

1 year ago

Thank you!

Maybe you know where I can found more information about multiple groups?

velvetkev..

Here is how I approached it. I created a simple class, GeomText, which has a string, position and a Geomerative group. Instead of having a single Geomerative group you can have an array of GeomItems and position and display each one individually.

import geomerative.*;
String fontName= "ariblk.ttf";
String[] lines= {
"Here are", "some words", "on", "different", "lines"
};
GeomText[] items;
void setup() {
size(1200, 850);
background(255);
//smooth();
RG.init(this);
RG.setPolygonizer(RG.ADAPTATIVE);
items= new GeomText[lines.length];
for (int i=0; i<lines.length; i++) {
float offset=i*100;
items[i]= new GeomText(lines[i], 100, 0, -300+offset);
}
}
void draw() {
background(255);
for (int i=0; i<items.length; i++) {
items[i].display();
}
}
/*
Simple wrapper for an individual Geromerative group.
*/
class GeomText{
String msg;
RShape grp;
RPoint[] points;
int fontSize;
float posx;
float posy;
GeomText(String MSG, int FONTSIZE, float POSX, float POSY){
msg=MSG;
fontSize= FONTSIZE;
posx= POSX;
posy= POSY;
create();
}
void create(){
grp= RG.getText(msg, fontName, fontSize, CENTER);
points= grp.getPoints();
}
void display(){
pushMatrix();
translate(width/2, height/2);
translate(posx, posy);
stroke(130, 180);
grp.draw();
popMatrix();
}
}//end of class

There might be simpler ways of doing it but this was the most usable for me. Hope that helps.

l00psler

Re: Re: How to insert a new line?

1 year ago

Great, thank you! I get an error on line 62: NullPointerExeption. I use version 2.0a6.

at processing.core.PGraphicsJava2D.requestDraw(PGraphicsJava2D.java:187)
at processing.core.PApplet.run(PApplet.java:1855)
at java.lang.Thread.run(Thread.java:680)

velvetkev..

Re: How to insert a new line?

1 year ago

Runs for me in 2.0a6. Do you have the listed font installed on your system (Arial Black)? Maybe try changing fontName on line 4 to one of the fonts on your system?

Top Reply