How to create a delay between sounds?

General Discussion Other

jay_sama

How to create a delay between sounds?

in General Discussion • Other • 1 year ago

Hi,

I have recently started coding with Processing and the Minim library and now I'm stuck :(. I am currently trying to make a program that plays sounds consecutively with a certain amount of delay between each sound (Playing of the sounds are triggered by mousePressed()). I have tried Timers and the Thread.sleep(<num>) and both does not give me the result i'm looking for (as it lags the program). If anyone knows of another way to put a delay between sounds, please let me know :)

Thank you for reading

Replies(1)

tfguy44

Re: How to create a delay between sounds?

1 year ago

"How do I make something happen after a certain amount of time?" comes up a lot around here.

The trick is to remember when you want that thing to happen (in a seperate variable) - based on the time of milliseconds since the program started (as returned by a call to millis()) - and then check if that time is now. Here's a modified snippet based on the Minim Example loadSample. You'll want to get the BD.mp3 file from it (or use your's!) to make this work.

import ddf.minim.*;
Minim minim;
AudioSample kick;
int kickAt=-1;
void setup()
{
size(512, 200, P2D);
minim = new Minim(this);
kick = minim.loadSample("BD.mp3", 2048);
}
void draw()
{
background(0);
stroke(255);
for (int i = 0; i < kick.bufferSize() - 1; i++)
{
line(i, 100 - kick.left.get(i)*50, i+1, 100 - kick.left.get(i+1)*50);
}
// Kick it again at the specified time.
if( kickAt > 0 && kickAt < millis() ){
kick.trigger();
kickAt = -1;
}
}
void mouseClicked()
{
kick.trigger();
kickAt = millis() + 2000; // And again in 2 seconds.
}
void stop()
{
kick.close();
minim.stop();
super.stop();
}

If you want to kick of more complex sounds after various amounts of time, you can always push the times that things should happen into an ArrayList, and then check if any of those things in the ArrayList should occur.