How to increment through a nested for loop

Programming Questions

command_z

How to increment through a nested for loop

in Programming Questions • 9 months ago

I'm having trouble figuring out how to change each element through the for loop.

I want to display a grid of growing slices of "pie." So each piece of pie grows slightly in the grid. I'm not trying to create an animation, but just a static image. Does that make sense?

Here is the code I have so far:

float inc=1;
void setup(){
size(600,600);
smooth();
noStroke();
}
void draw(){
background(0);
fill(100);
for (int x=20; x<width-20; x+=50){
for (int y=20; y<height-20; y+=50){
inc+=.01;
arc(x,y,30,30,radians(inc),radians(360));
println(inc);
}
}
}

Replies(8)

command_z

Re: How to increment through a nested for loop

9 months ago

Here is a better example of what I want to do.

I want the upper left circle to be at "1%" and the bottom right circle to be at "100%"

Happy Holidays all.

void setup(){
size(600,600);
smooth();
noStroke();
}
void draw(){
background(0);
fill(100);
for (int x=20; x<width-20; x+=50){
for (int y=20; y<height-20; y+=50){
arc(x,y,30,30,radians(10),radians(x));
}
}
}

GoToLoop

Re: Re: How to increment through a nested for loop

9 months ago

How about this one?

float inc;

void setup() {
    size(600, 600);
    smooth();
    noStroke();
    fill(100);
}

void draw() {

    background(0);

    for (int x=20; x<width-20; x+=50)
        for (int y=20; y<height-20; y+=50) {
            arc( x, y, 30, 30, radians(inc), radians(x) );
            inc = ( inc+.01f ) % width;
            println(inc);
        }
}

GoToLoop

Re: How to increment through a nested for loop

9 months ago

I don't quite get what you want.

But perhaps you just want a way to put a limit to variable inc:

inc = ( inc+.01f ) % 360;

Here's your code modified:

float inc;

void setup() {
    size(600, 600);
    smooth();
    noStroke();
    fill(100);
}

void draw() {

    background(0);

    for (int x=20; x<width-20; x+=50)
        for (int y=20; y<height-20; y+=50) {
            arc( x, y, 30, 30, radians(inc), radians(360) );
            inc = ( inc+.01f ) % 360;
            println(inc);
        }
}

command_z

Re: How to increment through a nested for loop

9 months ago

Thanks for your help. Sorry, I'm having a hard time describing what I want to code. Lets say that each number below is a circle. The number represents the percentage of circle drawn.

Thank for your help.

01 02 03 04 05 06 07 08 09 10

11 12 13 14 15 16 17 18 19 20

21 22 23 24 25 26 27 28 29 30

...

91 92 93 94 95 96 97 98 99 100

Chrisir

Re: How to increment through a nested for loop

9 months ago

here....
I had to swap the lines 9 and 10 to make it go right first and not down...

void setup() {
size(600, 600);
smooth();
noStroke();
}
void draw() {
background(0);
float howFarCircle=10;
for (int y=20; y<height-20; y+=50) {
for (int x=20; x<width-20; x+=50) {
stroke(255);
fill(100);
arc(x-12, y-12, 30, 30, radians(0), radians(howFarCircle));
howFarCircle+=2.45;
}
}
println(howFarCircle);
}

Chrisir

Re: How to increment through a nested for loop

9 months ago

or using map...

http://www.processing.org/reference/map_.html

void setup() {
size(600, 600);
smooth();
noStroke();
}
void draw() {
background(0);
float howFarCircle=0;
int counter=0;
for (int y=20; y<height-20; y+=50) {
for (int x=20; x<width-20; x+=50) {
stroke(255);
fill(100);
howFarCircle=map(counter, 0, 144, 0, 363);
arc(x-1, y-1, 30, 30, radians(0), radians(howFarCircle));
counter++;
}
}
println(howFarCircle);
println(counter);
}

amnon.owed

Re: How to increment through a nested for loop

9 months ago

Note that realising what you want doesn't require a nested for loop per se.

Adapted Code

int numPies = 100;
void setup() {
size(600, 600);
noStroke();
smooth();
fill(0);
}
void draw() {
background(255);
frame.setTitle("We got " + numPies + " pies");
int nw = int(sqrt(numPies));
int nh = numPies/nw;
if (numPies%nw>0) { nh++; }
float w = width/nw;
float h = height/nh;
float r = w/2;
for (int i=0; i<numPies; i++) {
float x = (i%nw+0.5)*w;
float y = (i/nw+0.5)*h;
float theta = i/(numPies-1.0)*TWO_PI;
arc(x, y, r, r, 0, theta);
}
}
void keyPressed() {
if (key == 'z') { numPies--; }
if (key == 'x') { numPies++; }
}

command_z

Re: How to increment through a nested for loop

9 months ago

Thanks everyone. I think switching the nested loop so it goes horizontally first did the trick. Thanks Chrisir.

I didn't know you could change the window title name! Thanks Amnon!

frame.setTitle("We got " + numPies + " pies")

Top Reply