How to: Ease IN not out?

Programming Questions

7immer

in Programming Questions • 2 years ago

Hi all,

I have a small question to ask. I've made this little code, all it does is follow the mouse around and ease out as it gets to a stop. My problem is I would like it to do the oposite and EASE IN instead of ease out. Unfortunately I just cant get my head around the maths. Could anyone help me here?

float rectposX=0;

float rectposY=0;

void setup(){

size(500,500);

smooth();

}

void draw(){

rectposX = rectposX +(mouseX - rectposX)/10;

rectposY = rectposY +(mouseY - rectposY)/10;

background(50);

fill(255,255,0);

rect(rectposX,rectposY,20,20);

}

Many thanks in advance :)

Replies(2)

davbol

Re: How to: Ease IN not out?

2 years ago

here's one way you might solve this...

your current code is equivalent to:

float t = 0.1;
rectposX = lerp(rectposX, mouseX, t);
rectposY = lerp(rectposY, mouseY, t);

which is straight linear interpolation - you always move 1/10th the distance, so the further away you are the further you move towards goal, as you get closer you move smaller, thus the "ease out" effect.

so what you want to do, essentially, is invert t, so that the further away you are the smaller t becomes, so the smaller your movement steps, and as you get closer t increases. note that since distance is also decreasing, t need to "decrease faster" (that is, "more geometrically") than distance to counter that. for instance, you might use the square-of-distance:

float dx = mouseX - rectposX;
float dy = mouseY - rectposY;
float dlsq = dx*dx+dy*dy; // note no sqrt() - need a nonlinear measure
float overall_speed = 1000; // adjust this for "feel"
float t = 1.0 / dlsq * overall_speed; // t is smaller when dlsq is bigger
if (t > 1.0) t = 1.0; // gotta clamp when very close else it'll explode
rectposX = lerp(rectposX, mouseX, t);
rectposY = lerp(rectposY, mouseY, t);

(btw, alternatively, you could could model it as velocity/acceleration/drag, but you'd likely get a bit of "rubber band" overshoot that you may not want, and would have to clamp hard to get rid of)

7immer

Re: How to: Ease IN not out?

2 years ago

many thanks, this is great!

Top Reply