" Is it possible"
Yes, of course! It shouldn't be too hard, indeed.

With a lot of points it would be best to make a basic class that stores the point and the image. Otherwise you might get stuck in a web of if's in the draw() loop. Another advantage of a class is that you can tweak the behavior, for example the gradual appearance of the image. Any changes in the class would immediately be applied to all the points. See the small example below.

For more information on classes/objects see this page.

Code Example

1. ArrayList <ImageCoordinate> points = new ArrayList <ImageCoordinate> ();
2.  
3. void setup() {
4.   size(600, 600);
5.   noStroke();
6.   smooth();
7.   PImage a = loadImage("http://www.psdvault.com/wp-content/uploads/thumbs/landscape-photo-manip-200.jpg");
8.   PImage b = loadImage("http://woofie1.pixiq.com/files/blog/smallaperture/uploads/2010/08/arizona-landscape_200x200.jpg");
9.   PImage c = loadImage("http://mykelownabuzz.com/wp-content/uploads/2011/06/landscape-200x200.jpg");
10.   points.add(new ImageCoordinate( 50, 150, a));
11.   points.add(new ImageCoordinate(170, 350, a));
12.   points.add(new ImageCoordinate(400, 250, b));
13.   points.add(new ImageCoordinate(305,  50, b));
14.   points.add(new ImageCoordinate(250, 250, c));
15.   points.add(new ImageCoordinate(100, 450, c));
16. }
17.  
18. void draw() {
19.   background(255);
20.   for (ImageCoordinate ic : points) {
21.     ic.update();
22.     ic.display();
23.   }
24. }
25.  
26. class ImageCoordinate {
27.   int x, y, transparency;
28.   PImage img;
29.  
30.   ImageCoordinate(int x, int y, PImage img) {
31.     this.x = x;
32.     this.y = y;
33.     this.img = img;
34.   }
35.  
36.   void update() {
37.     if (dist(mouseX, mouseY, x, y) < 15 && transparency < 255) {
38.       transparency += 5;
39.     } else if (transparency > 0) {
40.       transparency -= 3;
41.     }
42.   }
43.  
44.   void display() {
45.     fill(0);
46.     ellipse(x, y, 10, 10);
47.     fill(0, transparency);
48.     rect(x-1, y-1, img.width+2, img.height+2);
49.     tint(255, transparency);
50.     image(img, x, y);
51.   }
52. }