You should mention that this code was written by GoToLoop and you copy-pasted it from here without changing a thing. In the current form the code is really meant for drawing one circle, for example see the global variables. You can turn this code into a custom function drawMovingCircle() which takes some input parameters such as x, y, segments, radius etc. Then it will be easier to make multiple circles at different positions and with different radii.

Or if you really want the exact same circle but just smaller, you can add something like the following INSIDE the for loop but AFTER the line() call:

1.     p0.mult(0.3);
2.     p1.mult(0.3);
3.     line(p0.x, p0.y, p1.x, p1.y);

T'wasn't me who wrote that perlin noise example, but baud.r! Just made some tiny tweaks! 

I guess in order to change the circle, it's just enough to change constant -> INNER_RADIUS.
Those all-caps variables are there for just that!

It's a good idea to turn the whole code into a class, so you can have as many copies of it on canvas.
And those constants can be passed as constructor parameters! 

Now it's in a class. You can use the constructor to manually create a MovingCircle with specific settings, you can randomly generate some circles or you can use mousePressed to generate a MovingCircle at the position of the mouse. To learn more about classes, check out this page.

Adapted Code

1. int numCircles = 5;
2. ArrayList <MovingCircle> circles = new ArrayList <MovingCircle> ();
3.  
4. void setup() {
5.   size(500, 500);
6.   smooth();
7.   for (int i=0; i<numCircles; i++) {
8.     circles.add( new MovingCircle((int)random(width), (int)random(height), 100,
9.         random(10,100), random(50,100), random(0.2, 0.8), 4) );
10.   }
11. }
12.  
13. void draw() {
14.   background(255);
15.   for (MovingCircle mc : circles) {
16.     mc.display();
17.   }
18. }
19.  
20. void mousePressed() {
21.   circles.add( new MovingCircle(mouseX, mouseY, 100, random(10,100),
22.       random(50,100), random(0.2, 0.8), 4) );
23. }
24.  
25. class MovingCircle {
26.   int x, y, segments;
27.   float rad, radVariation, noiseScale, theta, lineWeight, unique;
28.  
29.   MovingCircle(int x, int y, int segments, float rad, float radVariation,
30.       float noiseScale, float lineWeight) {
31.     this.x = x;
32.     this.y = y;
33.     this.segments = segments;
34.     this.rad = rad;
35.     this.radVariation = radVariation;
36.     this.noiseScale = noiseScale;
37.     this.lineWeight = lineWeight;
38.     theta = TWO_PI / segments;
39.     unique = random(10000);
40.   }
41.  
42.   void display() {
43.     pushMatrix();
44.     translate(x, y);
45.     strokeWeight(lineWeight);
46.     for (int i=0; i!=segments;) {
47.       PVector p0 = PointForIndex(i);
48.       PVector p1 = PointForIndex(++i);
49.       line(p0.x, p0.y, p1.x, p1.y);
50.     }
51.     popMatrix();
52.   }
53.  
54.   PVector PointForIndex(int i) {
55.     float angle = theta*i;
56.     float cosAngle = cos(angle);
57.     float sinAngle = sin(angle);
58.     float time = unique + frameCount * 1e-2;
59.     float noiseValue = noise(noiseScale*cosAngle + noiseScale,
60.         noiseScale*sinAngle + noiseScale, time);
61.     float radius = rad + radVariation*noiseValue;
62.     return new PVector(radius*cosAngle, radius*sinAngle);
63.   }
64. }

ok, now i understand, but how do i put the circle on specific point, i mean if i wan circle to be center and all the circle will be on the larger circle which mean on a ripple pattern.. now i wanna know how to put the circle on specific place..

See the constructor of the MovingCircle class. The first two parameters are x and y. These two are the position of the circles. For example lines 21 places them at the mouse position. Just change the code and see what happens.

Sorry for posting other ppl code here...
I'm still new, so I'm trying other ppl code as a step to get familiar with Processing...

I'm still in training too. And I love to tweak other peeps code too! 

And I did a variation of the code again. You asked for a circle inside another circle.
Then, here's my Perlin Egg version: