Loading...
Logo
Processing Forum
Programming Questions
nighrage
nighrage

How do I represent two 3D graphs on a single sketch?

in Programming Questions  •  2 years ago  
I want to publish two 3D graphs on one segmented window but the problems is that the end sketch seems to be distorted. This method seems to work with 2D graphs but I cant get it to work for 3D graphs. I cant seem to figure out what the problem is so any help would be much appreciated. This is what I am trying to generate:-

but this is what I end up with:-



The first part of the sketch;
Copy code
  1.  
  2. import processing.opengl.*;
  3.  
  4. PVector[] vecs = new PVector[160];
  5. int dim = 250;
  6. float x;
  7. float y;
  8. float z;
  9. float maxX, maxY, maxZ;
  10. float minX, minY, minZ;
  11. float rotY;      // Amount of rotation around y-axis.
  12. float rotX;      // Amount of rotation around the x-axis.
  13. PFont font;

  15. void setup()
  16. {
  17.   size(500,500,P3D);
  18.   smooth();
  19.   setupSketch1();
  20.   setupSketch2();
  21. }

  23. void draw()
  24. {  
  25.   scale(.5,.5);
  26.   drawSketch1();
  27.   
  28.   translate(width,0);
  29.   drawSketch2();

  31. }


The second bit of the sketch;
Copy code
  2. void setupSketch1()
  3. {
  4.   font = createFont( "arial", 14 );
  5.   textFont(font);
  6.   
  7. Random gauss = new Random(0);

  9.  for (int i=0; i<vecs.length; i++)
  10.    {
  11.      x = (float)gauss.nextGaussian()*118.9533 + 261.3167;
  12.      y = (float)gauss.nextGaussian()*48.88477 + 133.6271;
  13.      z = (float)gauss.nextGaussian()*3318.683 + 906.6409;
  14.      vecs[i] = new PVector(x, y, z);
  15.      println(vecs[i]);
  16.      
  17.      maxX = max(maxX,vecs[i].x);
  18.      maxY = max(maxY,vecs[i].y);
  19.      maxZ = max(maxZ,vecs[i].z);
  20.      
  21.      minX = min(minX,vecs[i].x);
  22.      minY = min(minY,vecs[i].y);
  23.      minZ = min(minZ,vecs[i].z);
  24.    }

  26. }

  28. void drawSketch1()
  29. {
  30.   background(255);
  31.    
  32.   translate(width/2,height/2);
  33.   scale(1,-1,1); // so Y is up, which makes more sense in plotting
  34.   
  35.   rotateY(rotY);
  36.   rotateX(rotX);
  37.  
  38.   noFill();
  39.   strokeWeight(1);
  40.   stroke(0,10);
  41.   box(dim);
  42.  
  43.   translate(-dim/2,-dim/2,-dim/2);
  44.   
  45.   strokeWeight(2);
  46.   stroke(0);
  47.   line(0,0,0,dim,0,0);
  48.   line(0,0,0,0,dim,0);
  49.   line(0,0,0,0,0,dim);
  50.   
  51.   // Draw axis labels.
  52.   textSize(25);
  53.   String axisLabel;
  54.   fill(50);
  55.   pushMatrix();
  56.   
  57.   scale(1,-1,1);
  58.   axisLabel = "x-axis";
  59.   text(axisLabel,dim-textWidth(axisLabel),0,0);
  60.   
  61.   axisLabel = "y-axis";
  62.   rotateZ(HALF_PI);
  63.   text(axisLabel,-dim,0,0);
  64.   
  65.   axisLabel = "z-axis";
  66.   rotateZ(-HALF_PI);
  67.   rotateY(HALF_PI);
  68.   text(axisLabel,-dim,0,0);
  69.  
  70.   popMatrix();
  71.   
  72.   // Draw cubes.
  73.   for (int i=0; i<vecs.length; i++) 
  74.   {
  75.     PVector v = vecs[i];
  76.     
  77.     // cubes
  78.     noStroke();
  79.     fill( 255, 100, 100 );
  80.     pushMatrix();
  81.     
  82.     // translate(v.x,v.y,v.z);
  83.     
  84.     translate( map(v.x,minX,maxX,0,dim),
  85.                map(v.y,minY,maxY,0,dim),
  86.                map(v.z,minZ,maxZ,0,dim));
  87.     
  88.     box(5);
  89.     popMatrix();
  90.     
  91.   }
  92. }

Replies(6)

nighrage
nighrage

Re: How do I represent two 3D graphs on a single sketch?

2 years ago
Help...Anybody?
tfguy44
tfguy44

Re: How do I represent two 3D graphs on a single sketch?

2 years ago
Merging two graphs is never easy. I don't know what was throwing off your view, so I started with what you had, slimmed it down a bit, and got this:

