High-resolution MouseEvent catching (or how to access queued MouseEvent)

Programming Questions

dimkir

High-resolution MouseEvent catching (or how to access queued MouseEvent)

in Programming Questions • 4 months ago

I want to draw smooth lines on screen with the mouse.

if I do it this way

void draw()
{
line(pmouseX, mouseY, mouseX, mouseY);
}

then the lines wouldn't be smooth (even if instead of line() I would use curve() or curveVertex() it will not take into account all of the points where mouse was. And what's even worse would be frame-dependent.

How to get access to high-resolution mouse movements? (Like those movements which happen between the frames? As far as I understand events are caught in a separate thread (not drawing), so that thread should have very high-precision history of mouse movements somewhere?

thanx in advance,

Dimitry

Replies(2)

quarks

Re: High-resolution MouseEvent catching (or how to access queued MouseEvent)

4 months ago

The operating system system will capture mouse movements and then create mouse events which it sends to the active application.

In Processing these are caught by the mouseMoved() method.

This program demonstartes that there can be multiple mouse moved events between calls to draw. So if you want to capture every mouse moved event use the mouseMoved() method.

int lastX, lastY;
void setup(){
size(300,300);
}
void draw(){
int dx = (mouseX - pmouseX);
int dy = (mouseY - pmouseY);
println("DRAW mouse moved by " + dx + " " + dy) ;
}
void mouseMoved(){
println("MOUSE_MOVED by " + (mouseX - lastX) + " " + (mouseY - lastY));
lastX = mouseX;
lastY = mouseY;
}

BTW mouse position resolution is 1 pixel (that is as HIRES as it gets)

dimkir

Re: High-resolution MouseEvent catching (or how to access queued MouseEvent)

4 months ago

thank you Quarks,

that was exactly what I was looking for. Now I am queueing the mouse events and then drawing them inside of draw. That made my sketch frame-independent.

// i think thousand queued mouse events between two frames would be enough
final int MAX_QUEUED_MOUSE_EVENTS = 1000;
int[] queueOfMouseX = new int[MAX_QUEUED_MOUSE_EVENTS];
int[] queueOfMouseY = new int[MAX_QUEUED_MOUSE_EVENTS];
int queuedEventsCount = 0;
int lastX, lastY;
void setup(){
size(800,600 );
//frameRate(5);
}
void draw(){
drawQueuedMouseEvents();
// int dx = (mouseX - pmouseX);
// int dy = (mouseY - pmouseY);
// println("DRAW mouse moved by " + dx + " " + dy) ;
}
void mouseMoved(){
// println("MOUSE_MOVED by " + (mouseX - lastX) + " " + (mouseY - lastY));
lastX = mouseX;
lastY = mouseY;
saveMouseEvent(mouseX, mouseY);
}
void mousePressed(){
background(128);
}
void saveMouseEvent(int mx, int my){
if ( queuedEventsCount == MAX_QUEUED_MOUSE_EVENTS ){
throw new RuntimeException("Some error in logic. cannot be between frames so many mouse events and movements");
}
queueOfMouseX[queuedEventsCount] = mx;
queueOfMouseY[queuedEventsCount] = my;
queuedEventsCount++;
}
void drawQueuedMouseEvents(){
println("Queued mouse event count: " + queuedEventsCount );
for(int i = 0 ; i < queuedEventsCount ; i++){
drawMouse(queueOfMouseX[i], queueOfMouseY[i]);
}
queuedEventsCount = 0;
}
void drawMouse(int xx, int yy){
ellipse(xx, yy, 3, 3);
}

Top Reply