Hexagonal Array, Dummy maths question.

Programming Questions

miles.tone

Hexagonal Array, Dummy maths question.

in Programming Questions • 2 years ago

Hi there,

Im trying to make a simple honeycomb structure

I keep on going round in circles, I'm missing one simple computation somewhere.

Heres the code:

Hexagon[][] hexagon;

int rad = 50;

int hexcountx, hexcounty;

void setup()

{

size(300, 300);

background(255);

smooth();

noFill();

stroke(0);

hexcountx = (height/(rad*2));

hexcounty = (width/(rad*2));

hexagon = new Hexagon [hexcountx][hexcounty];

for (int i = 0; i < hexcountx; i++){

for (int j = 0; j < hexcounty; j++){

hexagon[i][j] = new Hexagon((2*rad*i), (rad*j), rad);

}

}

}

void draw(){

for (int i = 0; i < hexcountx; i ++ ) {

for (int j = 0; j < hexcounty; j ++ ) {

// Oscillate and display each object

hexagon[i][j].display();

}

}

}

class Hexagon{

float x,y,radi;

float angle = 360.0 / 6;

Hexagon(float cx, float cy, float r)

{

x=cx;

y=cy;

radi=r;

}

void display(){

beginShape();

for (int i = 0; i < 6; i++)

{

vertex(x + radi * cos(radians(angle * i)),

y + radi * sin(radians(angle * i)));

}

endShape(CLOSE);

}

}

All the best

Miles

Replies(13)

kooogy

Re: Hexagonal Array, Dummy maths question.

2 years ago

