What is the best algorithm to plot a co-ordinate using degrees and distance ?

Programming Questions

owaunandr..

What is the best algorithm to plot a co-ordinate using degrees and distance ?

in Programming Questions • 3 years ago

What is the best algorithm to plot a point using degrees and distance ?

I want to be able to draw a line but use the start point (x,y) the degree of movement from that point ( -ve or +ve) degrees and the distance away from that point.

This probably requires mathematics at some level or vectors.

Replies(4)

Jack Kern

Re: What is the best algorithm to plot a co-ordinate using degrees and distance ?

3 years ago

I'd use something like:

float endx = startx + cos(angle) * distance;
float endy = starty + sin(angle) * distance;

Just add your +/- ve into angle after drawing each segment, and set startx/starty to be the previous segment's end point.

http://www.jackkern.com
http://www.twitter.com/ElectricJack

owaunandr..

Re: What is the best algorithm to plot a co-ordinate using degrees and distance ?

3 years ago

Thanks Jack I will try that..

If I want to use the z-axis use atan() or tan ()

toxmeister

Re: What is the best algorithm to plot a co-ordinate using degrees and distance ?

3 years ago

What you're after is called polar coordinates (in 2D) or spherical in (3D), and forgive me repeating this, but my Vec2D & Vec3D classes have built in support for these. Here's a 2D example (and more are in the /examples folder of the library):

To define a point in polar space, the X component is interpreted as radius, the Y as angle (in radians):

// a point at radius 100 and 90 degrees
Vec2D p=new Vec2D(100,HALF_PI);
// now convert it into cartesian space
p.toCartesian();
// converting (back) to polar works too
p.toPolar();

You can also draw lines with in polar space directly, only lines become arcs/curves/spirals (obviously). The example shows how to draw lines in either space between 2 points defined as polar coords:

import toxi.geom.*;
size(400,400);
smooth();
background(255);
translate(width/2,height/2);
stroke(255,0,0);
// start at radius 50, 0 degrees
Vec2D a=new Vec2D(50,0);
// end at readius 150, 270 degrees
Vec2D b=new Vec2D(150,PI*1.5);
// draw a line from a -> b in polar space
// calculate 100 intermediate points
for(int i=0,num=100; i<num; i++) {
Vec2D p=a.interpolateTo(b,(float)i/num).toCartesian();
point(p.x,p.y);
}
// draw a line from a -> b in cartesian space
// first convert points to cartesian
a.toCartesian();
b.toCartesian();
stroke(0,0,255);
// then calculate 100 intermediate points
for(int i=0,num=100; i<num; i++) {
Vec2D p=a.interpolateTo(b,(float)i/num);
point(p.x,p.y);
}

owaunandr..

Re: What is the best algorithm to plot a co-ordinate using degrees and distance ?

3 years ago

thankx toxi... I will try that out.

Top Reply