How can I make a ball always move towards the player character?

Programming Questions

mnredr

How can I make a ball always move towards the player character?

in Programming Questions • 5 months ago

I'm making a game that has an enemy move in a circle around the center of the screen (kind of like an orbit). The player is within this circle, it can move around.
The enemy shoots balls out every 3 seconds. I want these balls to always be aimed at the player's current position. It doesn't need to follow the player around when it moves, but it needs to be aimed towards the player.

Here are some images to show what I want to do. The red arrow is how the ball should move.

Thanks in advance.

Replies(6)

GoToLoop

Re: How can I make a ball always move towards the player character?

5 months ago

Look for program 'Multiple Bullets' at this post below:

http://forum.processing.org/topic/array-usage-objects-in-general

In that example, a bullet goes from playerPos towards ( mouseX, mouseY).

It uses PVectors for those calculations!

mnredr

Re: How can I make a ball always move towards the player character?

5 months ago

Sorry, I looked through this and played with the code since you first posted it an hour ago and I still don't understand much of it. I'm not familiar with PVectors. Do you know what kind of formulas Processing uses to calculate vector motion?

EDIT: I have a hunch about what to do.. should I give my enemy and player a PVector for their positions, and give the ball a PVector for its velocity.. then set the velocity to the player position?

GoToLoop

Re: How can I make a ball always move towards the player character?

5 months ago

I don't understand that much how it works either! I'm not the author of that. I've just tweaked it a little!

I've just thought that example would be the closest to adapt for your needs!

The playerPos from that example would be your monster PVector instead.

And the mouse coordinates would become your hero coordinates now!

The Bullet created would try to reach your locked hero's coordinates at the speed of your choice!

Well, that's it! Post your code when you need more help!

asimes

Re: How can I make a ball always move towards the player character?

5 months ago

This should be helpful for you. I only did one projectile, to fire more than one use an array and fire each one after some amount of time:

int rad = 250;
float theta = 0;
PVector enemy, player, projectile, target;
void setup() {
size(600, 600);
enemy = new PVector(rad, 0);
player = new PVector(width/2, height/2);
projectile = new PVector(enemy.x, enemy.y);
target = new PVector(player.x, player.y);
}
void draw() {
background(128);
// Move the enemy in a circle
enemy.x = width/2+cos(theta)*rad;
enemy.y = height/2+sin(theta)*rad;
theta += TWO_PI/500;
// Replace this condition with your 3 second timer
if (frameCount%180 == 0) {
// Make the starting position of the projectile be where the enemy is
projectile.x = enemy.x;
projectile.y = enemy.y;
// Aim at wherever the player currently is
target.x = player.x-enemy.x;
target.y = player.y-enemy.y;
// Normalize the direction vector
target.normalize();
// Multiply by whatever speed you want the projectile to move
target.x *= 5;
target.y *= 5;
}
// Update the projectile
projectile.x += target.x;
projectile.y += target.y;
fill(255);
ellipse(width/2, height/2, rad*2, rad*2);
ellipse(enemy.x, enemy.y, 50, 50);
ellipse(player.x, player.y, 50, 50);
fill(255, 0, 0);
ellipse(projectile.x, projectile.y, 10, 10);
}

allonestr..

Re: How can I make a ball always move towards the player character?

5 months ago

Taking vectors out of it, all you need to know is the distance from the target to the follower:

float dx = targetx - followerx;

float dy = targety - followery;

I assume that you move the target:

target.move(); // or however you're doing it

Then move the follower a proportion of the distance between them

followerx = followerx + dx / 100; //say

followery = followery + dy / 100; //say

GoToLoop

Re: How can I make a ball always move towards the player character?

5 months ago

Here's a re-factored asimes's code sample. Fully parameterized & using other PVector's methods.

Check it online too:

http://studio.processingtogether.com/sp/pad/export/ro.91nVQMnL$v06L/latest

2013/Apr/22 -> (v2.3):

Using translate() to display objects;
Using PVector.rotate() in place of variable theta.

(v2.5):

enemy can spit more than 1 fire bullet now!
new function showBullets().

2013/Apr/23 -> (v2.6):

Player moves erratically @ P_SPD steps.

2013/Apr/24 -> (v2.7):

Back working online! Method rotate() from class PVector doesn't work there!

/**
 Spit Fire Sample (v2.71)
 by  asimes (2013/Apr)
 mod GoToLoop
 for mnredr
 
 http://forum.processing.org/topic/how-can-i-make-a-ball-always-move-towards-the-player-character
 
 http://studio.processingtogether.com/sp/pad/export/ro.91nVQMnL$v06L/latest
 */

final static String GFX = JAVA2D; // Use JAVA2D for Processing 2+ or P2D

final static short E_SPD = 25, P_SPD = 5, B_SPD = 5, B_FREQ = 40;
final static short E_SIZE = 50, P_SIZE = 50, B_SIZE = 10;
final static float FPS = 50, BOLD = 2;

final static color E_COL = #00FF00, P_COL = #0000FF, B_COL = #FF0000;
final static color BG = 0100, FG = 0300;

final static byte MAX_BULLETS = 3;
final static PVector[] bullets = new PVector[MAX_BULLETS];
final static PVector[] targets = new PVector[MAX_BULLETS];

final static PVector enemy  = new PVector();
final static PVector player = new PVector();

int centerX, centerY, diam, rad, bulletsIdx;
//float theta;

void setup() {
  size(700, 700, GFX);
  frameRate(FPS);
  smooth();
  strokeWeight(BOLD);
  ellipseMode(CENTER);
  imageMode(CENTER);

  centerX = width  >> 1;
  centerY = height >> 1;
  diam = width - 100;
  rad  = diam >> 1;

  enemy.set(rad, 0, 0);

  for (int i = 0; i != MAX_BULLETS; i++) {
    bullets[i] = new PVector(1e5, 1e5);
    targets[i] = new PVector();
  }
}

void draw() {
  background(BG);

  // Move the enemy in a circle:
  enemy.rotate(-HALF_PI/E_SPD);
  //enemy.set(cos(theta -= HALF_PI/E_SPD)*rad, sin(theta)*rad, 0);

  // Create bullets:
  if (frameCount % B_FREQ == 0)    spitFire();

  // Display all objects:
  show();
}

void spitFire() {
  // Make the starting position of the bullets be where the enemy is:
  bullets[bulletsIdx = (bulletsIdx + 1) % MAX_BULLETS].set(enemy);

  // Aim at wherever the player currently is:
  final PVector t = targets[bulletsIdx];
  PVector.sub(player, enemy, t);
  //t.set( PVector.sub(player, enemy) );

  // Normalize the direction vector:
  t.normalize();

  // Multiply by whatever speed you want bullets to move:
  t.mult(B_SPD);
}

void show() {
  translate(centerX, centerY);              // centralizes

  fill(FG);
  ellipse(0, 0, diam, diam);

  fill(E_COL);
  ellipse(enemy.x, enemy.y, E_SIZE, E_SIZE);

  fill(P_COL);
  player.add(random(-P_SPD, P_SPD), random(-P_SPD, P_SPD), 0);
  ellipse(player.x, player.y, P_SIZE, P_SIZE);

  // Update & display bullets:
  showBullets();
}

void showBullets() {
  fill(B_COL);

  for (int i = 0; i != MAX_BULLETS;) {
    PVector b = bullets[i];
    b.add(targets[i++]);                    // updates
    ellipse(b.x, b.y, B_SIZE, B_SIZE);      // displays
  }
}

Top Reply