centres of the odd numbered rows are offset in the x axis by the radius and in the y axis by .866 of the radius (or do i mean 2 * .866? i can't remember) (.866 is sin(60))

actually, that's wrong. i always do mine the other way around, points upwards and not to the side

anyway, the following will do it, but you'll need to change how you calculate hexcountx and hexcounty

...
for (int i = 0; i < hexcountx; i++){
for (int j = 0; j < hexcounty; j++){
if ((j % 2) == 0) {
hexagon[i][j] = new Hexagon((3 * rad * i), (.866 * rad * j), rad);
} else {
hexagon[i][j] = new Hexagon(3 * rad * (i + .5), .866 * rad * j, rad);
}
}
}
...

miles.tone

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

Oh right cool thanks,

Ill give it a go, arrays confuse the hell out of me though, melty brain.

Whereabouts would i call this?

Sorry for being a hassle

Cheers

kooogy

Re: Hexagonal Array, Dummy maths question.

2 years ago

(not sure you noticed, but i've changed my previous comment...)

miles.tone

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

Thanks thats excellent

ahah i think i understand now, i was being a bit of a muppet with it.

I can't see to understand the problem with the computation of the hexcounts

Is it because actually it would be multiplied by 0.866?

kooogy

Re: Hexagonal Array, Dummy maths question.

2 years ago

not sure.

each column is 3 * radius apart, so there are width / (3 * radius) across

each line is .866 * radius apart, so there are height / (.866 * radius) down

but the offset for alternate rows may mean that you're missing half a hex at the start of some lines.

kooogy

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

tbh i usually hardcode the counts once i've found a screensize and hexsize that i like 8)

miles.tone

Re: Hexagonal Array, Dummy maths question.

2 years ago

Oh cool good shout.

Ive just been having a bit of a play,

give this a click

Hexagon[][] hexagon;
int rad = 15;
int hexcountx, hexcounty;
import processing.opengl.*;
void setup()
{
noCursor();
size(1000, 1000);
smooth();
frameRate(50);
noStroke();
hexcountx = (height/(rad));
hexcounty = (width/(rad)*2);
hexagon = new Hexagon [hexcountx][hexcounty];
for (int i = 0; i < hexcountx; i++){
for (int j = 0; j < hexcounty; j++){
if ((j % 2) == 0) {
hexagon[i][j] = new Hexagon((3 * rad * i), (.866 * rad * j), rad);
} else {
hexagon[i][j] = new Hexagon(3 * rad * (i + .5), .866 * rad * j, rad);
}
}
}
}
void draw(){
for (int i = 0; i < hexcountx; i ++ ) {
for (int j = 0; j < hexcounty; j ++ ) {
hexagon[i][j].display();
}
}
}
class Hexagon{
float x,y,radi;
float angle = 360.0 / 6;
Hexagon(float cx, float cy, float r)
{
x=cx;
y=cy;
radi=r;
}
void display(){
beginShape();
for (int i = 0; i < 6; i++)
{
vertex(x + radi * cos(radians(angle * i)),
y + radi * sin(radians(angle * i)));
}
if (mousePressed){
colorMode(HSB, 500);
fill(abs(x-mouseX),abs(y-mouseY),500-dist(mouseX,mouseY,x,y));
}
endShape(CLOSE);
}
}

toxmeister

Re: Hexagonal Array, Dummy maths question.

2 years ago

Below's a bit shorter example using toxiclibs:

/**
* Hexagonal grid utility class
* Dependencies: toxiclibs-0018 or newer
* LGPL2 licensed
*/
import toxi.geom.*;
import toxi.processing.*;
HexGrid grid;
ToxiclibsSupport gfx;
void setup() {
size(640, 480);
gfx=new ToxiclibsSupport(this);
grid=new HexGrid(30);
}
void draw() {
background(255);
noFill();
translate(mouseX,mouseY);
grid.draw(gfx, 10, 10);
}
public class HexGrid {
float cellWidth, cellHeight;
Polygon2D hexProto;
public HexGrid(float radius) {
hexProto=new Circle(radius).toPolygon2D(6);
for(Vec2D v : hexProto.vertices) v.rotate(PI/6);
cellWidth=hexProto.getBounds().width;
cellHeight=cellWidth*sin(PI/3);
}
void draw(ToxiclibsSupport gfx, int cols, int rows) {
for (int x=0; x<cols; x++) {
for (int y=0; y<rows; y++) {
gfx.polygon2D(hexProto.copy().translate(getPosForCell(x,y)));
}
}
}
Vec2D getPosForCell(int x, int y) {
return new Vec2D((x+(1==y%2 ? 0.5 : 0))*cellWidth, y*cellHeight);
}
}

Hth!

http://postspectacular.com | http://toxiclibs.org

miles.tone

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

It doesn't seem to be working on mine,

Something to do with .rotate not existing, I'm not great at understanding classes yet.

Thanks

Miles

toxmeister

Re: Hexagonal Array, Dummy maths question.

2 years ago

Arggh, sorry, that must have been one of the more recent things I've added since the last release (there were dozens & i loose track of when features have been added). You can easily work around it for now by replacing the rotate() line with this one:

for(Vec2D v : hexProto.vertices) v.rotate(PI/6);

Instead of rotating the polygon as a unit, we just rotate all of its vertices... same effect :)

Hth! Btw. I've updated the code above already...

http://postspectacular.com | http://toxiclibs.org

miles.tone

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

lines 32 and 39 are still returning errors

is it the same on your machine?

cheers

Miles

toxmeister

Re: Hexagonal Array, Dummy maths question.

2 years ago

Ah, really sorry mister... classic versioning conflict scenario here. Rotating, scaling & translating polygons are only available in the codebase not yet released. But if you're still interested in getting this working it's a similarly easy fix as the rotate above. Translation in terms of vectors simply means addition. So here's the updated HexGrid, which now really should work:

import toxi.geom.*;
HexGrid grid;
void setup() {
size(640, 480);
grid=new HexGrid(30);
}
void draw() {
background(255);
noFill();
translate(mouseX,mouseY);
grid.draw(10, 10);
}
public class HexGrid {
float cellWidth, cellHeight;
Polygon2D hexProto;
public HexGrid(float radius) {
hexProto=new Circle(radius).toPolygon2D(6);
for(Vec2D v : hexProto.vertices) v.rotate(PI/6);
cellWidth=2*radius*sin(PI/3);
cellHeight=cellWidth*sin(PI/3);
}
void draw(int cols, int rows) {
for (int x=0; x<cols; x++) {
for (int y=0; y<rows; y++) {
Vec2D offset=getPosForCell(x,y);
beginShape();
for(Vec2D v : hexProto.vertices) vertex(v.x+offset.x,v.y+offset.y);
endShape(CLOSE);
}
}
}
Vec2D getPosForCell(int x, int y) {
return new Vec2D((x+(1==y%2 ? 0.5 : 0))*cellWidth, y*cellHeight);
}
}

http://postspectacular.com | http://toxiclibs.org

miles.tone

Re: Re: Hexagonal Array, Dummy maths question.

2 years ago

lovely thank you very much

I've got a tasty honeycomb now

Top Reply