How do you make a class with a spaceship...

Programming Questions

shadowvox

How do you make a class with a spaceship...

in Programming Questions • 7 months ago

..changing pictures when keypressed right or left and goes bk to normal when its not?

this is wat i have so far, but not in the class yet

PImage images[];

int index;

int y;

void setup()

{

background (255);

size (500, 500);

images = new PImage[7];

images[0] = loadImage("spaceship2.jpg");

}

void draw()

{

background (255);

PImage a;

a = loadImage("spaceship2.jpg");

image(a, 170, 350);

if (keyPressed);

{

if (key==RIGHT);

{

PImage b;

b = loadImage("2.gif");

image(b, 170, 350+y);

}

it doesnt move right yet, and picture doesnt change

Replies(3)

GoToLoop

Re: How do you make a class with a spaceship...

7 months ago

Hello shadowvox!

There are a few of things you're not doing right.

If you have a variable which needs to be used in more than 1 function or the value must be remembered,
you have to declare them "globally", just the at the top above setup().
And of course, if it's to be used in just 1 function, declare that variable there!

Generally, it's a waste of time & resources to load images within callback function draw().
The reason why is that it only needs to be loaded once; and draw() is generally called 60 times a second!
So it's a bunch of disk readings on spree!

Keyboard readings are best to be put in a separate callback function -> keyPressed() & keyReleased().
Although like in your specific case, it can be done within function draw() anyways.

And most importantly...
Each picture object needs to have its own set of variables to define all of its features like:

location
dimension
speed
color
etc

The best way is to define a class to store all of them.
But you can also use regular variables and arrays for it as well.

Here's a post of 2 months ago from a guy who had similar issues:
http://forum.processing.org/topic/keypressed-problem

Here's the basic sample I've posted there:

/* Move Object Example
 * by GoToLoop (2012/Dec)
 *
 * http://forum.processing.org/topic/keypressed-problem
 */

// Object's variables:
int x, y;     // position
int w, h;     // dimensions
int ww, hh;   // object's radii
int spX, spY; // speed movement
color c;      // color
boolean ballOrBox;

// General variables:
final static color bg  = #FFFF00;   // #yellow

void initVars() {

  x = width>>1;    // center of screen 
  y = height>>1;

  w = width/10;    // 1/10th size of screen
  h = height/10;

  ww = w>>1;       // distances from center (radii)
  hh = h>>1;

  spX = 30;
  spY = 20;

  c = #0000FF;    // #blue
}

void setup() {

  size(800, 600);
  noLoop();            // turn draw() callback off
  rectMode(CENTER);    // coordinates are relative from center
  ellipseMode(CENTER);

  initVars();
}

void draw() {

  background(bg);
  fill(c);

  if (ballOrBox)    ellipse(x, y, w, h);
  else              rect(x, y, w, h);
}

void keyPressed() {

  if (key == ' ' | key == ENTER | key == RETURN)
    ballOrBox = !ballOrBox;

  else if (keyCode == UP    | keyCode == 'W')   y -= spY;
  else if (keyCode == DOWN  | keyCode == 'S')   y += spY;
  else if (keyCode == LEFT  | keyCode == 'A')   x -= spX;
  else if (keyCode == RIGHT | keyCode == 'D')   x += spX;

  if (x > width-ww)    x = width-ww;   // check screen limits
  else if (x < ww)     x = ww;

  if (y > height-hh)   y = height-hh;
  else if (y < hh)     y = hh;

  redraw();   //  draw once
}