/** * SPEEDWAY! (v2.54) * by GoToLoop (2013/May); * * http://forum.processing.org/topic/ * how-to-get-objects-to-move-in-an-opposite-direction * * http://www.dailymotion.com/video/ * xq41dq_classic-game-room-speedway-for-magnavox-odyssey-2_videogames * * http://studio.processingtogether.com/sp/pad/export/ro.96iIYk57mRuYP/latest */

final static color ROAD = 040, LANE = #FFFF40, BG = 0200;

final static short NUM_LANES = 10, LANE_SPD = 8;
final static short LANE_WIDE = 10, MARGIN = 80;
final static float LANE_SCALE = .4;

final static byte NUM_CARS = 4;
final Car[] foeCars = new Car[NUM_CARS];

Player myCar;

int laneGap, laneHigh;
int ww, hh;

void setup() {
  size(600, 800);
  frameRate(50);
  noCursor();
  rectMode(CENTER);
  background(BG);
  strokeWeight(LANE_WIDE);

  laneGap = height/NUM_LANES;
  laneHigh = round(laneGap * LANE_SCALE);

  ww = width >> 1;
  hh = height >> 1;

  myCar = new Player(#0000FF);

  foeCars[0] = new Car(5, 3, #FFA500);
  foeCars[1] = new Car(1, 5, #00FF00);
  foeCars[2] = new Car(3, 2, #FF0000);
  foeCars[3] = new Car(5, 4, #FF00FF);
}

void draw() {
  final int scroll = frameCount % laneGap * LANE_SPD;

  fill(ROAD);
  rect(ww, hh, width - MARGIN*2, height);

  stroke(LANE);
  for (int i = -LANE_SPD; i != NUM_LANES; ++i) {
    final int high = laneGap*i + scroll;
    line(ww, high, ww, high + laneHigh);
  }

  noStroke();
  for (Car c: foeCars)  c.script();
  myCar.script();
}

void mousePressed() {
  looping = !looping;
}

void keyPressed() {
  mousePressed();
}

class Car { 
  static final short W = 32, H = 48;
  static final short W2 = W>>1, W3 = W/3;
  static final short H2 = H>>1, H3 = H/3, H5 = H/5;

  byte r;       // spX
  final byte S; // spY

  final color C;

  int x = (int) random(MARGIN + W, width - MARGIN - W);
  short y = H;

  Car(int rr, int ss, color cc) {
    r = (byte)  rr;
    S = (byte)  ss;
    C = cc;
  }

  void script() {
    drive();
    bounce();
    display();
  }

  void drive() {
    if ( (y += S) > height + H )  y = -H2;
  }

  void bounce() {
    if ( (x += r) > width - MARGIN - W | x < MARGIN + W )
      r *= -1;
  }

  void display() {
    fill(C);
    rect(x, y, W - W3, H);          // main body
    rect(x, y - H5, W, H3);         // front tyres
    rect(x, y + H5*2, W + W3, H3);  // back tyres
    rect(x, y + H2, W, H3);         // wing

    fill(ROAD);
    rect(x, y + W3, W3, H3);        // cockpit
  }
}

final class Player extends Car {
  Player(color cc) {
    super(0, 0, cc);
    y = (short) (height - H);
  }

  void drive() {
    x = mouseX;
  }

  void bounce() {
    if (x > width - MARGIN - W)  x = width - MARGIN - W;
    else if (x < MARGIN + W)     x = MARGIN + W;
  }
}