How to calculate the tangent line of a circle?

Programming Questions

nardove

How to calculate the tangent line of a circle?

in Programming Questions • 2 years ago

Hi,

I just dont seem to get this trig problem, so I need your help, I need to calculate the tangent line for each vertex of a circle, liket show in the image

And this is the code

int numSegments = 8;
float radius = 80;
float slope;
PVector[] vectors = new PVector[numSegments];
void setup() {
size(300, 300);
smooth();
noLoop();
// Get cirlce vertices
float k = TWO_PI / (float)numSegments;
for ( int i = 0; i < numSegments; i++ ) {
float x = cos(k*i) * radius;
float y = sin(k*i) * radius;
vectors[i] = new PVector(x, y);
}
}
void draw() {
background(255);
// Get slope at point
float m = (vectors[1].y - vectors[0].y) / (vectors[1].x - vectors[0].x);
slope = pow(-m, -1);
println("slope: " + slope );
float b = vectors[1].y - slope*(vectors[1].x);
println("y intercept: " + b);
// Draw circle
pushMatrix();
translate( width/2, height/2 );
for ( int i = 0; i < numSegments; i++ ) {
float x = vectors[i].x;
float y = vectors[i].y;
float x1 = (i < numSegments-1) ? vectors[i+1].x : vectors[0].x;
float y1 = (i < numSegments-1) ? vectors[i+1].y : vectors[0].y;
stroke(0); noFill();
strokeWeight(2);
line(x, y, x1, y1);
strokeWeight(1);
stroke(127);
line(0, 0, x, y);
fill(127);
textAlign(CENTER);
text("V" + i, x * 1.2, y * 1.2 + 5);
}
popMatrix();
}

Any help will be much appreciated

- rS

Replies(2)

toxmeister

Re: How to calculate the tangent line of a circle?

2 years ago

Your sketch already contains all the answers. The tangent of a circle is perpendicular to the direction to the tangent point from the centre, so using you could just do this:

import toxi.geom.*;
import toxi.processing.*;
ToxiclibsSupport gfx;
void setup() {
size(400, 400);
noFill();
gfx=new ToxiclibsSupport(this);
}
void draw() {
// new circle with radius 100
Circle c=new Circle(width/2, height/2, 100);
// get direction from centre to point
Vec2D mousePos=new Vec2D(mouseX, mouseY);
Vec2D dir=mousePos.sub(c).normalize();
// tangent direction
Vec2D tangent=dir.getPerpendicular();
// point on circle
Vec2D pos=c.add(dir.scale(c.getRadius()));
background(255);
gfx.ellipse(c);
gfx.line(c,pos);
// scale tangent to be more visible
tangent.scaleSelf(50);
gfx.line(pos.sub(tangent),pos.add(tangent));
}

http://postspectacular.com | http://toxiclibs.org

nardove

Re: How to calculate the tangent line of a circle?

2 years ago

You have no idea how toxiclibs are spoiling me (in a good way), I look inside Vec2D.getPerpendicular() method, and the solution strike me with its simplicity

For those interested here is the code:

int numSegments = 8;
float radius = 80;
float slope;
PVector[] vectors = new PVector[numSegments];
void setup() {
size(300, 300);
smooth();
noLoop();
// Get circle vertices
float k = TWO_PI / (float)numSegments;
for ( int i = 0; i < numSegments; i++ ) {
float x = cos(k*i) * radius;
float y = sin(k*i) * radius;
vectors[i] = new PVector(x, y);
}
}
void draw() {
background(255);
// Draw circle
pushMatrix();
translate( width/2, height/2 );
for ( int i = 0; i < numSegments; i++ ) {
float x = vectors[i].x;
float y = vectors[i].y;
float x1 = (i < numSegments-1) ? vectors[i+1].x : vectors[0].x;
float y1 = (i < numSegments-1) ? vectors[i+1].y : vectors[0].y;
stroke(0); noFill();
strokeWeight(2);
line(x, y, x1, y1);
strokeWeight(1);
stroke(127);
line(0, 0, x, y);
// Draw tangent lines
PVector tl = new PVector( -vectors[i].y, vectors[i].x );
tl.mult(0.5f);
stroke(255, 0, 0);
line(vectors[i].x, vectors[i].y, vectors[i].x - tl.x, vectors[i].y - tl.y);
fill(127);
textAlign(CENTER);
text("V" + i, x * 1.2, y * 1.2 + 5);
}
popMatrix();
}

Many thanks!

- rS

Top Reply