Hexagonal Grid - Adjacent hexagons array

Programming Questions

idmay19

Hexagonal Grid - Adjacent hexagons array

in Programming Questions • 4 months ago

Hello all,

At this moment I am working on a program to show an emergent system like The Game of Life from Conway. I want each hexagon to follow 3 different rules, causing an emergent behaviour.

I managed to make a hexagonal grid, but now I want to add 3 rules, where all units should listen to:

1. your color should be the average color (grayscale) of your neighbors (the 6 adjacent cells have a colorvalue, so the colorvalue of this hexagon should be the sum allcolorvalues/6.

2 if the colorvalues of your neigbors are to close to eachother, your value should rise to the maximum colorvalue (with RGB this is 255 (white), when the average colorvalue of your neighbors is LOWER then 127 (half of 255).

3. if the colorvalues of your neigbors are to close to eachother, your value should rise to the minimum colorvalue (with RGB this is 0 (black), when the average colorvalue of your neighbors is HIGHER then 127 (half of 255).

In this way there is no form of saturation and all units should behave emergent.

Does anyone know how I can give those rules to all the hexagons?

Bellow you will find the code for the hexagongrid.

Code:

Hexagon[][] hexagon;

int rad = 15;

int hexcountx, hexcounty;

void setup()

{

size(1200, 800);

smooth();

frameRate(50);

hexcountx = (height/(rad));

hexcounty = (width/(rad)*2);

hexagon = new Hexagon [hexcountx][hexcounty];

for (int i = 0; i < hexcountx; i++){

for (int j = 0; j < hexcounty; j++){

if ((j % 2) == 0) {

hexagon[i][j] = new Hexagon((3 * rad * i), (.866 * rad * j), rad);

} else {

hexagon[i][j] = new Hexagon(3 * rad * (i + .5), .866 * rad * j, rad);

}

void draw(){

for (int i = 0; i < hexcountx; i ++ ) {

for (int j = 0; j < hexcounty; j ++ ) {

hexagon[i][j].display();

}

class Hexagon{

float x,y,radi;

float angle = 360.0 / 6;

Hexagon(float cx, float cy, float r)

{

x=cx;

y=cy;

radi=r;

}

void display(){

beginShape();

for (int i = 0; i < 6; i++)

{

vertex(x + radi * cos(radians(angle * i)),

y + radi * sin(radians(angle * i)));

}

colorMode(HSB, 500);

fill(500);

endShape(CLOSE);

}

Replies(5)

tfguy44

Re: Hexagonal Grid - Adjacent hexagons array

4 months ago

Here's a good start. I can't be bothered to finish this, nor can I be bothered to make sure I'm accessing the 6 hexagons around each one.

Hexagon[][] hexagon;
int rad = 15;
int hexcountx, hexcounty;
void setup()
{
size(1200, 800);
smooth();
frameRate(50);
hexcountx = (height/(rad));
hexcounty = (width/(rad));//*2);
hexagon = new Hexagon [hexcountx][hexcounty];
for (int i = 0; i < hexcountx; i++) {
for (int j = 0; j < hexcounty; j++) {
if ((j % 2) == 0) {
hexagon[i][j] = new Hexagon((3 * rad * i), (.866 * rad * j), rad);
}
else {
hexagon[i][j] = new Hexagon(3 * rad * (i + .5), .866 * rad * j, rad);
}
}
}
}
void draw() {
for (int i = 0; i < hexcountx; i ++ ) {
for (int j = 0; j < hexcounty; j ++ ) {
hexagon[i][j].newColor(i,j);
}
}
for (int i = 0; i < hexcountx; i ++ ) {
for (int j = 0; j < hexcounty; j ++ ) {
hexagon[i][j].display();
}
}
}
class Hexagon {
float x, y, radi;
float angle = 360.0 / 6;
int myColor;
Hexagon(float cx, float cy, float r)
{
x=cx;
y=cy;
radi=r;
myColor = rcolor();
}
void display() {
beginShape();
for (int i = 0; i < 6; i++)
{
vertex(x + radi * cos(radians(angle * i)),
y + radi * sin(radians(angle * i)));
}
colorMode(HSB, 500);
fill(myColor);//rcolor());//500);
endShape(CLOSE);
}
void newColor(int i, int j){
int total = 0;
total+=hexagon[i][(j-1+hexcounty)%hexcounty].myColor;
total+=hexagon[i][(j+1+hexcounty)%hexcounty].myColor;
total+=hexagon[(i-1+hexcountx)%hexcountx][(j+hexcounty)%hexcounty].myColor;
total+=hexagon[(i+1+hexcountx)%hexcountx][(j+hexcounty)%hexcounty].myColor;
total/=4;
myColor = total;
}
}
int rcolor(){
return( int(random(500)) );
}

Mushussu

Re: Hexagonal Grid - Adjacent hexagons array

4 months ago

Here is my approach. Clic on hex to see neighborhood.

Hexagon[] hexagon;
float rad = 15;
int nHexWidth, nHexHeight;
float angle = PI / 3;
void setup() {
nHexWidth = 30; // Must be pair
nHexHeight = 20;
float nWidth = nHexWidth * (rad + rad * cos(PI / 3)) + rad - rad * cos(PI / 3);
float nHeight = (nHexHeight * 2 + 1) * rad * sin(PI / 3) ;
size((int)nWidth, (int)nHeight);
smooth();
frameRate(20);
hexagon = new Hexagon [nHexWidth * nHexHeight];
for (int i = 0; i <nHexWidth; i++) {
for (int j = 0; j < nHexHeight; j++) {
float x = i * (rad + rad * cos(PI / 3)) + rad;
float y;
if (i % 2 == 0) {
y = j * 2 * rad *sin(PI / 3) + rad *sin(PI / 3);
} else {
y = j * 2 * rad *sin(PI / 3) + 2 * rad *sin(PI / 3);
;
}
hexagon[j * nHexWidth + i] = new Hexagon(j * nHexWidth + i, x, y, rad);
hexagon[j * nHexWidth + i].initNeighbor(nHexWidth, nHexHeight);
}
}
}
void draw() {
background(0);
for (int i = 0; i < hexagon.length; i ++ ) {
hexagon[i].display();
}
}
void mousePressed() {
for (int i = 0; i < hexagon.length; i++) {
if (sqrt((mouseX - hexagon[i].x) * (mouseX - hexagon[i].x) + (mouseY - hexagon[i].y) * (mouseY - hexagon[i].y)) < rad * sin(angle)) {
for (int j = 0; j < hexagon[i].nNeighbor; j ++) {
hexagon[hexagon[i].neighbor[j]].myColor = color(255, 0, 0);
//println(hexagon[i].neighbor[j]);
}
println();
}
}
}
void mouseReleased() {
for (int i = 0; i < hexagon.length; i++) {
hexagon[i].myColor = color(255);
}
}
class Hexagon {
float x, y, r;
int myColor;
int id;
int nNeighbor;
int[] neighbor;
Hexagon(int _id, float _x, float _y, float _r) {
id = _id;
x = _x;
y = _y;
r = _r;
myColor = color(255);
}
void display() {
fill(myColor);
beginShape();
for (int i = 0; i < 6; i++) {
vertex(x + r * cos(angle * i), y + r * sin(angle * i));
}
endShape(CLOSE);
}
void initNeighbor(int hexWidth, int hexHeight) {
neighbor = new int[2];
neighbor[0] = id - hexWidth;
neighbor[1] = id + hexWidth;
int xHex = id % hexWidth;
if (xHex > 0) {
neighbor = expand(neighbor, neighbor.length + 2);
if (id % 2 == 0) {
neighbor[2] = id - 1;
neighbor[3] = id - hexWidth - 1;
} else {
neighbor[2] = id +hexWidth - 1;
neighbor[3] = id - 1;
}
}
if (xHex < hexWidth - 1) {
neighbor = expand(neighbor, neighbor.length + 2);
if (id % 2 == 0) {
neighbor[neighbor.length - 2] = id - hexWidth + 1;
neighbor[neighbor.length - 1] = id + 1;
} else {
neighbor[neighbor.length - 2] = id + 1;
neighbor[neighbor.length - 1] = id + hexWidth + 1;
}
}
for (int i = 0; i < neighbor.length; i++) {
if ((neighbor[i] < 0) || (neighbor[i] >= hexWidth * hexHeight)) {
for (int j = i + 1; j < neighbor.length; j++) {
neighbor[j - 1] = neighbor[j];
}
neighbor = shorten(neighbor);
i--;
}
}
nNeighbor = neighbor.length;
}
}

Mushussu

Re: Hexagonal Grid - Adjacent hexagons array

4 months ago

Last but not least :

Hexagon[] hexagon;
float rad = 15;
int nHexWidth, nHexHeight;
float angle = PI / 3;
int threshold;
void setup() {
nHexWidth = 30; // Must be pair
nHexHeight = 20;
threshold = 10;
float nWidth = nHexWidth * (rad + rad * cos(PI / 3)) + rad - rad * cos(PI / 3);
float nHeight = (nHexHeight * 2 + 1) * rad * sin(PI / 3) ;
size((int)nWidth, (int)nHeight);
smooth();
frameRate(1);
hexagon = new Hexagon [nHexWidth * nHexHeight];
for (int i = 0; i <nHexWidth; i++) {
for (int j = 0; j < nHexHeight; j++) {
float x = i * (rad + rad * cos(PI / 3)) + rad;
float y;
if (i % 2 == 0) {
y = j * 2 * rad *sin(PI / 3) + rad *sin(PI / 3);
} else {
y = j * 2 * rad *sin(PI / 3) + 2 * rad *sin(PI / 3);
}
hexagon[j * nHexWidth + i] = new Hexagon(j * nHexWidth + i, x, y, rad);
hexagon[j * nHexWidth + i].initNeighbor(nHexWidth, nHexHeight);
}
}
}
void draw() {
background(0);
for (int i = 0; i < hexagon.length; i ++ ) {
int moyenne = 0;
int minVal = 255;
int maxVal = 0;
for (int j = 0; j < hexagon[i].nNeighbor; j++) {
int valeur = hexagon[hexagon[i].neighbor[j]].myColor;
if (valeur < minVal) {
minVal = valeur;
}
if (valeur > maxVal) {
maxVal = valeur;
}
moyenne += valeur;
}
moyenne = moyenne / hexagon[i].nNeighbor; // Rule 1
hexagon[i].nextColor = moyenne;
if (((maxVal - minVal) < threshold) && moyenne < 127) { // Rule 2
hexagon[i].nextColor = 255;
}
if (((maxVal - minVal) < threshold) && moyenne > 127) { // Rule 3
hexagon[i].nextColor = 0;
}
}
for (int i = 0; i < hexagon.length; i ++ ) {
hexagon[i].update();
}
for (int i = 0; i < hexagon.length; i ++ ) {
hexagon[i].display();
}
}
void mousePressed() {
for (int i = 0; i < hexagon.length; i++) {
if (sqrt((mouseX - hexagon[i].x) * (mouseX - hexagon[i].x) + (mouseY - hexagon[i].y) * (mouseY - hexagon[i].y)) < rad * sin(angle)) {
for (int j = 0; j < hexagon[i].nNeighbor; j ++) {
hexagon[hexagon[i].neighbor[j]].myColor = color(255, 0, 0);
//println(hexagon[i].neighbor[j]);
}
println();
}
}
}
void mouseReleased() {
for (int i = 0; i < hexagon.length; i++) {
hexagon[i].myColor = color(255);
}
}
class Hexagon {
float x, y, r;
int myColor, nextColor;
int id;
int nNeighbor;
int[] neighbor;
Hexagon(int _id, float _x, float _y, float _r) {
id = _id;
x = _x;
y = _y;
r = _r;
myColor = (int)random(0, 255);
nextColor = 0;
}
void display() {
fill(myColor);
beginShape();
for (int i = 0; i < 6; i++) {
vertex(x + r * cos(angle * i), y + r * sin(angle * i));
}
endShape(CLOSE);
}
void initNeighbor(int hexWidth, int hexHeight) {
neighbor = new int[2];
neighbor[0] = id - hexWidth;
neighbor[1] = id + hexWidth;
int xHex = id % hexWidth;
if (xHex > 0) {
neighbor = expand(neighbor, neighbor.length + 2);
if (id % 2 == 0) {
neighbor[2] = id - 1;
neighbor[3] = id - hexWidth - 1;
} else {
neighbor[2] = id +hexWidth - 1;
neighbor[3] = id - 1;
}
}
if (xHex < hexWidth - 1) {
neighbor = expand(neighbor, neighbor.length + 2);
if (id % 2 == 0) {
neighbor[neighbor.length - 2] = id - hexWidth + 1;
neighbor[neighbor.length - 1] = id + 1;
} else {
neighbor[neighbor.length - 2] = id + 1;
neighbor[neighbor.length - 1] = id + hexWidth + 1;
}
}
for (int i = 0; i < neighbor.length; i++) {
if ((neighbor[i] < 0) || (neighbor[i] >= hexWidth * hexHeight)) {
for (int j = i + 1; j < neighbor.length; j++) {
neighbor[j - 1] = neighbor[j];
}
neighbor = shorten(neighbor);
i--;
}
}
nNeighbor = neighbor.length;
}
void update() {
myColor = nextColor;
nextColor = 0;
}
}

idmay19

Re: Hexagonal Grid - Adjacent hexagons array

4 months ago

Thanks a lot!

With both of your answers I can create the program and the behaviour I want.

Next challenge is to add color to it, which I think is possible with the HSB color mode. If I can't figure it out, which I don't think, I know who to ask!