Help with the new selectInput()

Programming Questions

vextex

Help with the new selectInput()

in Programming Questions • 1 year ago

The new selectInput() (and friends selectOutput() and selectFolder()) have a strange way of operating, and I'm not getting my head around the concept of how they work, it seems to be very confusing. You can see the changes here.

What I'd like to do is something simple, like

PShape shapeToUse;
void setup() {
size(200, 200);
}
void draw() {
shapeToUse = loadShape("somethingIHaveSelected");
shape(somethingIHaveSelected);
}

How do I go about implementing selectInput() in it's new state, so that I can select the .svg to be loaded on the sketch?

Replies(9)

PhiLho

Re: Help with the new selectInput()

1 year ago

What about using the example given in the page you link to?
It is a bad idea to load the file in draw(), I don't think its content will change 60 times per second, so no need to load it on each frame.

vextex

Re: Help with the new selectInput()

1 year ago

Because the problem is I can make no sense of how the example is supposed to work.

I can do

PShape shapeToUse;
void setup() {
size(200, 200);
selectInput("Select a file to process:", "fileSelected");
}
void fileSelected(File selection) {
shapeToUse = loadShape(selection);
}

But that doesn't even work. I don't understand how to work with this new way. All I want is to be asked to select a file, that will be assigned to a global variable so I can load it as an SVG shape, in processing 2.0

benja

Re: Help with the new selectInput()

1 year ago

Hey,

loadShape() expects the path to the file as a String.
"selection" is a File-Object, you can get the path to the file with the method getAbsolutePath(), which is also used in the example-code you were linking to.

void fileSelected(File selection) {
if (selection != null) {
shapeToUse = loadShape(selection.getAbsolutePath());
}
}

vextex

Re: Help with the new selectInput()

1 year ago

So far so good, thank you, I can at least get it to load with

PShape shapeToUse;
void setup() {
size(200, 200);
selectInput("Select a file to process:", "fileSelected");
}
void fileSelected(File selection) {
shapeToUse = loadShape(selection.getAbsolutePath());
shape(shapeToUse);
}
void draw() {
}

( void draw() has to be present, even if empty, or it won't load).

The thing missing, is now that shapeToUse has a loaded shape, how can I use it inside of void draw() (or any other place actually)? This is what is driving me crazy, taking it out of void fileSelected, and use it anywhere it could actually be useful.

PhiLho

Re: Help with the new selectInput()

1 year ago

PShape shapeToUse;
void setup()
{
size(200, 200);
selectInput("Select a file to process:", "fileSelected");
}
void fileSelected(File selection)
{
shapeToUse = loadShape(selection.getAbsolutePath());
}
void draw()
{
background(255);
if (shapeToUse != null)
{
shape(shapeToUse, width / 2, height / 2);
}
}

vextex

Re: Help with the new selectInput()

1 year ago

Thank you both for the help, I got it to work, and made a few additions. I don't always use void draw() in my sketches, and I really wanted a way for the sketch to start only after I choose my file (for various reasons, like frame accuracy), and came up with this.

PShape shapeToUse;
void setup()
{
size(200, 200);
selectInput("Select a file to process:", "fileSelected");
interrupt();
}
void fileSelected(File selection)
{
shapeToUse = loadShape(selection.getAbsolutePath());
}
void interrupt() {
while(shapeToUse == null) {
noLoop();
}
loop();
}
void draw() {
shape(shapeToUse, 0, 0);
}

The interrupt() stops the rest of the sketch from loading, and there are no visible downsides I can come up, with using this technique, so far so good.

Again, thank you both for the help.

PhiLho

Re: Help with the new selectInput()

1 year ago

A little variant, perhaps easier on the CPU:

PShape shapeToUse;
void setup()
{
size(200, 200);
selectInput("Select a SVG file", "fileSelected");
noLoop();
interrupt();
}
void fileSelected(File selection)
{
shapeToUse = loadShape(selection.getAbsolutePath());
}
void interrupt() {
while (shapeToUse == null) {
delay(200);
}
loop();
}
void draw() {
println(frameCount);
shape(shapeToUse, 0, 0);
}

geoffree

Re: Help with the new selectInput()

3 months ago

Just discovered that if you want to use OPENGL i.e. size(200, 200, OPENGL) then you cannot stop draw() being called with the interrupt(), otherwise the file dialog window does not appear! Put the ' while (shapeToUse == null) {' in the draw loop so it doesn't do anything until the file has been selected.

PhiLho

Re: Help with the new selectInput()

3 months ago

Good to know. It is a better practice, anyway.

Top Reply