Copy code
  1. PFont font;

  3. void setup()
  4. {
  5.   size(500,500,P3D);
  6.   smooth();
  7.   font = createFont( "arial", 25 );
  8.   textFont(font);
  9. }

  11. void draw()
  12. {  
  13.  background(255);
  14.    
  15.   translate(width/2.0,height/2.0);
  16.   scale(1,-1,1); // so Y is up, which makes more sense in plotting
  17.   
  18.   
  19.   rotateX(map(mouseY,0,width,-PI,PI));
  20.   rotateY(map(mouseX,0,height,-PI,PI));
  21.  
  22.   noFill();
  23.   strokeWeight(1);
  24.   stroke(0,10);
  25.   box(250);
  26.   
  27.    // Draw axis labels.
  28.   textSize(25);
  29.   String axisLabel;
  30.   fill(50);
  31.   pushMatrix();
  32.   translate(-125,-125,-125);
  33.   
  34.   scale(1,-1,1);
  35.   axisLabel = "x-axis";
  36.   text(axisLabel,250 - textWidth(axisLabel),0,0);
  37.   
  38.   axisLabel = "y-axis";
  39.   rotateZ(HALF_PI);
  40.   text(axisLabel,-250,0,0);
  41.   
  42.   axisLabel = "z-axis";
  43.   rotateZ(-HALF_PI);
  44.   rotateY(HALF_PI);
  45.   text(axisLabel,-250,0,0);

  47.   
  48.   strokeWeight(2);
  49.   stroke(0);
  50.   line(0,0,0,-250,0,0);
  51.   line(0,0,0,0,-250,0);
  52.   line(0,0,0,0,0,250);
  53.   
  54.   popMatrix();
  55. }

It's leaving out any code that renders little red squares, and it doesn't muck about with scale(1,-1,1) calls, but at least the perspective is right!
tfguy44
tfguy44

Re: How do I represent two 3D graphs on a single sketch?

2 years ago
Oh! I'm thick! I thought the problem was the skewed perspective! After reading what you actually posted, the solution is simple: Just render the second 3D view to a separate PGraphics object, then draw it's image next to the first one!

Here's the demo code snippet I have about doing that. This has three separate possible views, but you only need an always-on second one:

Copy code
  1. /// "ThreeViews" by TfGuy44 (TfGuy44@gmail.com)
  2. PGraphics BC, GC, RC;
  3. float rot = 0.0;

  5. void setup(){
  6.   size( 400, 200, P2D);
  7.   BC = createGraphics(200, 200, P3D);
  8.   RC = createGraphics(200, 200, P3D);
  9.   GC = createGraphics(200, 200, P3D);
  10. }

  12. void draw(){
  13.   rot=(rot+0.01)%360;
  14.   // Render the "main" scene.
  15.   background(0);
  16.   noStroke();
  17.   fill(color(255,0,0));
  18.   rect(10,40,20,20);
  19.   fill(color(0,0,255));
  20.   rect(70,70,20,20);
  21.   fill(color(0,255,0));
  22.   rect(70,10,20,20);
  23.   // Render to things off-screen!
  24.   RC.beginDraw();
  25.   RC.background(color(128,0,0));
  26.   RC.fill(color(255,0,0));
  27.   RC.lights();
  28.   RC.translate(100,100,0);
  29.   RC.rotateX(rot);
  30.   RC.rotateY(2*rot);
  31.   RC.box(20);
  32.   RC.endDraw();
  33.   // And the green one...
  34.   GC.beginDraw();
  35.   GC.background(color(0,128,0));
  36.   GC.fill(color(0,255,0));
  37.   GC.lights();
  38.   GC.translate(100,100,0);
  39.   GC.rotateX(rot);
  40.   GC.rotateY(2*rot);
  41.   GC.box(50);
  42.   GC.endDraw();
  43.   // And the blue one...
  44.   BC.beginDraw();
  45.   BC.background(color(0,0,128));
  46.   BC.fill(color(0,0,255));
  47.   BC.lights();
  48.   BC.translate(100,100,0);
  49.   BC.rotateX(rot);
  50.   BC.rotateY(2*rot);
  51.   BC.box(80);
  52.   BC.endDraw();
  53.   // Display one of those buffers? 
  54.   if( get( mouseX, mouseY ) == color(255,0,0) ){
  55.     image( RC.get(), 200, 0);
  56.   }
  57.   if( get( mouseX, mouseY ) == color(0,255,0) ){
  58.     image( GC.get(), 200, 0);
  59.   }
  60.   if( get( mouseX, mouseY ) == color(0,0,255) ){
  61.     image( BC.get(), 200, 0);
  62.   } 
  63. }

nighrage
nighrage

Re: Re: How do I represent two 3D graphs on a single sketch?

2 years ago
Thank you for responding mate. I did try out your method in my sketch but it doesn't seem to resolve the problem for some weird reason. 
Makio135
Makio135

Re: How do I represent two 3D graphs on a single sketch?

2 years ago
@tfguy44: thanks for the tip

@nighrage: think you could look for Napplet library
nighrage
nighrage

Re: Re: How do I represent two 3D graphs on a single sketch?

2 years ago
Cheers mate.:)
Top Reply

Statistics

  • 6 Replies
  • 1070  Views
  • 0 Followers

Tags

No tags available for this topic.

Actions

Related Posts