how to draw a certain geometric shape - a rectangle with a circular hole

Programming Questions

fromage

how to draw a certain geometric shape - a rectangle with a circular hole

in Programming Questions • 3 years ago

hey there,
i was wondering if there is an easy and clean way to draw a filled rectangle that has a circular hole in the middle?
for my case it is important that nothing gets drawn to this hole at all. so i cannot work around it with first drawing a rect and than an ellipse which overdraws that and creates a hole, i need the exact geometric shape
thank you

Replies(6)

PhiLho

Re: how to draw a certain geometric shape - a rectangle with a circular hole

3 years ago

Trying to do Emmental fromage (cheese!)?

I would look at mask() to do such partially transparent shapes.

local_guru

Re: how to draw a certain geometric shape - a rectangle with a circular hole

3 years ago

One way to draw arbitray transparent shapes is drawing them in a Graphics object and using blend to add them to the

screen

void setup() {
size(300,300);
}
void draw() {
background(255);
line(0,0,300,300);
line(0,300,300,0);
PGraphics g = createGraphics(300,300,P2D);
g.beginDraw();
g.background(255);
g.fill(0);
g.rect(100,100,100,100);
g.fill(255);
g.ellipse(150,150,80,80);
g.endDraw();
blend(g,0,0,300,300,0,0,300,300,DARKEST);
}

cedrickie..

Re: Re: how to draw a certain geometric shape - a rectangle with a circular hole

3 years ago

Take a look at the breakShape example by Dave Bollinger.

size(500,500,JAVA2D);
background(#CC9966);
fill(255);
stroke(0);
// "o" is compound because it has a hole
beginShape();
// outer portion
vertex(100,200);
vertex(250,200);
vertex(250,400);
vertex(100,400);
vertex(100,200); // must close manually (if you want the stroke)
// the hole
breakShape();
vertex(150,250);
vertex(150,350);
vertex(200,350);
vertex(200,250);
endShape(CLOSE); // ok to let p5 close it
// "i" is compound because it is disjoint
beginShape();
// base portion
vertex(300,200);
vertex(400,200);
vertex(400,400);
vertex(300,400);
vertex(300,200); // must close manually (if you want the stroke)
// the dot
breakShape();
vertex(300,100);
vertex(400,100);
vertex(400,150);
vertex(300,150);
endShape(CLOSE); // ok to let p5 close it
// now try making a capital greek theta
// (hint: it'll require 2 breakShapes()'s)

jonobr1

Re: Re: how to draw a certain geometric shape - a rectangle with a circular hole

2 years ago

is breakShape() native to Java? how does this work?

—
http://jonobr1.com/

fromage

Re: how to draw a certain geometric shape - a rectangle with a circular hole

3 years ago

thank you! i tried the different approaches and found that the mask thing was best fitting for my purposes, since the geometrical figure is so easy. so now i finally can make my emmental pictures ;)

p.s.: i had some trouble getting the blend method working, maybe because i use GLConstants.GLGRAPHICS as renderer?

PhiLho

Re: how to draw a certain geometric shape - a rectangle with a circular hole

2 years ago

See breakShape()

Top Reply