Loading...
Logo
Processing Forum
Programming Questions
p3tr4s
p3tr4s

How to connect last ball of the array with the first ball?

in Programming Questions  •  1 month ago  
Hi,

I have a small question with arrays. 
I have 10 ellipses drawn in a circle. Each ellipse is connected by a string.

How to write the last string in order to connect the last ellipse with the first one?

Thank you in advance:)

The code:

Copy code
  2. ball[] balls;
  3. stick[] sticks;


  6. int stickLen = 80;
  7. int nBalls = 10;
  8. int nSticks = nBalls-1;

  10. void setup() {

  12.   size(1280, 720);
  13.   smooth();
  14.   frameRate(1);

  16.   balls = new ball[nBalls];
  17.   sticks = new stick[nSticks];

  19.   for (int i = 0; i < nBalls; i++) {

  21.     balls[i] = new ball(new PVector(sin(radians(i*36))*100+width/2, cos(radians(i*36))*100+height/2), 10);

  23.     if (i > 0) {
  24.       sticks[i-1] = new stick(balls[i-1], balls[i]);
  25.     }
  26.     
  27.     
  28.   }
  29. }

  31. void draw() {

  33.   background(255);

  35.   for (int i = 0; i < nSticks; i++) {


  38.     sticks[i].update();
  39.     sticks[i].display();
  40.   }
  41. }
  44. class ball {

  46.   color ballColor;
  47.   float radius;

  49.   PVector location;
  50.   PVector oldLocation;
  51.   PVector nudge;

  53.   ball(PVector loc, float r) {
  54.     location = loc;
  55.     radius = r;
  56.     ballColor = color(0);

  58.     oldLocation = location.get();
  59.     nudge = new PVector(random(1, 3), random(1, 3));
  60.     location.add(nudge);
  61.   }//ball()

  63.   void display() {

  65.     stroke(1);
  66.     noFill();
  67.     ellipse(location.x, location.y, 2*radius, 2*radius);
  68.   }

  70.   void move() {

  72.     PVector temp = location.get();
  73.     location.x += (location.x-oldLocation.x);
  74.     location.y += (location.y-oldLocation.y);
  75.     oldLocation.set(temp);

  77.     stroke(10);
  78.     line(location.x, location.y, oldLocation.x, oldLocation.y);

  80.     bounce();
  81.   }//move


  84.     void bounce() {

  86.     if (location.x > (width-radius)) {
  87.       location.x = width-radius;
  88.       oldLocation.x = location.x;
  89.       location.x -= nudge.x;
  90.     }

  92.     if (location.x < radius) {
  93.       location.x = radius;
  94.       oldLocation.x = location.x;
  95.       location.x += nudge.x;
  96.     }

  98.     if (location.y > (height-radius)) {
  99.       location.y = height-radius;
  100.       oldLocation.y = location.y;
  101.       location.y -= nudge.y;
  102.     }

  104.     if (location.y < radius) {
  105.       location.y = radius;
  106.       oldLocation.y = location.y;
  107.       location.y += nudge.y;
  108.     }
  109.   }
  110. }//end of class ball
  113. class stick {

  115.   ball b1, b2;
  116.   float r;

  118.   stick(ball b1, ball b2) {

  120.     this.b1 = b1;
  121.     this.b2 = b2;

  123.     //compute the length of the stick
  124.     //same as the intial distance between two balls

  126.     r = b1.location.dist(b2.location);
  127.   }

  129.   void display() {

  131.     b1.display();
  132.     b2.display();

  134.     stroke(255, 0, 0);
  135.     strokeWeight(5);
  136.     line(b1.location.x, b1.location.y, b2.location.x, b2.location.y);
  137.   }

  139.   void update() {
  140.     b1.move();  
  141.     b2.move();
  142.     constrainLength();
  143.   }

  145.   void constrainLength() {

  147.     float k = 0.1;
  148.     //delta = atstumas
  149.     //r = distance
  150.     PVector delta = PVector.sub(b2.location, b1.location);

  152.     float deltaLength = delta.mag();
  153.     float d = ( (deltaLength - r) / deltaLength);

  155.     b1.location.x += delta.x * k * d/2;
  156.     b1.location.y += delta.y * k * d/2;
  157.     b2.location.x -= delta.x * k * d/2;
  158.     b2.location.y -= delta.y * k * d/2;
  159.   }//constrainLength()
  160. }//end of stick

