hello,

this code let's you click on a 3D box no matter how deep in space it is
it makes use of screenX and screenY (see reference)
Usage: you can click the center of the box and it prints yes instead of no; this work no matter what Z value you give the box. Just make sure you operate the translate() for the box with the same values as for screenX and screenY. You might want to increase the value 30 in the dist() statement.

1. void setup() {
2.   size(700, 700, P3D);
3. }
4. void draw() {
5.   background(204);
6.   // 
7.   float theX = screenX(100, 100, -990);
8.   float theY = screenY(100, 100, -990);
9.   pushMatrix();
10.   translate(100, 100, -990);
11.   box(210);
12.   popMatrix();
13.   if (dist(mouseX, mouseY, theX, theY)<30)
14.     println ("yes");
15.   else
16.     println ("no ");
17.   //
18. }

I don't know if those are still working with version processing 2.0:
another way of doing this is the 3D picking technique
http://www.openprocessing.org/sketch/7881
http://wiki.processing.org/w/Picking_with_a_color_buffer


here is a 3D picking approach that works medium well:

1. /**
2.  picking code taken from
   
3.  http://processinghacks.com/hacks:picking
4.  @author nicolas clavaud
5.  */
6. //import processing.opengl.*;
7. class Cube {
8.   // variables
9.   int id;          // id
10.   int x, y, z, w;  // position (x, y, z) and width (w)
11.   color c;         // color (in scene, not buffer)
12.   // constructor
13.   public Cube(int id, int x, int y, int z, int w) {
14.     this.id = id;
15.     this.x = x;
16.     this.y = y;
17.     this.z = z;
18.     this.w = w;
19.     c = color(random(255), 250, 50);
20.   }
21.   // make the color change
22.   public void changeColor() {
23.     int r = (int)red(c);
24.     int g = (int)green(c);
25.     int b = (int)blue(c);
26.     c = color(r, 255 - g, b);
27.   }
28.   // display the cube on screen
29.   public void display(PGraphics ecran) {
30.     ecran.fill(c);
31.     drawCube(ecran);
32.   }
33.   // draw the cube in the buffer
34.   public void drawBuffer(PGraphics buffer) {
35.     color idColor = getColor(id);
36.     buffer.fill(idColor);
37.     drawCube(buffer);
38.   }
39.   private void drawCube(PGraphics g) {
40.     g.pushMatrix();
41.     g.translate(x, y, z);
42.     g.box(w);
43.     g.popMatrix();
44.   }
45. }
46. PGraphics buffer;   // buffer
47. Cube[] cubes;       // cubes
48. float a = 0;        // angle to make the scene rotate
49. void setup() {
50.   // we use OPENGL for display
51.   size(200, 200, OPENGL);
52.   // buffer is created using applet dimensions
53.   buffer = createGraphics(width, height, P3D);
54.   // put cubes randomly in the scene
55.   cubes = new Cube[10];
56.   for (int i = 0; i < cubes.length; i++) {
57.     cubes[i] = new Cube(
58.     i, // identifiant
59.     -15 + (int)random(30), // position x
60.     -15 + (int)random(30), // position y
61.     -15 + (int)random(30), // position z
62.     5 + (int)random(15)     // taille
63.     );
64.   }
65. }
66. void draw() {
67.   background(255);
68.   camera(-20, -20, 70,
69.   0, 0, 0,
70.   0, 1, 0);
71.   rotateY(a);
72.   lights();
73.   for (int i = 0; i < cubes.length; i++) {
74.     cubes[i].display(this.g);
75.   }
76.   a += 0.002;
77.   if (a > TWO_PI) a -= TWO_PI;
78. }
79. void mouseClicked() {
80.   // draw the scene in the buffer
81.   buffer.beginDraw();
82.   buffer.background(getColor(-1)); // since background is not an object, its id is -1
83.   buffer.noStroke();
84.   buffer.camera(-20, -20, 50, 0, 0, 0, 0, 1, 0);
85.   buffer.rotateY(a);
86.   for (int i = 0; i < cubes.length; i++) {
87.     cubes[i].drawBuffer(buffer);
88.   }
89.   buffer.endDraw();
90.   // get the pixel color under the mouse
91.   color pick = buffer.get(mouseX, mouseY);
92.   // get object id
93.   int id = getId(pick);
94.   // if id > 0 (background id = -1)
95.   if (id >= 0) {
96.     // change the cube color
97.     cubes[id].changeColor();
98.   }
99. }
100. // id 0 gives color -2, etc.
101. color getColor(int id) {
102.   return -(id + 2);
103. }
104. // color -2 gives 0, etc.
105. int getId(color c) {
106.   return -(c + 2);
107. }

Greetings, Chrisir     

If you need an answer, please send me a personal message since this forum doesn't notify.

You really need to stop double posting the same question multiple times.

Read: https://forum.processing.org/topic/where-to-place-threads-and-other-forum-practices

Especially Annex D.