Replies(2)

GoToLoop
GoToLoop

Re: How to connect last ball of the array with the first ball?

1 month ago
I've made it! 
Copy code
    /** 
 * Ball-Chained (v2.21)
 * by p3tr4s (2013/Aug)
 * mod GoToLoop
 * 
 * http://forum.processing.org/topic/
 * how-to-connect-last-ball-of-the-array-with-the-first-ball
 */

final static int BALLS_NUM = 10;

final Ball[]  balls  = new Ball[BALLS_NUM];
final Stick[] sticks = new Stick[BALLS_NUM];

final PVector tmp = new PVector();

void setup() {
  size(1280, 720);
  smooth();
  frameRate(10);

  strokeWeight(5);
  noFill();

  for (int i = 0; i != BALLS_NUM; i++) {
    balls[i] = new Ball(new PVector
      (sin(radians(i*36))*100+width/2, cos(radians(i*36))*100+height/2), 10);

    if (i > 0)  sticks[i-1] = new Stick(balls[i-1], balls[i]);
  }

  sticks[BALLS_NUM - 1] = new Stick(balls[BALLS_NUM - 1], balls[0]);
}

void draw() {
  background(-1);
  for (Stick st: sticks)  st.action();
}

class Ball {
  final static color BALL_COLOR = 1, CHAIN_COLOR = 10;

  final float radius, diameter;

  final PVector location = new PVector();
  final PVector oldLocation = new PVector();
  final PVector nudge = new PVector(random(1, 3), random(1, 3));

  Ball(PVector loc, float r) {
    oldLocation.set(loc);
    location.set(loc);
    location.add(nudge);
    diameter = (radius = r) * 2;
  }

  void display() {
    stroke(BALL_COLOR);
    ellipse(location.x, location.y, diameter, diameter);
  }

  void move() {
    PVector.sub(location, oldLocation, tmp);
    oldLocation.set(location);
    location.add(tmp);

    stroke(CHAIN_COLOR);
    line(location.x, location.y, oldLocation.x, oldLocation.y);

    bounce();
  }

  void bounce() {
    if (location.x > (width - radius)) {
      oldLocation.x = location.x = width - radius;
      location.x -= nudge.x;
    }

    else if (location.x < radius) {
      oldLocation.x = location.x = radius;
      location.x += nudge.x;
    }

    if (location.y > (height - radius)) {
      oldLocation.y = location.y = height - radius;
      location.y -= nudge.y;
    }

    else if (location.y < radius) {
      oldLocation.y = location.y = radius;
      location.y += nudge.y;
    }
  }
}

class Stick {

  Ball b1, b2;
  float r;

  Stick(Ball b1, Ball b2) {
    this.b1 = b1;
    this.b2 = b2;

    r = b1.location.dist(b2.location);
  }

  void action() {
    update();
    display();
  }

  void display() {
    b1.display();
    b2.display();

    stroke(#FF0000);
    line(b1.location.x, b1.location.y, b2.location.x, b2.location.y);
  }

  void update() {
    b1.move();
    b2.move();

    constrainLength();
  }

  void constrainLength() {
    final float deltaLen = PVector.sub(b2.location, b1.location, tmp).mag();
    tmp.mult((deltaLen - r) / deltaLen / 5);

    b1.location.add(tmp);
    b2.location.sub(tmp);
  }
}
p3tr4s
p3tr4s

Re: How to connect last ball of the array with the first ball?

1 month ago
Thank you,

I wrote this line ten times but getting errors.

Now I see that it had to be written outside the loop.

Good Night;)
Top Reply

Statistics

  • 2 Replies
  • 225  Views
  • 0 Followers

Tags

No tags available for this topic.

Actions

Related Posts